Sub RangeToPicture()
    If TypeName(Selection) <> "Range" Then
        MsgBox "Выделенная область не является диапазоном."
        Exit Sub
    End If
    Dim imgName As String, wsTmpSh As Worksheet
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    With Selection
        .CopyPicture
        Set wsTmpSh = ThisWorkbook.Sheets.Add
        imgName = "Range_" & Format(Now(), "yyyymmdd") & Replace(Timer, ",", "")
        With wsTmpSh.ChartObjects.Add(0, 0, .Width, .Height).Chart
            .ChartArea.Border.LineStyle = 0
            .Parent.Select
            .Paste
            .Export Filename:=ActiveWorkbook.Path & "\" & imgName & ".png", FilterName:="PNG"
            .Parent.Delete
        End With
    End With
    wsTmpSh.Delete
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True
End Sub

'Булевая функция для проверки, является ли строка датой
' в формате ДД.ММ.ГГГГ по григорианскому календарю
Function isGregorianDate(data As String) As Boolean

    'Проверка, соответствует ли дата формату ДД.ММ.ГГГГ
    If Not data Like "##.##.####" Then
        isGregorianDate = False
        Exit Function
    End If

    Dim d As String, m As String, y As String
    d = Left(data, 2)   'день
    m = Mid(data, 4, 2) 'месяц
    y = Mid(data, 7, 4) 'год
    
    'Проверка, корректная ли дата по григорианскому календарю.
    ' До 1582 г. все года н.э., делящиеся на 4, считаются високосными,
    ' после только те года, которые делятся на 4 и не деляться на 100 или делятся на 400;
    ' если нужно учитывать високосные года до принятия григорианского календаря в России в 1918 г.,
    ' то замените в коде 1582 в "y < 1582" на 1918.
    ' https://ru.wikipedia.org/wiki/Високосный_год#Григорианский_календарь
    If (d = 0 Or m = 0 Or m > 12 Or y = 0 _
        Or ((m = 1 Or m = 3 Or m = 5 Or m = 7 Or m = 8 Or m = 10 Or m = 12) And d > 31) _
        Or ((m = 4 Or m = 6 Or m = 9 Or m = 11) And d > 30) _
        Or (m = 2 And Not (d < 29 Or (d < 30 And y Mod 4 = 0 _
                And (y < 1582 Or y Mod 100 <> 0 Or y Mod 400 = 0))))) _
    Then
        isGregorianDate = False
        Exit Function
    End If
    
    isGregorianDate = True
    
End Function