Выбрать дату в календареВыбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 31 След.
Гугл таблицы. сцепить текст из ячеек массива по условию
 
Вам нужна формула массива? Можно так. =ARRAYFORMULA(TEXTJOIN(" ";0;IF($A$2:$A$8=G2;$B$2:$B$8;"")))
Функция =ARRAYFORMULA() преобразует формулу в массивную.
Изменено: memo - 20.05.2022 08:08:35
Гугл таблицы. сцепить текст из ячеек массива по условию
 
Исходные:
=UNIQUE(A2:A8;0;0)
Значения:
=TEXTJOIN(" ";0;FILTER($B$2:$B$8;$A$2:$A$8=G2))
Указания аргументов функции, которые извлекаются из другой формулы
 
Формулы массива.
Столбцы (до Z):
Код
=INDEX($C$2:$F$2;MATCH(COLUMN(INDIRECT(MID(SUBSTITUTE(FORMULATEXT($B10);"+";";");INT((COLUMNS($B10:B10)-1)*3)+2;2)));COLUMN($C$2:$F$2);))

Строки:
Код
=INDEX($B$3:$B$6;MATCH(ROW(INDIRECT(MID(SUBSTITUTE(FORMULATEXT($B10);"+";";");INT((COLUMNS($B10:B10)-1)*3)+2;2)));ROW($B$3:$B$6);))
Изменено: memo - 17.05.2022 20:17:40
Извлечение значений в первом столбце согласно условию и перечисление этих значений через точку с запятой
 
surkenny, Отлично, спасибо.
Вывод месяцев в список по дате начала и конца проекта, Автозаполнение месяцев при заданном временном диапазоне: дата начала и конца
 
=IF(EOMONTH($B$1;ROWS($B$6:B6)-2)+1>$B$2;"";EOMONTH($B$1;ROWS($B$6:B6)-2)+1)
Извлечение значений в первом столбце согласно условию и перечисление этих значений через точку с запятой
 
Вариант на Power Query. Вышло громоздко, но уж как получилось. Буду рад видеть более компактное решение.
Код
let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    Type = Table.TransformColumnTypes(Source,{{"Страна", type text}, {"Да / Нет", type text}}),
    RemZero = Table.SelectRows(Type, each ([Страна] <> "0")),
    Col1 = Table.AddColumn(RemZero, "concat", each [Страна]),
    GroupedR = Table.Group(Col1, {"Да / Нет"}, {{"Grouped", each _, type table}}),
    Col2 = Table.AddColumn(GroupedR, "Custom", each Table.Column([Grouped],"concat")),
    Extracted = Table.TransformColumns(Col2, {"Custom", each Text.Combine(List.Transform(_, Text.From), "; "), type text}),
    Custom2 = Table.AddColumn(Extracted, "Страна", each if [#"Да / Нет"] = "Yes" then [Custom] else if [#"Да / Нет"] = "No" then null else null),
    Filtered = Table.SelectRows(Custom2, each ([Страна] <> null)),
    Output = Table.SelectColumns(Filtered,{"Страна"})
in
    Output
Поиск значения по двум критериям, формулы для Excel 2003
 
Максим Для протягивания по горизонтали используйте например COLUMN(B$1) или COLUMNS($A1:B$1) это даст нужный результат: 2...3...4 и т.д.
Поиск всех значении каждого наименования из таблицы
 
Могу только посоветовать максимально урезать файл, лишь бы была понятна структура, и если данные не конфиденциальны выложить сюда.
В качестве альтернативы попробуйте адаптировать такой вариант, может сработает:
Код
=IF(COUNTIF(Лист1!$A:$A;$A2)>=COUNTIF(A$2:$A2;$A2);INDEX(Лист1!B:B;MATCH($A2;Лист1!$A:$A;)+COUNTIF(A$2:$A2;$A2)-1))
Изменено: memo - 13.05.2022 23:19:20
Поиск всех значении каждого наименования из таблицы
 
Это альтернатива (чисто демонстрационная) вот этому блоку: COUNTIF($A$2:$A2;$A2)
Но как я уже написал в замене нет нужды, потому что он работает с текущей таблицей и к первой таблице отношения не имеет.
Поиск всех значении каждого наименования из таблицы
 
Ибрагим Белхороев, Да, СЧЕТЕСЛИ не работает с закрытой книгой, но в данном случае эта функция работает с текущей таблицей. Ее цель подсчитать скоро раз встречается конкретное наименование и передать числа в качестве аргумента функции АГРЕГАТ.
Но есливсе равно  нужна альтернатива, то вот массивный вариант:
Код
=COUNT(IF($A$2:$A2=$A2;1+MAX($F$1:F1)))
Поиск всех значении каждого наименования из таблицы
 
Ибрагим Белхороев, Отредактировал свой пост. См. файл.
Поиск значения по двум критериям, формулы для Excel 2003
 
Как вариант.
Код
=INDEX(C$3:C$123;MATCH(1;INDEX(LOOKUP(ROW(A$3:A$123);ROW(A$3:A$123)/(A$3:A$123>0);A$3:A$123=LOOKUP(2;1/(A$136:A136>0);A$136:A136))/(B$3:B$123=B136););))
Поиск всех значении каждого наименования из таблицы
 
Ибрагим Белхороев,
Можете заполнить пример, что и как должно выглядеть? А то задача мне кажется подозрительно простой)
---
Вдруг правильно:
Код
=INDEX(Лист1!$B$2:$C$50;AGGREGATE(15;6;(ROW($B$2:$B$50)-ROW($B$1))/(Лист1!$A$2:$A$50=$A2);COUNTIF($A$2:$A2;$A2));MATCH(B$1;Лист1!$B$1:$C$1;))
Изменено: memo - 13.05.2022 20:07:24
Подсчет уникальных значений в видимых ячейках после применения фильтра
 
Вариант.
Код
=SUMPRODUCT(SUBTOTAL(3;OFFSET($A$3;ROW($A$3:$A$316)-ROW($A$3);))*((ROW($A$3:$A$316)-ROW($A$3)+1)=MATCH($A$3:$A$316;$A$3:$A$316;0)))
количество не пустых ячеек
 
Цитата
Алексей Логвинов написал:
Я чайник
У вас русский офис, и ваш Excel понимает русский (локализованный) вариант формул. Переведите английские формулы на русские аналоги и все прекрасно посчитается. На возможный вопрос, где искать - гугл в помощь.
количество не пустых ячеек
 
=COUNTIFS($F$6:$F$15;$L6;$G$6:$G$15;"<>")
Заполнение колонки с последовательным изменением числа, но внутри ссылки
 
chgm, Вариант.
Функция СЧЁТЕСЛИ, СУММЕСЛИ, в качестве критерия "условие не содержит значение "003" (текстовое значение)", Функция СЧЁТЕСЛИ, СУММЕСЛИ, в качестве критерия "условие не содержит значение "003" (текстовое значение)"
 
Попробуйте так.
=SUMPRODUCT(N(Лист1!$G$2:$G$17<>"003"))
Строки в столбец, Преоброзование строк в столбцы
 
Цитата
Ham13 написал:
Если имеете ввиду ограничение по колву,и это важно
Ну, это не мне важно а ТС :)
Цитата
Alesger Mammedov написал:
чтобы каждому поставщику соответствовало относящаяся ему значение в прозрачности.
Вариант без INDIRECT()
Код
=IF(COUNTIF($A$2:$A$496;$L$1)>=ROWS(L$1:L1);INDEX($B:$B;MATCH(L$1;$A:$A;)+ROW(A1)-1);"")
Строки в столбец, Преоброзование строк в столбцы
 
Ham13, Эта формула не будет фильтровать значения по конкретному критерию. Она будет выводить их все.
Строки в столбец, Преоброзование строк в столбцы
 
Формула.
Код
=IFERROR(INDEX($B$2:$B$496;AGGREGATE(15;6;ROW($A$1:$A$600)/($A$2:$A$496=E$1);ROW(E1)));"")

В Е2. Растянуть вправо и вниз
как из нескольких строк в эксель сделать одну
 
Вариант через ИНДЕКС. Рассчитан на меньшее кол-во водки и всего пару банок пива.
В файле, строчками ниже решения показана наглядная работа формулы. На всякий случай: 16 - это кол-во столбцов, начиная со столбца С. Формула - COLUMN(A$1)>16*4 - отсечка по столбцам.
Формула массивная, для большого кол-ва строк скорее всего не подойдет, поэтому носит чисто демонстрационный характер. На практике юзайте макрос и PQ.
Изменено: memo - 07.05.2022 13:41:40
сумма чисел при выборе из 2-х массивов
 
Код
=SUMPRODUCT(COUNTIF($C$4:$C$6;$C$9:$C$18);$D$9:$D$18)

и о кроссе нужно информировать прямыми ссылками, в соответствии с правилами форума.
Изменено: memo - 07.05.2022 00:44:15
Удаление старых дат из таблицы и транспонирование самой новой, Транспонирование определенных строк в столбец
 
Анварбек Телекаев,
Вариант.
=SUMIFS('1'!D$7:E$67;'1'!$A$8:$B$68;"*.";'1'!$A$7:$B$67;$L3)
и
=SUMIFS('1'!F$7:G$67;'1'!$A$8:$B$68;"*.";'1'!$A$7:$B$67;$L3)
Первую и последнюю формулы позаимствовал у Бороды (не вижу смысла изобретать велосипед), лишь использовал немассивный вариант. Листы переименовал для удобства на 1 и 2.
подсчет кол-ва календарных дней между текстовыми значениями в ячейке
 
Ольга Боб, Вариант.
Дни.
Код
=IFERROR(1/(1/(DAYS(AGGREGATE(14;6;$C$1:$Q$1/(C2:Q2<>"");1);AGGREGATE(15;6;$C$1:$Q$1/(C2:Q2<>"");1))));"")

Пустые ячейки.
Код
=IFERROR(SUMPRODUCT(AGGREGATE(15;6;COLUMN($C:$Q)/(C2:Q2<>"");ROW($1:$2))*{-1;1})-1;"")
Изменено: memo - 03.05.2022 07:07:39
подсчет кол-ва календарных дней между текстовыми значениями в ячейке
 
Почему для первой строки начальная и конечная дата учитываются, а для второй и четвертой нет?
Первое и последнее событие, Фильтр первого и последнего события дня
 
Варианты.
Фильтр дат.
Код
=IFERROR(INDEX($C$2:$C$37;MATCH(FALSE;INDEX(COUNTIF($I$1:$I1;$C$2:$C$37)=2;);0));"")

На случай если в датах будут пропуски замените блок MATCH на этот:
Код
MATCH(1;INDEX((COUNTIF($I$1:$I1;$C$2:$C$37)=2)+($C$2:$C$37<>""););0)

Время (вариант №1).
Код
=AGGREGATE(15;6;$D$2:$D$37/($C$2:$C$37=I2);INT((COUNTIF($I$1:$I2;I2)-1)*COUNTIF($C$2:$C$37;I2))+MOD(ROWS($J$1:J1);2))

Время (вариант №2).
Код
=CHOOSE(COUNTIF(I$2:I2;I2);AGGREGATE(15;6;$D$2:$D$37/($C$2:$C$37=$I2);1);AGGREGATE(14;6;$D$2:$D$37/($C$2:$C$37=$I2);1))

Время (вариант №3).
Код
=INDEX(AGGREGATE({15;14};6;$D$2:$D$37/($C$2:$C$37=$I2);1);1+MOD(ROWS(L$2:L2)-1;2))
Изменено: memo - 29.04.2022 03:48:03
Изменение диапазона листов при суммировании, Использование имени листа из ячейки
 
Цитата
Александр Курочкин написал:
Но если названия листов будет текст?
Можно использовать список имен листов и ориентироваться по нему. Пример приложил.
Изменено: memo - 27.04.2022 16:30:49
Смещение диапазона в формуле на определенный шаг
 
Цитата
БМВ написал:
Ну с датами можно проще
А вдруг в какой-то момент у ТС возникнет необходимость отказаться от определенного шага?
Насчет остального не буду спорить, это всего лишь вариант.
Смещение диапазона в формуле на определенный шаг
 
Еще вариант.
Фильтруем даты:
Код
=INDEX($B$3:$B$11;MATCH(TRUE;INDEX(COUNTIF($H$2:H2;$B$3:$B$11)=0;);0))

Выводим наименования по наибольшим показателям и отфильтрованным датам.
Код
=INDEX($C$3:$C$11;MATCH(AGGREGATE(14;6;$D$3:$D$11/($B$3:$B$11=H3);COUNTIF($H$3:H3;H3));$D$3:$D$11;0))
Изменено: memo - 26.04.2022 22:39:21
Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 31 След.
Наверх