Выбрать дату в календареВыбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 51 След.
Выбор данных из таблицы по двум критериям., Формула Смещ помогите!!! Надо добавить в поиск 2 критерию
 
Название темы: "СМЕЩ, которая трется и мешает". Шутка - если что :).
Artem Fil, А может, ну его этот смещ, он летуч (и вообще трется:) ), и воспользоваться комбинацией ИНДЕКС+АГРЕГАТ?
Код
=INDEX(B:B;AGGREGATE(15;6;ROW($A$6:$A$1000)/($E$6:$E$1000={"Овощи"\"Фрукты"});ROW(A1)))

Ну и более подходящий вариант названия темы:
Выбор данных из таблицы по двум критериям.
Список из ячеек, Формирования большого списка из списков в ячейках
 
Чуть универсальнее, чтобы не было ошибки, если в списке будут числа
Код
let
    from = Excel.CurrentWorkbook(){[Name="Таблица1"]}[Content][Списки],
    unique = List.Distinct(Text.Split(Text.Combine(List.Transform(from, (x) => Text.From(x)), ", "),", "))
in
    unique
Формула для определения кол-ва одной формулой, если в ячейке несколько значений, Формула для определения кол-ва одной формулой, если в ячейке несколько значений
 
Еще вариант.
=SUMPRODUCT(SUMIF($D$2:$D$6;TRIM(MID(SUBSTITUTE(A2;CHAR(10);REPT(" ";99));ROW($1:$15)*99-98;99));$E$2:$E$6))
Найти номер строки дубля
 
Для чисел и текста можно такой вариант:
=IFERROR(SMALL(IF(COUNTIF(C3;A$2:A$99);ROW(A$2:A$99));D3);MATCH(C3;COUNTIF(C3;A$2:A$99);)+1)
Найти номер строки дубля
 
В ваших данных текст вместо чисел, отсюда и ошибка. Для преобразования текста в числа поставьте в этом блоке двойное отрицание (--A$2:A$99=C3)
Ну и чуть дополнил формулу, чтобы при остутствии дубликата выводился номер строки первого значения.
Найти номер строки дубля
 
Если правильно понял, то как-то так (формула массива):
=SMALL(IF((A$2:A$99=C3);ROW(A$2:A$99));D3)
Изменено: memo - 13.02.2024 08:55:23
Из списка с пустыми ячейками сделать список без пустых ячеек
 
DanKZ, Попробуйте убрать LOOKUP("zzzzz";CHOOSE({1,2};""; и две скобки в конце.
Выбор из массива по нескольким условиям, Выбор из массива по нескольким условиям
 
Цитата
Александр Шишкин написал:
Не работает. Excel 2019/
Не верю (с).

Еще подкину.
=SUMPRODUCT(COUNTIFS($D$16:$D$112;"Округ "&A4;$E$16:$E$112;$A$17:$A$136);$B$17:$B$136)
Выбор из массива по нескольким условиям, Выбор из массива по нескольким условиям
 
Для №4 массивно:
=SUM(SUMIF($A$17:$A$136;IF(TRIM(SUBSTITUTE($D$16:$D$112;"Округ";))=A4;$E$16:$E$112);$B$17:$B$136))
Перевод формул
Срзнач суммированных ячеек по строкам или столбцам
 
Цитата
Wild717 написал:
Подскажите, пожалуйста, формулу,
Приложите, пожалуйста, файл-пример.
Удалить текст до первой запятой с конца, Подбор формулы для обработки текста
 
Цитата
БМВ написал:
наличии повторов до последней запятой наборов символов которые после, вариант  memo  сбойнет
Все пытаюсь повторить этот самый сбой с повторами, никак не выходит, что я делаю не так? Что касается двойных и более пробелов, то оборачиваем А1 в TRIM (везде кроме SUBSTITUTE) и сбоя нет.
Изменено: memo - 03.11.2023 23:14:15
Нужно создать количество строк по количеству столбцов, Создать количество строк по количеству столбцов (пример на фото)
 
Примитивный и не очень формульные варианты.
Изменено: memo - 03.11.2023 22:59:00 (Дополнение)
Удалить текст до первой запятой с конца, Подбор формулы для обработки текста
 
Цитата
julia_terekhova написал:
итог формулы: #ИМЯ?
Естественно. Нужно перевести.
Ладно, сам переведу.
=ЛЕВСИМВ(A1,ПОИСК(СЖПРОБЕЛЫ(ПРАВСИМВ(ПОДСТАВИТЬ(A1,",",ПОВТОР(" ",99)),99)),A1)-3)
Изменено: memo - 03.11.2023 15:19:29 (перевод и озвучка)
Удалить текст до первой запятой с конца, Подбор формулы для обработки текста
 
Еще.
=LEFT(A1;SEARCH(TRIM(RIGHT(SUBSTITUTE(A1;",";REPT(" ";99));99));A1)-3)
Подставить в формулу СУММ() строковое значение из другой ячейки, Подскажите, как сделать так, чтобы в СУММ() в название листа подтягивалось значение из другой ячейки
 
Цитата
Дмитрий(The_Prist) Щербаков написал:
Формула же обычная, не требует никаких массивных вычислений.
Совершенно верно. Моя ошибка.
Подставить в формулу СУММ() строковое значение из другой ячейки, Подскажите, как сделать так, чтобы в СУММ() в название листа подтягивалось значение из другой ячейки
 
Правильно вам написал Матрос, надо было лишь немного подправить формулу.
=SUM(INDIRECT("'"&B1&"'!A2:A100"))
Вводить как формулу массива через CTRL+SHIFT+ENTER.
Второе минимальное значение
 
Цитата
bass777 написал:
Ваше решение очень удобное!
Мне оно таким не казалось, поэтому решил уделить вопросу больше времени и вот теперь, думаю, выглядит более-менее сносно))
=SMALL(SUMIF(INDIRECT("'"&$L$2:$L$4&"'!B2:B100");B2;INDIRECT("'"&$L$2:$L$4&"'!AG2:AG100"));2)
Второе минимальное значение
 
Вариант.
=SMALL(IF(T(OFFSET(INDIRECT("'"&TRANSPOSE($L$2:$L$4)&"'!B2:B17");ROW($2:$17)-2;))=B2;N(OFFSET(INDIRECT("'"&TRANSPOSE($L$2:$L$4)&"'!AG2:AG17");ROW($2:$17)-2;)));2)

ну или так (можно пополнять список листов)
=SMALL(IF(IFERROR(T(OFFSET(INDIRECT("'"&TRANSPOSE($L$2:$L$17)&"'!B2:B17");ROW($2:$17)-2;));"")=B2;IFERROR(N(OFFSET(INDIRECT("'"&TRANSPOSE($L$2:$L$17)&"'!AG2:AG17");ROW($2:$17)-2;)); ));2)
Изменено: memo - 29.10.2023 15:33:05
Получить сумму значений по условию
 
Цитата
БМВ написал:
Попробуйте не 13 а 100,500, 1000
Когда переносил, не взглянул на диапазон. Попробовал на 10000. Не очень. Ну понятно, что такая схема быстро работать не будет - 50-100 записей вполне сносно.
Получить сумму значений по условию
 
Чуть переделал, вроде быстрее.
Код
=IF(E2>0;SUM(INDEX(LOOKUP(ROW($E$2:$E$13);ROW($E$2:$E$13)/($E$2:$E$13>0);$E$2:$E$13=E2)*$F$2:$F$13;));"")
Получить сумму значений по условию
 
Ну и мой вариант:
Код
=IFERROR(1/(1/(SUMPRODUCT((LOOKUP(ROW($A$2:$A$35);ROW($A$2:$A$35)/($A$2:$A$35>0);$A$2:$A$35)=A2)*($C$2:$C$35>0)*$C$2:$C$35)));"")
Получить сумму значений по условию
 
Файл-пример в студию.
Произвести подсчёт данных с множества страниц в одну по выбору даты
 
Tatar,
=SUM(N(INDIRECT("'"&TEXT(DAY(ROW(INDEX($D$1:$D$100000;$E$9):INDEX($D$1:$D$100000;$F$9)))*100+MONTH(ROW(INDEX($D$1:$D$100000;$E$9):INDEX($D$1:$D$100000;$F$9)))&YEAR(ROW(INDEX($D$1:$D$100000;$E$9):INDEX($D$1:$D$100000;$F$9)));"00\.00\.0000")&"'!"&ADDRESS(ROW(C3);COLUMN(C3);1;1))))

Ну и вводить надо тремя известными клавишами - CTRL+SHIFT+ENTER
Прикрепил файл.
Произвести подсчёт данных с множества страниц в одну по выбору даты
 
Как я уже писал, если в наименовании листов будут даты, то формула будет работать. Переименовать сразу группу листов можно с помощью макроса, я ими пока особо не интересовался, поэтому помочь с кодом не смогу.
Произвести подсчёт данных с множества страниц в одну по выбору даты
 
Tatar, В вашем первоначальном примере листам присвоены названия в виде дат, собственно, все формулы в этой теме от этого и отталкиваются. В последнем примере у листов разные названия и естественно, ни одна формула работать не будет.
В теории, можно, в отдельном столбце прописать названия листов (причем прописанные имена должны быть на 100% идентичны названиям листов) и использовать их в качестве критерия, но как это будет на практике не представляю. Возможно, точно не знаю, это легче сделать с помощью макроса.
Выше Дмитрий предложил вариант и он вроде работает. (Приложил файл с его кодом).
Изменено: memo - 18.10.2023 21:59:21
Произвести подсчёт данных с множества страниц в одну по выбору даты
 
Tatar, Сделайте подробный пример в котором будет передана структура основного файла, и по возможности со всеми ньюансами.
Расчёт среднего показателя с первой записи
 
Простой вариант:
=IFERROR(AVERAGEIF(AE4:AL4;">0";AE4:AL4); )
Изменено: memo - 13.10.2023 09:21:16
Произвести подсчёт данных с множества страниц в одну по выбору даты
 
Немного изменил формулу Максим В., чтобы работала с любой локалью (на всякий случай поясню - не надо будет мучаться со сменой алфавита ДД, JJ, DD и т.д.)
=SUM(N(INDIRECT("'"&TEXT(DAY(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))*100+MONTH(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))&YEAR(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)));"00\.00\.0000")&"'!"&ADDRESS(ROW(B3);COLUMN(B3);1;1))))

Ну и мой жирноватый немассивный вариант:
=SUMPRODUCT(SUMIF(INDIRECT("'"&TEXT(DAY(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))*100+MONTH(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))&YEAR(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)));"00\.00\.0000")&"'!A2:A100");$A4;INDIRECT("'"&TEXT(DAY(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))*100+MONTH(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)))&YEAR(ROW(INDEX($A$1:$A$100000;$B$1):INDEX($A$1:$A$100000;$C$1)));"00\.00\.0000")&"'!"&ADDRESS(2;COLUMN(B2);1;1))))
Изменено: memo - 05.10.2023 19:13:15
Заполнение матрицы по совпадению значений строк и столбцов на исходной таблице., Поиск совпадений текстовых значений в исходной таблице для последующего заполнения ячеек результирующей матрицы.
 
Вариант.
=COUNTIFS($J$3:$J$9;$B4;$K$3:$K$9;C$3)
Нули скрыть пользовательским форматом ;;;
Суммирование диапазона по условию, Функция СУММЕСЛИ
 
Еще парочка для года и месяца:
=SUMIFS(B:B;A:A;">="&EDATE(TODAY();-12))
=SUMIFS(B:B;A:A;">="&EDATE(TODAY();-1))

Хотя, так будет правильнее:
=SUMIFS(B:B;A:A;">="&DATE(YEAR(TODAY());1;1))
=SUMIFS(B:B;A:A;">"&EOMONTH(TODAY();-1))
Изменено: memo - 22.09.2023 18:58:13
Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 51 След.
Наверх