Страницы: 1
RSS
Суммирование по критериям в столбцах и строке
 
Задача:
Таблица 1 заполняется.
Таблица 2 должна просчитываться автоматически при заполнении критериев в столбцах К и L. при этом формула должна считать значения в соответствующей строке и по критериям в столбцах. То есть в прилагаемом примере функция в ячейке М5 должна найти в столбцах В и С значения "РВК" и "4" и проссуммировать все значения в столбцах, где критерием в заголовках столбцов является любое значение, начинающееся или имеющее значение "А".
Код
=СУММПРОИЗВ(($K5=$B$5:$B$9)*($L5=$C$5:$C$9)*(M4=$D$4:$I$4)*($D$5:$I$9)) 
Формула производит подсчет только при полном совпадении значений М4 в диапазоне D4:I4, а необходимо, чтобы согласно условию формула просчитала значения в ячейках D8, F8, G8 и I8 (А*).
Изменено: vikttur - 16.09.2021 20:47:30
 
Валерий Жуковский, ловите извращений немного
Код
=СУММЕСЛИМН(ИНДЕКС($D$5:$I$9;ПРОСМОТР(2;1/(($B$5:$B$9=$K5)*($C$5:$C$9=$L5));СТРОКА($B$5:$B$9))-4;1):ИНДЕКС($D$5:$I$9;ПРОСМОТР(2;1/(($B$5:$B$9=$K5)*($C$5:$C$9=$L5));СТРОКА($B$5:$B$9))-4;6);$D$4:$I$4;M$4)
Не бойтесь совершенства. Вам его не достичь.
 
Вариант.
Уровень извращенности - средний.
Код
=СУММЕСЛИМН(СМЕЩ($D$4;ПОИСКПОЗ(СТРОКА($B$5:$B$9)-СТРОКА($B$5)+1;ИНДЕКС(($B$5:$B$9=$K5)/($C$5:$C$9=$L5);););;;СЧЁТЗ($D$4:$I$4));$D$4:$I$4;M$4)

Или короче, но конкретно по примеру:
Код
=СУММЕСЛИМН(СМЕЩ($D$4;$L5;;;СЧЁТЗ($D$4:$I$4));$D$4:$I$4;M$4)
Изменено: memo - 17.09.2021 05:48:39
 
Еще вариант:
Код
=СУММЕСЛИ($D$4:$I$4;M$4;ИНДЕКС($D$5:$I$9;ПОИСКПОЗ($K5&$L5;$B$5:$B$9&$C$5:$C$9;);0))
Формула массива.
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
Еще вариант:
Код
=СУММ(ЕСЛИОШИБКА(ПОИСК(M$4;$D$4:$I$4;1);0)*СМЕЩ($C$4;ПОИСКПОЗ($K5&$L5;$B$5:$B$9&$C$5:$C$9;0);1;1;6))
 
Спасибо за участие всем откликнувшимся. Но, к сожалению, ни один из предложенных вариантов не работает корректно. Необходимо, чтобы формула просчитывала все значения, где в диапазоне критериев ( $D$4:$I$4) присутствует символ критерия.
 
Валерий Жуковский, А вы не могли бы показать в таблице как должен выглядеть конечный результат?
 
Цитата
Валерий Жуковский написал:
не работает корректно
Прям все по вашему ТЗ
Цитата
Валерий Жуковский написал:
формула просчитывала все значения, где в диапазоне критериев ( $D$4:$I$4) присутствует символ критерия
Вы формулу вводите как массивную?
 
Adamm, перепроверил, все отлично. Спасибо большое!
Изменено: Валерий Жуковский - 18.09.2021 11:36:48
 
Валерий Жуковский, У абсолютно всех предложенных здесь вариантов одинаковый результат. В чем же тогда некорректность?
 
Да, это я ошибся. Изменил критерии в своем примере и потом просто подставил ваши решения. Все работает корректно во всех примерах. Всех благодарю за участие и помощь!
Страницы: 1
Наверх