Страницы: 1
RSS
Найти среднее значение 5 минимальных положительных значений в диапазоне
 
Всем привет.
Есть формула, которая вычисляет среднее первых 5 минимальных значений:
Код
=СРЗНАЧ(НАИМЕНЬШИЙ($A$1:A10;{1;2;3;4;5}))

В вычислении "участвуют" положительные и отрицательные числа.
Подскажите, пожалуйста, как сделать, чтобы формула вычислила среднее первых 5 минимальных положительных значений?
 
Код
=СРЗНАЧ(НАИМЕНЬШИЙ(ФИЛЬТР(A1:A10;A1:A10>0);{1;2;3;4;5}))
Компьютер никогда не заменит человека (©️ Hannibal Lecter)
 
Ещё одна формула
Код
=AVERAGE(AGGREGATE(15;6;A1:A10/(A1:A10>0);{1\2\3\4\5}))
Изменено: jakim - 31.10.2021 08:07:27
 
массивная
=AVERAGE(SMALL(IF($A$1:A10>0;$A$1:A10);{1\2\3\4\5}))
не массивная
=AVERAGE(AGGREGATE(15;6;$A$1:A10/($A$1:A10>0);{1\2\3\4\5}))
По вопросам из тем форума, личку не читаю.
 
Игнорируем лишнее:
=СРЗНАЧ(НАИМЕНЬШИЙ(A1:A10; СЧЁТЕСЛИ(A1:A10;"<=0")+{1;2;3;4;5}))
 
Интересно как там FILTR
но по сокорости примерно равны
=AVERAGE(SMALL(IF($A$1:A10>0,$A$1:A10),{1,2,3,4,5}))     441,4063
=AVERAGE(AGGREGATE(15,6,$A$1:A10/($A$1:A10>0),{1,2,3,4,5}))            433,5938
=AVERAGE(SMALL(IF($A$1:A10>0,$A$1:A10),COUNTIF(A1:A10,"<=0")+{1,2,3,4,5}))           449,2188
По вопросам из тем форума, личку не читаю.
 
Моя без массивного ввода и применима даже в Excel-2003 )

:) ------------------- :)
Тщательный анализ показанного тестирования показал: скорость формулы напрямую зависит от количества символов!

P.S. Исследование проведено по научной методике "слух таракана".
- оторвали лапку (чего только не сделаешь ради науки), крикнули "беги" - побежал;
...
- оторвали последнюю, крикнули, - не побежал.

Вывод: научная гипотеза подтверждена - органы слуха у таракана находятся в конечностях
 
Сергей Евдокимов, jakim, БМВ, vikttur,
люди, вы гении!)) Спасибо огромное! По скорости, да, все примерно одинаковые - тестировал на 200 строках.

Сергей Евдокимов, не получилось проверить вашу формулу, так как в Excel 2019 нет функции ФИЛЬТР.))
 
Сергей Евдокимов, получается, самый гениальный гений ;)

Не разбрасывайтесь словами, не приуменьшайте гениальность, путая его с умением и опытом.
 
Цитата
vikttur написал:
Не разбрасывайтесь словами, не приуменьшайте гениальность, путая его с умением и опытом.
Какой вы строгий, учитель:)
Страницы: 1
Читают тему (гостей: 1)
Наверх