Страницы: 1
RSS
Посчитать количество билетов с наибольшей серией
 
К примеру у меня в диапазоне A1:10 прописаны номера с сериями 2568 и 2622, мне нужно посчитать количество ячеек с наибольшей серией, в данном случае 2622. Как это реализовать с помощью формулы?
 
Код
=СЧЁТ(ЕСЛИОШИБКА(НАЙТИ(МАКС(ЛЕВБ(A1:A9;4));A1:A9;1);""))
 
Тимофеев, ноль выдаёт.
Изменено: Ибрагим Белхороев - 30.11.2021 16:04:59
 
массивно опять же Ctrl+Shift+Enter! или поменять версию эксель
Код
=СЧЁТ(ПОИСК(МАКС(ЛЕВБ(A1:A9;4));A1:A9;1))
Изменено: Тимофеев - 30.11.2021 16:07:28
 
для коллекции =COUNTIF(A1:A9;">="&LARGE(--LEFT(A1:A9;4);2)*1000) массивная
 
Тимофеев, понял. А можно это реализовать с помощью функции СУММПРОИЗВ?
 
Цитата
Ибрагим Белхороев написал:
СУММПРОИЗВ?
=SUMPRODUCT(A1:A9>=LARGE(--LEFT(A1:A9;4);2)*1000) :) Excel нет попробовать, но
что-то мне подсказывает, что она должна быть тоже массивной
 
Код
=СУММПРОИЗВ(ЕСЛИОШИБКА(ПОИСК(ПСТР(МАКС(A1:A9);1;4);A1:A9);0);ЛЕВБ(A1:A9;4)/ЛЕВБ(A1:A9;4))
 
bigorq, формула "=СУММПРОИЗВ(A1:A10>=НАИБОЛЬШИЙ(--ЛЕВСИМВ(A1:A10;4);2)*1000)" не работает, в том числе и с массивом.
 
Цитата
Ибрагим Белхороев написал:
не работает,
пришлось искать excel, такая работает, массивная
=СУММПРОИЗВ(--((A1:A9)>=НАИБОЛЬШИЙ(--ЛЕВСИМВ(A1:A9;4);2)*1000))
 
Код
=СЧЁТ(ПРОСМОТР(ЛЕВБ(A1:A9;4)*1000;A1:A9))
 
=--(ЛЕВСИМВ(A1;2)>"25")
 
Цитата
Игорь Давыдов написал:
>"25"
ТС добавит в табличку 2815253 и Вы будете переписывать формулу?
 
Цитата
написал:
=--(ЛЕВСИМВ(A1;2)>"25")
вставь и посмотри
 
Игорь Давыдов, разницу в обращении видите?
Цитата
bigorq написал: Вы будете переписывать
Цитата
Игорь Давыдов написал: вставь и посмотри
 
=СУММПРОИЗВ(--(ЛЕВСИМВ($A$1:$A$9;2)>"25")) , что бы при добавлении данных все считало в помощь динамическая таблица!!!
 
Не возмущаться нужно, а прислушиваться к замечаниям.

Цитата
Ибрагим Белхороев написал: нужно посчитать количество ячеек с наибольшей серией
2568318
2622101
2622102
2655555
2855555
И что Ваша формула выдаст при таких данных? А правильный результат - 1
Да и серия должна проверяться по четырем символам

---------------------------------------------------------------
В примере данные размещены в возрастающем порядке. Для такого случая:
=СЧЁТЕСЛИ(A1:A30;">="&ЛЕВБ(МАКС(A1:A30);4)*1000)
 
=COUNTIF(A:A;">="&AGGREGATE(14;;ROUNDDOWN(A1:A9;-3);1))
ну или  массивка
=COUNTIF(A:A;">="&MAX(ROUNDDOWN(A1:A9;-3)))
ну или варианты по делению и умножению на 1000
По вопросам из тем форума, личку не читаю.
 
Массивная
Код
=СУММ(Ч(A1:A9>=МАКС(ОКРУГЛВНИЗ(A1:A9;-3))))


PS: формулы от БМВ сразу не видел, поэтому СЧЕТЕСЛИ добавлять не буду (уже есть)
 
Ещё одна с массивным вводом
Код
=SUMPRODUCT(--(INT((A1:A10)/1000)=MAX(INT(A1:A10/1000))))
 
Всем спасибо за помощь.
Страницы: 1
Наверх