Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Пользователи » _Boroda_
Выбрать дату в календаре…Выбрать дату в календаре

Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 56 След.
Как выделить строки в которых есть заливка в любом из столбцов
 
#
14.04.2025 13:57:52
Не, ну, можно в каждом из столбцов выбрать по фильтру "Нет заливки". Оставшиеся видимыми после всех фильтров строки - кандидаты на удаление
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Как создать правильно условие на ссылку с одной таблицы на другую?
 
#
14.04.2025 13:52:35
Цитата
24fusion.ru написал:
себестоимость вставала в табличку апрель к определенному артикулу и только там где указана продажа
Так и напишите:
Код
=ЕСЛИ((D266="Продажа")*E266;ВПР(B266;[себестоимость.xlsx]Лист1!$A$1:$B$16;2;);0)
Изменено: _Boroda_ - 14.04.2025 13:53:13
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Суммирование по значению из Списка
 
#
11.04.2025 15:49:45
Код
=СУММПРОИЗВ(E$5:E$11*(D$5:D$11=--ПРАВБ(B20;3))*СЧЁТЕСЛИ(ИНДЕКС(J$5:L$9;;ПОИСКПОЗ(ЛЕВБ(B20;4)&"*";J$3:L$3;));C$5:C$11))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Сумма произведений в столбце через строку
 
#
11.04.2025 15:21:30
Код
=СУММПРОИЗВ(D2:D10*D3:D11*(A2:A10=A2))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Как вытащить из даты месяц и год
 
#
08.04.2025 17:42:29
Та попробуйте МММ английские написать
Или напишите в ячейку дату, зайдите в формат ячейки, выберите Дата, в правом поле выберите нужный тип, потом в левом выберите "Все форматы" и посмотрите, что будет написано в поле Тип. Вот это Вам и нужно. Обычно без того, что там написано в квадратных скобках (но не всегда, нужно пробовать) и без куска ;@
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
ВПР на несколько столбцов, Как создать функцию ВПР для нескольких столбцов
 
#
08.04.2025 12:00:40
Код
=СУММЕСЛИМН(Классификация!D$2:D$9;Классификация!$B$2:$B$9;$C2;Классификация!$C$2:$C$9;$D2)
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Разбить информация по столбам
 
#
04.04.2025 14:31:27
Можно формулами (обычными, которые во всех версиях excel работают)))), но они тяжеловаты будут. Если у Вас данных много, то можно допстолбец сделать и сводной таблицей потом
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Вопрос о сводной: почему при двойном клике на значении разворачивается не вся структура
 
#
04.04.2025 11:27:25
Файлик бы посмотреть)))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Несколько итогов в сводной
 
#
04.04.2025 10:40:12
Цитата
Viktoriya3675 написал:
спасибо, как это сделано?)
Обычная сводная, в старом формате, без модели
Топ на сводную - Анализ - Поля, элементы, наборы - Вычисляемый объект
Там не стал извращаться, просто сложил.
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Причины долгой работы макроса, Причины долгой работы макроса
 
#
04.04.2025 10:36:24
Здесь смотрели?
https://www.planetaexcel.ru/forum/?PAGE_NAME=read&FID=1&TID=151769&TITLE_SEO=151769-samoe-bystroe-udalenie-strok
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Формула сумма значений с разделителем, Формула сумма значений с разделителем
 
#
04.04.2025 10:24:53
Цитата
gling написал:
Все варианты выдают разные значения.
Ваш вариант верный.
Мой не учитывает, что может быть несколько областей. А Матрос забыл обнулить хх во втором цикле
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Несколько итогов в сводной
 
#
03.04.2025 17:40:08
Может, так подойдет?
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Формула сумма значений с разделителем, Формула сумма значений с разделителем
 
#
03.04.2025 17:22:17
Формулой
=ЕСЛИОШИБКА(СУММПРОИЗВ((СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ([@Сотрудники];";";ПОВТОР(" ";999));999*СТОЛБЕЦ(A:Z)-998;999))=F$2:F$5)*ИНДЕКС(G$2:H$5;;ПОИСКПОЗ([@Области];G$1:H$1;)));)
Изменено: _Boroda_ - 03.04.2025 17:22:32
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Поиск даты превышения суммы погашения относительно суммы получения,
 
#
03.04.2025 15:09:46
Формула массива
Код
=ЕСЛИОШИБКА(ИНДЕКС(E$3:E$254;ПОИСКПОЗ(СУММ(H$2:H3);СУММЕСЛИ(E$2:E$254;"<="&E$2:E$254;I$2:I$254);1));"-")

Или обычная формула
Код
=ПРОСМОТР(;-1/(СУММ(H$2:H3)>=СУММЕСЛИ(E$2:E$254;"<="&E$2:E$254;I$2:I$254));E$3:E$255)
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
vba Как обратится к листу, чье имя - это значение ячейки?
 
#
03.04.2025 14:40:38
Цитата
syt navy написал:
Так не. Не работает
А у меня работает, иначе я бы не выложил код.
Как вы думаете, что нужно сделать, чтобы и в вашем файле заработало?
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
vba Как обратится к листу, чье имя - это значение ячейки?
 
#
03.04.2025 13:01:40
Так не?
Код
a_ = Sheets(1).Cells(1).Value & ""
    Set sh_ = Worksheets(a_)
    sh_.Select

В ячейке А1 первого листа число (для простоты, там уж сами потом из своего файла возьмите). Остальные листы названы 1-2-3-...
Изменено: _Boroda_ - 03.04.2025 13:03:39
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 17:13:39
Тогда так
=СУММ(ИНДЕКС(G:G;ПОИСКПОЗ(1;$A:$A;)+1):ИНДЕКС(G:G;СТРОКА()-1))-2*СУММЕСЛИ($F$1:ИНДЕКС(F:F;СТРОКА()-1);$F14;G$1)
В ячейках Столбца А выше шапки не должно быть единицы
Изменено: _Boroda_ - 01.04.2025 17:14:31
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 16:29:29
Цитата
Павел \Ʌ/ написал:
т.е. условная "7" может быть и выше (месяцев)
Да, действительно. Тогда ориентироваться на тот столбец, где точно не будет ничего меняться. Например
ПОИСКПОЗ(1;A:A;)
Цитата
Павел \Ʌ/ написал:
.а так конечно баловство все это ;-)
О, золотые слова!!!
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 16:07:30
Цитата
Павел \Ʌ/ написал:
чуть некорректно - там во все "серые" надо копировать )
А кто ж мешает растянуть формулу вправо и потом все это вставить во все серые?
Цитата
Павел \Ʌ/ написал:
потом есть желание у некоторых строки вставлять/удалять выше таблицы
Тоже никто не мешает
Цитата
Павел \Ʌ/ написал:
поэтому я и привязался к шапке
Я тоже ))))
Но, я так вижу, тут файл какой-то непостоянный, с неопределенной шапкой. Потому и написал
Цитата
_Boroda_ написал:
Вероника Суворова , определитесь как-то поконкретнее - ...
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Умная таблица, суммпроизв, выставление фильтров.
 
#
01.04.2025 16:02:00
Цитата
JRO написал:
тормоза из-за формул массива с фигурными скобками.
Не совсем так. Наличие или отсутствие именно фигурных скобочек вообще ни на что не влияет. Например, обычная формула
=СУММПРОИЗВ(G6:G10*H6:H10)
ничем не отличается от массивной
=СУММ(G6:G10*H6:H10)
Просто разные способы ввода.
Важно не то, массивная формула или нет, а что и как она считает

А почему тормоза - Вам уже рассказали выше. И даже не один раз)))) И да, СУММЕСЛИМН посчитает быстрее
Цитата
Павел \Ʌ/ написал:
о тоже самое посчитает СУММЕСЛИМН, причём ещё быстрее:
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 15:40:15
Цитата
Вероника Суворова написал:
К сожалению считает в шапке и выше
Вероника Суворова, определитесь как-то поконкретнее - что же у Вас в шапке и выше может быть. Формуле нужно за что-то зацепиться, чтобы найти верх таблицы. Например, название первого столбца таблицы, которое ВСЕГДА будет именно таким. Или, как в Вашем примере, нумерация столбцов. Или еще что-нибудь
Изменено: _Boroda_ - 01.04.2025 15:41:52
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 15:36:06
Такой вариант для g11
=СУММ(ИНДЕКС(G:G;ПОИСКПОЗ(СТОЛБЕЦ();G:G;)+1):ИНДЕКС(G:G;СТРОКА()-1))-2*СУММЕСЛИ($F$1:ИНДЕКС(F:F;СТРОКА()-1);$F11;G$1)
Изменено: _Boroda_ - 01.04.2025 15:37:54
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Внутритабличные итоги, Какую формулу использовать или без макроса никак?
 
#
01.04.2025 15:24:51
Цитата
ZVI написал:
Несмотря на то, что эти формулы со СМЕЩ() каждый раз пересчитываются,
Дык можно же написать тоже ИНДЕКС
=СУММ(ИНДЕКС(G:G;2):ИНДЕКС(G:G;СТРОКА()-1))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Перенос текста из строки, Как перенести текст по строкам
 
#
01.04.2025 15:18:27
Цитата
Soni написал:
в примере 4
В ПРИМЕРЕ одна строка. В решении 4. Однотипных. А что будет, если вот так:
Зеленая слива 1 250 гр по цене 1250 руб
Поэтому и нужно в подобных случаях давать как можно больше информации
Изменено: _Boroda_ - 01.04.2025 15:19:01
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Изменяется размер примечаний, Со временем меняется размер выводимого на экран примечания
 
#
28.03.2025 12:14:05
Топните мышой не на само примечание, а на его границу
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
заменить цифры после последней точки
 
#
27.03.2025 15:37:45
Код
=СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(A1;".";".ххх      ";3);15))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Подсчёт ячеек с датой текущего месяца, Не хочет работать формула
 
#
27.03.2025 14:18:38
У Вас там дата выдачи. Предположу, что она не может быть в будущем. Тогда можно
Код
=СЧЁТЕСЛИ(A3:A22;">"&(СЕГОДНЯ()-ДЕНЬ(СЕГОДНЯ())))

Код
=СЧЁТЕСЛИ(A3:A22;">="&ТЕКСТ(СЕГОДНЯ();"М.Г"))
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Обрезка текста в ячейке после второго пробела
 
#
27.03.2025 14:07:25
Еще
Код
=СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(A1;" ";ПОВТОР(" ";999);1+СЧЁТЕСЛИ(A1;"* * *"));999))

Или
Код
=ЛЕВБ(A1;ПОИСК(A1;ПОДСТАВИТЬ(A1;" ";A1;1+СЧЁТЕСЛИ(A1;"* * *")))-1)

Вторая не сработает на тексте без пробелов вообще. Впрочем, как и формула из поста #16
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Умная таблица, суммпроизв, выставление фильтров.
 
#
25.03.2025 15:01:49
Конечно тормозит! Вы в СУММПРОИЗВ запихали весь столбец. Замените все типа Продажи!$O:$O на Продажи!$O$3:$O$9999
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Перевод часов в десятичную дробь с условием текста
 
#
25.03.2025 10:44:45
Код
=(ЛЕВБ(A2;ПОИСК(" ";A2))+ПСТР(A2;ПОИСК(".";A2)+2;9))*24
Скажи мне, кудесник, любимец ба’гов...
 
Перейти    
Страницы: 1 2 3 4 5 6 7 8 9 10 11 ... 56 След.
Наверх