Sub Edit_PDFs_In_Word()
' ZVI:2024-02-06 https://www.planetaexcel.ru/forum/index.php?PAGE_NAME=read&TID=162848
  
  '=> Change In/Out folders to suit
  Const InFldr = "D:\InPdf"
  Const OutFldr = "D:\OutPdf"
  '<=
  
  Const wdExportFormatPDF = 17
  Dim WordApp As Object, WordContent As Object, File As Object
  
  If Dir(InFldr, vbDirectory) = "" Then
    MsgBox "Input Folder not found " & InFldr, vbCritical
    Exit Sub
  End If
  
  If Dir(OutFldr, vbDirectory) = "" Then
    MsgBox "Output Folder not found " & OutFldr, vbCritical
    Exit Sub
  End If
 
  Set WordApp = CreateObject("Word.Application")
  WordApp.Visible = True
  WordApp.Activate
  
  For Each File In CreateObject("Scripting.FileSystemObject").GetFolder(InFldr).files
    With WordApp.Documents.Open(Filename:=File.Path, ConfirmConversions:=False)

      Set WordContent = .Content
      
      ' ... Edit WordContent here ...
      
      .ExportAsFixedFormat OutputFileName:=OutFldr & "\" & File.Name, ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False

      .Close False
      Set WordContent = Nothing
      
    End With

  Next
  
  WordApp.Quit False
  Set WordApp = Nothing

End Sub

Sub Edit_Pdfs_In_Word()
' ZVI:2024-02-07 https://www.planetaexcel.ru/forum/index.php?PAGE_NAME=read&TID=162848
  
  '=> Change In/Out folders to suit
  Const InFldr = "D:\InPdf"
  Const OutFldr = "D:\OutPdf"
  '<=
  
  Const wdExportFormatPDF = 17
  Dim WordApp As Object, WordContent As Object, oWordPar As Object, File As Object
  Dim IsTotal As Boolean
  
  If Dir(InFldr, vbDirectory) = "" Then
    MsgBox "Input Folder not found " & InFldr, vbCritical
    Exit Sub
  End If
  
  If Dir(OutFldr, vbDirectory) = "" Then
    MsgBox "Output Folder not found " & OutFldr, vbCritical
    Exit Sub
  End If
 
  Set WordApp = CreateObject("Word.Application")
  WordApp.Visible = True
  WordApp.Activate
  
  For Each File In CreateObject("Scripting.FileSystemObject").GetFolder(InFldr).files
    With WordApp.Documents.Open(Filename:=File.Path, ConfirmConversions:=False)
      For Each oWordPar In .Range.Paragraphs
        If oWordPar.Range Like "EUR*" Then
          oWordPar.Range = "EUR 0.00"
        ElseIf oWordPar.Range Like "*Total Amount*" Then
          IsTotal = True
        ElseIf oWordPar.Range Like "*UZS*" Then
          If IsTotal Then
            oWordPar.Range = "UZS 0.00"
            Exit For
          Else
            oWordPar.Range = ""
          End If
        End If
      Next
      .ExportAsFixedFormat OutputFileName:=OutFldr & "\" & File.Name, ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
      .Close False
    End With
  Next
  
  WordApp.Quit False
  Set WordApp = Nothing

End Sub

Sub Edit_Pdfs_In_Word3()
' ZVI:2024-02-09 https://www.planetaexcel.ru/forum/index.php?PAGE_NAME=read&TID=162848
  
  '=> Change In/Out folders to suit
  Const InFldr = "D:\InPdf"
  Const OutFldr = "D:\OutPdf"
  '<=
  
  Const wdExportFormatPDF = 17, wdPaperLegal = 4
  Dim WordApp As Object, File As Object
  
  If Dir(InFldr, vbDirectory) = "" Then
    MsgBox "Input Folder not found " & InFldr, vbCritical
    Exit Sub
  End If
  
  If Dir(OutFldr, vbDirectory) = "" Then
    MsgBox "Output Folder not found " & OutFldr, vbCritical
    Exit Sub
  End If
 
  Set WordApp = CreateObject("Word.Application")
  WordApp.Visible = True
  WordApp.Activate
  
  For Each File In CreateObject("Scripting.FileSystemObject").GetFolder(InFldr).files
    With WordApp.Documents.Open(Filename:=File.Path, ConfirmConversions:=False)
      .PageSetup.PaperSize = wdPaperLegal
      With .Tables(2).Columns(3)
        .Cells(2).Range = "EUR 0.00"
        .Cells(3).Range = ""
        .Cells(4).Range = ""
        .Cells(5).Range = "UZS 0.00"
      End With
      .ExportAsFixedFormat OutputFileName:=OutFldr & "\" & File.Name, ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False
      .Close False
    End With
  Next
  
  WordApp.Quit False
  Set WordApp = Nothing

End Sub