Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
При вводе значения в ячейку, нужно автоматическое появление значение в соседней ячейке
 
#1
13.06.2014 11:02:08
Всем доброго дня! Нужен ваш совет и помощь. В столбце "А" я указываю тоннаж , нужно чтобы в столбце "B" автоматом от тоннажа проставлялась цена, Хочется воспользоваться средствами VBA ,чтобы  зашить эти цены и не пользоваться функцией ВПР.
 
 
 
#2
13.06.2014 11:07:08
Цитата
Vetalb пишет: чтобы зашить эти цены и не пользоваться функцией ВПР.
Куда "зашить"? а если цена поменяется, что будете делать?
 
 
 
#3
13.06.2014 11:13:38
Правильно Михаил говорит - не нужно "зашивать": создайте таблицу соответствий на соседнем листе и с помощью VBA забирайте оттуда данные.  
 
 
 
#4
13.06.2014 11:22:47
Вариант в файле.
 
 
 
#5
13.06.2014 11:48:04
Если поменяется в ее в VBA сам и поменяю
 
 
 
#6
13.06.2014 11:51:05
Юрий Спасибо , вариант то что надо, а чтобы в сам макрос цены залить такой вариант можете показать, чтобы не было другого листа.
 
 
 
#7
13.06.2014 11:58:21
Во-первых - слишком много "забивать". Используйте Select Case.
Во-вторых - потом, если придётся редактировать - каждый раз менять код?
Зачем Вам это? Просто спрячьте лист-справочник.
 
 
 
#8
13.06.2014 12:00:32
Цитата
Vetalb пишет: чтобы не было другого листа.
его можно скрыть или очень скрыть если он вам глаза мозолит.
 
 
 
#9
13.06.2014 12:05:39
Спасибо за совет, а если добавить дополнительное условие имя подрядчика пример прикладываю  Лист 3 имена подрядчиков Под1 , Под2 , ПОд3
 
 
 
#10
13.06.2014 12:10:46
Вот пример
 
 
 
#11
13.06.2014 12:10:50
Если уж "зашить" очень хочется, то можно так:
Код
Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("A2:A1000")) Is Nothing Then
        Application.EnableEvents = False
        Select Case (Target)
            Case 10: Target.Offset(0, 1) = 1524168
            Case 11: Target.Offset(0, 1) = 1534418
            Case 12: Target.Offset(0, 1) = 1552312
            '...Продолжение
        Case Else
                MsgBox "Такого значения не найдено.", 48, "Ашыпка!"
                Target.Offset(0, 1) = ""
        End Select
    End If
    Application.EnableEvents = True
End Sub
Цитата
Vetalb пишет: а если добавить дополнительное условие...
А вот по этому поводу - нужно сразу было говорить
 
 
 
#12
13.06.2014 12:17:07
Так ничего ведь не меняется:

Код
Select Case (Target & target.offset(,1))
      Case "10Под2": Target.Offset(0, 2) = 1524168
и т.д.  :)

Но конечно это не дело. Да и может строк кода не хватить :(
Изменено: Hugo - 13.06.2014 12:19:22
 
 
 
#13
13.06.2014 12:19:21
Юрий М,  Да я начинал также через Case забивать понял , что долгая история.
 
 
 
#14
13.06.2014 12:20:09
Цитата
Юрий М пишет: А вот по этому поводу - нужно сразу было говорить
Забыл упомянуть  :(
 
 
 
#15
13.06.2014 12:23:05
Цитата
Vetalb пишет: Да я начинал также через Case забивать понял , что долгая история.
Зачем тогда спрашивали, как "зашить"?))
===
Посмотрел Ваш второй файл - плохой пример: например, тоннажу 10 соответствуют несколько подрядчиков - кого из них считать за "правильного"? Это я просто ради интереса спрашиваю...
 
 
 
#16
13.06.2014 12:27:51
Может вариант есть другой поэтому и интересуюсь и я не знал как сделать чтобы сразу значение появлялось. Я в листе 1 добавил столб для подрядчик который нас интересует. Если поможете с этим вопросом , тему можно будет закрывать.
 
 
 
#17
13.06.2014 12:30:50
Да Вы даже код не сохранили в новом примере. Вам лень? Мне тоже.
 
 
 
#18
13.06.2014 12:31:44
Мне не лень сейчас попробую еще раз у меня файл не загружался сюда с кодом
 
 
 
#19
13.06.2014 12:32:32
Цитата
Vetalb пишет: у меня файл не загружался сюда с кодом
Это Вы серъёзно?
 
 
 
#20
13.06.2014 12:34:22
Ваш первый код.
 
 
 
#21
13.06.2014 12:41:00
Цитата
Юрий М пишет:
Это Вы серъёзно?
Серьезно
 
 
 
#22
13.06.2014 12:58:17
Код
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Rng As Range, iColumn As Integer
    If Not Intersect(Target, Range("A2:A1000")) Is Nothing Then
        Application.EnableEvents = False
        With Sheets("Лист2")
            Set Rng = .Rows(4).Find(what:=Target.Offset(0, 1), LookIn:=xlValues, lookAt:=xlWhole)
            If Not Rng Is Nothing Then
                iColumn = Rng.Column
                Set Rng = .Columns(iColumn).Find(what:=Target, LookIn:=xlValues, lookAt:=xlWhole)
                If Not Rng Is Nothing Then
                    Target.Offset(0, 2) = Rng.Offset(0, 1)
                Else
                    MsgBox "Такого тоннажа не найдено.", 48, "Ашыпка!"
                    Target.Offset(0, 2) = ""
                    Application.EnableEvents = True
                    Exit Sub
                End If
            Else
                MsgBox "Такого подрядчика не найдено.", 48, "Ашыпка!"
                Target.Offset(0, 1) = ""
                Application.EnableEvents = True
                Exit Sub
            End If
        End With
    End If
    Application.EnableEvents = True
End Sub
 
 
 
#23
13.06.2014 12:58:57
Как вариант - сперва найти в строке подрядчика, затем (если его нашли) искать в этом столбце ниже тоннаж (диапазоны поиска в коде можно ограничить, чтоб лишнего не найти, ну или оперативно его определить).
 
 
 
#24
13.06.2014 13:22:44
Юрий М, Спасибо Огромное.
На последок Юрий посоветуйте книгу по макросам на данный момент я закончил "Мэтью Харрис программирование MS Excel за 21 день".
 
 
 
#25
13.06.2014 13:29:00
Обратите внимание на совет Игоря (Hugo) по поводу ограничения диапазона: для тоннажа 10 и Подрядчика1 будет найдено значение "12/18" в ячейке D289.
По литературе: я в своё время читал Уокенбаха, многие советуют Гарнаева. Ну лучший учебник - форум: смотрите чужие решения, анализируйте их. "Полезняшки" сохраняйте у свою "Копилку".
 
 
 
#26
13.06.2014 13:38:27
Пока Юрий писал код, я немного подглядывал  :)
Я бы всё лишнее убрал ниже данных, через пустую строку, а искал тоннаж в intersect(Rng.currentregion, .Columns(iColumn))
Ну как-то так.
А изменение удобнее отслеживать по тому столбцу, который последний заполняется, или по обоим - при условии что соседний уже заполнен.
 
 
 
#27
13.06.2014 15:20:23
Всем Спасибо!
 
 
 
#28
05.11.2025 13:30:55
Юрий М
Здравствуйте! Воспользовался Вашим макросом, очень помогло, спасибо!
Но обнаружилась ошибка, своими силами не удаётся решить, помогите пожалуйста!
При вставке новой строки ругается на:
Target.Offset(0, 1) = Rng.Offset(0, 1)
Изменено: Андрей Максимов - 05.11.2025 13:32:21
 
 
 
#29
05.11.2025 13:38:37
Код
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Rng As Range
    If Not Intersect(Target, Range("A2:A1000")) Is Nothing Then
        If Target.Cells.CountLarge = 1 Then
            With Sheets("Лист2")
                Set Rng = .Columns(1).Find(what:=Target, LookIn:=xlValues, lookAt:=xlWhole)
                If Not Rng Is Nothing Then
                    Target.Offset(0, 1) = Rng.Offset(0, 1)
                Else
                    MsgBox "Такого значения не найдено.", 48, "Ашыпка!"
                    Target.Offset(0, 1) = ""
                End If
            End With
        End If
    End If
End Sub
 
 
 
#30
05.11.2025 14:04:10
Спасибо Вам большое! Сам бы не смог.
я копался не в ту сторону! Буду изучать countLarge
спасибо!
 
 
 
Страницы: 1
Читают тему
Наверх