Да, ещё важно - если предвидится большое количество строк - то тип Integer для переменной числа строк не годится, ставьте Long.  
Я вообще всегда ставлю Long или Byte, если до 256.

Сейчас Ваш код переделывать некогда, другим занят.  
Но взять в массив просто:  
 
Dim a  
a=[a1:b100]
 
Вот у Вас в массиве a данные из 200 ячеек. Содержимое массива смотрите в окне Locals.

Счас поищу - что-то мне казалось, что до как раз (т.е. 255 включительно :))

>>a=[a1:b100].Value
Я сам обалдел, кода первый раз увидел) Бац, и массив)  
 
Sub io()  
Dim v, x  
With Sheets("СПБ")  
v = .Range(.[A3], .Cells(.UsedRange.Rows.Count, "R")).Value ' массив таблицы
ReDim x(1 To UBound(v), 1 To 18)  
End With  
End Sub

255+1 :)

Вот, переделал Ваш Sub Формирование_Отгрузки_ЦИКЛ() на массив:  
 
 
Sub Формирование_Отгрузки_МАССИВ()  
   On Error Resume Next  
   Sheets("СПБ").ShowAllData    'Снимаем условия фильтрации, если они есть  
   'тут надо сделать динамическое определение заполненного диапазона для очистки!  
   Sheets("ОТГРУЗКА").Range("A3:J99").ClearContents    'Очищаем предыдущие результаты выборки  
   Dim Row As Long    ' количество строк для прохода циклом  
   Dim NRow As Long    '№ строки для вставки результата в отгруз. листе  
   Dim Data_Otgr As Date    'дата на которую формируем отгрузку  
   Dim a    'это будет исходный массив  
   '  
   Data_Otgr = InputBox("Введите дату отгрузки товара в формате ДД.ММ.ГГ")  
   If Data_Otgr = Empty Then Exit Sub  
 
   'берём исходные данные в массив  
   With Sheets("СПБ")  
       a = .Range("R3:A" & .Cells(.Rows.Count, 1).End(xlUp).Row)  
   End With  
 
   'создаём массив для результата отбора  
   'высота с исходный, ширина как нужно  
   ReDim b(1 To UBound(a), 1 To 9)  
     
   'перебор массива  
   For Row = 1 To UBound(a)  
       If Data_Otgr = a(Row, 12) Then  
           NRow = NRow + 1  
           '===>  
           b(NRow, 1) = a(Row, 4)    'Заявка  
           b(NRow, 2) = a(Row, 8)    'Материал  
           b(NRow, 3) = a(Row, 1)    'Кто  
           b(NRow, 4) = a(Row, 2)    'Кому  
           b(NRow, 5) = a(Row, 3)    'Договор  
           b(NRow, 7) = a(Row, 9)    'Наименование  
           b(NRow, 8) = a(Row, 10)    'Кол -во  
           b(NRow, 9) = a(Row, 18)    'Цена  
           '===>  
       End If  
   Next Row  
   Sheets("ОТГРУЗКА").Range("I1") = Data_Otgr  
   If NRow = 0 Then  
       MsgBox "На данную дату отгрузок нет!"  
   Else  
       'выгрузка результатов  
       Sheets("ОТГРУЗКА").Range("A3:I3").Resize(NRow) = b  
   End If  
End Sub

Да, ещё - использовать имя Row для переменной не есть хорошо...  
Я обычно использую i, ii, iii и т.д. для циклов - тут бы как раз вместо Row взять i, а вместо NRow взять ii.

Счас совсем человека запутаешь :)  
 
Я взял код как есть и с минимальными изменениями переделал на массив - если два кода поставить рядом, то хорошо видно, что на массиве даже код проще и по объёму меньше, чем при работе с ячейками напрямую.

совсем забыл, Dim b )))

with Sheets(1) ' C объектом  
' точка - обращение к with Sheets(1) (т.е. объекту)  
'Диапазон(Верхняя правая ячейка, ОтВерхнейЛевойКАоследнейЯчейке этого(1) столбца).Значения  
a = .Range(.[R3], .Cells(.Rows.Count, 1).End(xlUp)).value
end with

Пусть затирает, меня устраивает, в моём коде данные подтягиваю после вставки массива.  
На скрине видны различия как заполняется результирующий массив  в исходном варианте, и предложного Nerv, мне нужна эта пустая строчка (6), пока нужна, пока шаблон отчётности не переделал :) А может буду просто столбец потом вставлять.

\массив массивов : )

1 - номер столбца  
 
v = Array(Array(1, 2, 3, 4, 5, 7, 8, 9), Array(4, 8, 1, 2, 3, 9, 10, 18)) ' массив массивов  
 
               For j = 0 To 7  
                   b(i, v(0)(j)) = a(q, v(1)(j))  
               Next

{quote}{login=nerv}{date=14.10.2011 03:03}{thema=}{post}\массив массивов : ){/post}{/quote}  
Nerv, спасибо, но не дорос я ещё до такого кода. Понадобиться что-то осознанно изменить и буду весь день думать. Оставлю прежний вариант, а этот отложу на будущее для разбора.