МT ABC = 
IF (
    HASONEVALUE ( 'Bi бренд'[id_brend] ), // тут убираю пустые значения
    VAR brend_obem =
        ADDCOLUMNS (
            ALLSELECTED ( 'спрБренд' ),
            "@brend_obem", [М объём]    //здесь считаю весь объём (что бы на него поделить)
        )
    VAR brend_obem_Fix = [М объём]    // фиксирую объём
    VAR brend_obem_Filter =
        FILTER (
            brend_obem,
            [@brend_obem] >= brend_obem_Fix // в таблице отбираю равно и больше
        )
    VAR brend_obem_Cumal =
        SUMX (
            brend_obem_Filter,
            [@brend_obem]
        )
    VAR brend_obem_All =
        CALCULATE (
            [М объём],
            ALLSELECTED ()
        )
    VAR brend_obem_Proc = DIVIDE(brend_obem_Cumal , brend_obem_All)
    VAR result =
        SWITCH (
            TRUE (),
            [_М объём not blank], BLANK (),
            //brend_obem_Proc<=0.5, "A",
            brend_obem_Proc <= 0.8, "A",
            brend_obem_Proc <= 0.95, "B",
            "C"
        )
    RETURN
        result
)