Private Sub Worksheet_Change(ByVal Target As Range)
  If Not Intersect(Target, Columns(2)) Is Nothing Then
    Application.EnableEvents = False
    Dim mo As Object
    Dim j As Integer
    Dim iMin As Double
    Dim iMax As Double
     With CreateObject("VBScript.RegExp")
         .Global = True
         .IgnoreCase = True
         .Pattern = "[^;]+"
         Set mo = .Execute(Target.Offset(, -1))
         For j = 0 To mo.Count - 1
           iMin = Application.Trim(Split(mo(j), "-")(0))
           iMax = Application.Trim(Split(mo(j), "-")(1))
           If Target > iMin And Target < iMax Then
             Target.Offset(, 1) = j + 1
             Target.Offset(, 2) = iMin
             Target.Offset(, 3) = iMax
             Target.Offset(, 4) = mo(j)
             Exit For
           End If
         Next
           If Target.Offset(, 2) = "" Then Target.Offset(, 1) = "  Число не попало ни в одну из групп"
     End With
  End If
    Application.EnableEvents = True
End Sub

Function GUREEV(rngs$, num#, Optional prop = 1)
'rngs - Строка или ссылка на ячейку с диапазонами. Должно быть не менее двух диапазонов. Обязательный
'num - Проверяемое значение. Обязательные
'prop - Возвращаемое свойство. Не обязательный. По умолчанию - 1
    '1 - Номер диапазона
    '2 - Минимум
    '3 - Максимум
    '4 - Диапазон
Dim arrRngs, I&
    arrRngs = Split(Replace(rngs, " ", ""), ";")
    ReDim arrR(0 To UBound(arrRngs), 0 To 1)
    For I = 0 To UBound(arrRngs)
        arrR(I, 0) = CDbl(Split(arrRngs(I), "-")(0))
        arrR(I, 1) = CDbl(Split(arrRngs(I), "-")(1))
    Next
    For I = 0 To UBound(arrR)
        If num >= arrR(I, 0) And num < arrR(I, 1) Then
            Select Case prop
                Case 1
                    GUREEV = I + 1
                Case 2
                    GUREEV = arrR(I, 0)
                Case 3
                    GUREEV = arrR(I, 1)
                Case 4
                    GUREEV = arrR(I, 0) & "-" & arrR(I, 1)
            End Select
            Exit For
        End If
    Next
    If IsEmpty(GUREEV) Then GUREEV = CVErr(xlErrNA)
End Function