Sub SQL_Query_To_Smart_Table()
'ВАЖНО: есть ограничение SQL при указании адреса диапазона (A1:Z100) в 65536 строк, либо надо указывать полностью A:Z
    Dim sTblQuery As String, SheetName As String, Table_SourceAddress As String, sSQL_text As String, sConnStr As String
    Dim dtData1 As Date, dtData2 As Date
    Dim i As Long
    
    SheetName = "Лист1"
    dtData1 = Worksheets(SheetName).Cells(3, 21).Value 'начальная дата
    dtData2 = Worksheets(SheetName).Cells(3, 22).Value 'конечная дата
    
    Table_SourceAddress = Worksheets(SheetName).ListObjects("Таблица1").Range.Address(0, 0)
    sTblQuery = "[" & SheetName & "$" & Table_SourceAddress & "]"
    
    'Вариант 1
    Dim oRecordSet As Object, oConn As Object
    Set oRecordSet = CreateObject("ADODB.Recordset")
    Set oConn = CreateObject("ADODB.Connection")
    
    'Вариант 2
    'нужно добавить ссылку на Microsoft ActiveX Data Objects 6.1 Library, то
    '    Dim oConn As New ADODB.Connection
    '    Dim oRecordSet As New ADODB.Recordset
     
    oRecordSet.CursorLocation = 3 'adUseClient ' включает возможность order by
    'Вариант 1 с использованием функции Format
    'sSQL_text = "SELECT * FROM " & sTblQuery & " WHERE ([Дата] >= #" & Format(dtData1, "MM\/dd\/yy hh\:mm\:ss") & "#) AND ([Дата] <= #" & Format(dtData2, "MM\/dd\/yy hh\:mm\:ss") & "#)"
    'Вариант 2 с использованием функции DataSql
    sSQL_text = "SELECT * FROM " & sTblQuery & " WHERE ([Дата] >= " & DataSql(dtData1) & ")" & " AND ([Дата] <= " & DataSql(dtData2) & ")"
     
    sConnStr = "Provider=Microsoft.ACE.OLEDB.12.0;Mode=Read;Data Source=" & ThisWorkbook.FullName & ";Extended Properties=""Excel 12.0;HDR=YES"";"
    oConn.Open sConnStr
    oRecordSet.Open sSQL_text, oConn
    oRecordSet.Sort = "[Дата] ASC,[Смена] DESC" 'order by
    
    'выгрузка запроса на Лист2
    With Worksheets("Лист2")
        .Cells.Clear
        .Range("A2").CopyFromRecordset oRecordSet
        'заголовки таблицы
        For i = 0 To oRecordSet.Fields.Count - 1
            .Cells(1, i + 1) = oRecordSet.Fields(i).Name
        Next i
    End With

    oRecordSet.Close
    oConn.Close

    Set oRecordSet = Nothing
    Set oConn = Nothing

    MsgBox "Запрос выполнен!", vbInformation, ""
End Sub

Private Function DataSql(dt_sql)
    DataSql = "#" & Format(dt_sql, "mm\/dd\/yy hh\:mm\:ss") & "#"
End Function