Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Перевести 60 сут 6 ч 36 мин в часы
 
#1
02.04.2014 12:31:26
[CODE][/CODE]
Все доброго дня
есть данные в таблице
219 сут 20 ч 13 мин
1257 сут 2 ч 2 мин

надо переводить в часы?
как сутки достать примерно понял, как теперь остальное вытянуть?

=ЛЕВСИМВ(D24;((ПОИСК(" ";D24;1))-1))
Изменено: Borisovich - 02.04.2014 18:58:52
 
 
 
#2
02.04.2014 12:33:33
Borisovich, пункт правил 2,3
Лень двигатель прогресса, доказано!!!
 
 
 
#3
02.04.2014 12:39:25
не могу прикрепить к своему сообщению  555.xlsx (8.5 КБ)
 
 
 
#4
02.04.2014 12:40:34
Код
?
1
=ЛЕВСИМВ(B3;((ПОИСК(" ";B3;1))-1))*24+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(B3;"ч";":");"мин";"");"сут";"  ");7))
Изменено: Nic70y - 02.04.2014 12:45:14 (изменил, под пример)
 
 
 
#5
02.04.2014 12:45:42
1257 сут 2 ч 2 мин
получилось а на меньших нет
спасибо за оперативный ответ

если число байтов ((ЛЕВБ(A1;5) уменьшаю до 4 работает там где 3 знака в сутках, до 2х где 2 знака в сутках
Изменено: Borisovich - 17.06.2014 12:07:01
 
 
 
#6
02.04.2014 12:51:27
я ошибся
Код
?
1
=ЛЕВСИМВ(A1;((ПОИСК(" ";A1;1))-1))*24+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A1;"ч";":");"мин";"");"сут";"  ");8))
поспешил
 
 
 
#7
02.04.2014 12:51:58
работает!
 
 
 
#8
02.04.2014 12:52:44
Nic70y, я тоже вашу формулу подкоректировал маленько


Код
?
1
=ПОДСТАВИТЬ(ПСТР(B3;1;ПОИСК(" сут ";B3;1));"сут";"")*24+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(B3;"ч";":");"мин";"");"сут";"  ");7))
Лень двигатель прогресса, доказано!!!
 
 
 
#9
02.04.2014 12:54:21
См. №6, в №4 не верно
 
 
 
#10
02.04.2014 12:55:55
начал проверять из
1 сут 23 ч 15 мин
получается
24,13541667
должно быть 47,25
 
 
 
#11
02.04.2014 13:02:36
Код
?
1
=ЛЕВСИМВ(E9;((ПОИСК(" ";E9;1))-1))*24+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(E9;"ч";":");"мин";"");"сут";"  ");8))*24
*24
Код
?
1
=(ЛЕВСИМВ(E9;((ПОИСК(" ";E9;1))-1))+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(E9;"ч";":");"мин";"");"сут";"  ");8)))*24
Изменено: Nic70y - 02.04.2014 13:04:13
 
 
 
#12
02.04.2014 13:04:56
работает =
но на 1257 сутках не хочет дает значения
557.xlsx (10.26 КБ)
спасибо!
 
 
 
#13
02.04.2014 13:05:30
еще один вариант формулы Nic70y, вроде работает


Код
?
1
=ПСТР(B3;1;ПОИСК(" сут ";B3;1)-1)*24+СЖПРОБЕЛЫ(ПРАВБ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(B3;"ч";":");"мин";"");"сут";"  ");7))
извиняюсь за нарушение авторских прав
Изменено: Сергей - 02.04.2014 13:07:15
Лень двигатель прогресса, доказано!!!
 
 
 
#14
02.04.2014 13:11:51
Код
?
1
=(ЛЕВБ(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";99));99)+СЖПРОБЕЛЫ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПРАВБ(ПОДСТАВИТЬ(A2;"т";"  ");12);"мин";"");"ч";":")))*24
 
 
 
#15
02.04.2014 13:55:41
Код
?
1
=(ПСТР(A2;1; ПОИСК(" ";A2))+ВРЕМЗНАЧ(ПОДСТАВИТЬ(ПОДСТАВИТЬ(ПСТР(A2;ПОИСК("сут";A2)+3;20);"ч";":");"мин";"")))*24
 
 
 
#16
03.04.2014 05:34:14
Работает полностью формула Михаил С. - спасибо!
формула Nic70y - частично
формула Сергей - ошибки выдает
пример проверки формула прилагаю
558.xlsx (12.63 КБ)

Спасибо всем!
 
 
 
#17
03.04.2014 07:40:47
подкоректировал свой вариант, ща вроде проверку проходит


Код
?
1
=ПСТР(B3;1;ПОИСК(" сут ";B3;1)-1)*24+ПОДСТАВИТЬ(ПСТР(B3;ПОИСК(" сут ";B3;1)+5;(ДЛСТР(B3)-ПОИСК(" сут ";B3;1)+5)-12);" ч ";":";1)*24
Лень двигатель прогресса, доказано!!!
 
 
 
#18
03.04.2014 07:48:03
Сергей , спасибо! работает
 
 
 
#19
03.04.2014 08:11:57
А у меня работает  :)  
У Вас в моем формуле вместо двух пробелов символ 160  :)
Изменено: Nic70y - 03.04.2014 08:15:21
 
 
 
#20
17.06.2014 11:32:34
спустя  время понадобилось опять перевод суток в часы- у себя не нашел - только тут - еще раз спасибо Nic70y  Сергей  Михаил С.-. выкладываю рабочие три варианта с проверкой
 
 
 
#21
26.06.2014 10:22:25
есть функция которая переводит  часы в текстовый вариант?
пример
13:14:00
в 13 часов 14 минут
цель подстановка в формулу СЦЕПИТЬ
как склонять часы и минуты я нашел

Код
?
1
=ЕСЛИ(ОСТАТ(F9;ЕСЛИ(F9<0;1;1))>0;"часа";ЕСЛИ(И(ОСТАТ(F9;100)>=11;ОСТАТ(F9;100)<=14);"часов";ВПР(ОСТАТ(F9;10);{0;"часов":1;"час":2;"часа":3;"часа":4;"часа":5;"часов":6;"часов":7;"часов":8;"часов":9;"часов"};2)))


а как выцепить по отдельности часы и минут не знаю
Изменено: Borisovich - 26.06.2014 10:22:47
 
 
 
#22
26.06.2014 10:34:28
вот как вышло
- прочитав http://excel2.ru/articles/preobrazovanie-chisel-v-format-vremya сообразил
 
 
 
#23
26.06.2014 10:43:06
осталось сообразить как убрать "0 часов" 15 минут в фразе "0 часов 15 минут"
 
 
 
#24
26.06.2014 20:11:18
Интереснее было сообразить, как изменить формулу  :)  
Код
?
1
=ЕСЛИ(ЧАС(A1);ЧАС(A1)&" час"&ВЫБОР(МИН(ПРАВБ(ЧАС(A1));5)+1;"ов";;"а";"а";"а";"ов");"")&ЕСЛИ(МИНУТЫ(A1);" "&МИНУТЫ(A1)&" минут"&ВЫБОР(МИН(ПРАВБ(МИНУТЫ(A1));5)+1;;"а";"ы";"ы";"ы";);"")
Если минуты нужно отображать и при 0 мин., уберите проверку (ЕСЛИ...)
 
 
 
#25
28.04.2015 04:49:36
Доброе утро, подскажите как адаптировать формулы уже имеющиеся (лист 559) на новый формат  лист 560
5 сут. 5
 час. 51 мин.
 
 
 
Страницы: 1
Читают тему
Loading...