Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Поиск на наличие хотя бы одного совпадения в таблице
 
#1
17.07.2015 10:54:34
Добрый день.
Прошу помощи в решении одной задачи. Сижу час бьюсь, не могу понять, то ли действительно нельзя через формулу Excel провернуть задуманное,  то ли я стал совсем плохим к пятнице)

Есть диапазон таблицы A:E. Как "прошерстить" таблицу в диапазоне A:E и если хоть в одном из столбце найден номер из колонки J - в колонку F возвращалось значение "1"/Истина
прикладываю пример и результат в колонке F, как должно работать
caustic
 
 
 
#2
17.07.2015 11:03:06
вариант
Удивление есть начало познания © Surprise me!
И да пребудет с нами сила ВПР.
 
 
 
#3
17.07.2015 11:04:58
Можно попробовать вот такой формулой массива:
Код
=СУММ(--(A1:D1=$J$1:$J$4))

В F1 её, родимую, и тянуть вниз. :)
Кому решение нужно - тот пример и рисует.
 
 
 
#4
17.07.2015 11:09:27
Ёк-Мок, как вариант да. Но я думал есть более универсальный способ, через массив н-р. Спасибо
 Пытливый, Отличный способ, но он привязан к определенному кол-ву строк в диапазоне J. а это кол-во будет каждый раз разным.
caustic
 
 
 
#5
17.07.2015 11:15:55
=СУММ(--(A1:D1=$J$1:$J$4))

Объясните синтаксис, что за дв минуса вначале  :oops:
 
 
 
#6
17.07.2015 11:17:07
=СУММПРОИЗВ(СЧЁТЕСЛИ(jjj;$A1:$E1))>0
В диспетчере имён jjj:
=ИНДЕКС(Лист2!$J:$J;1):ИНДЕКС(Лист2!$J:$J;СЧЁТЗ(Лист2!$J:$J))

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#7
17.07.2015 11:17:45
еще вариант
Код
=СУММПРОИЗВ(--($J$1:$J$17=$A1:$E1)*--(""<>$A1:$E1))
Лень двигатель прогресса, доказано!!!
 
 
 
#8
17.07.2015 11:21:11
Спасибо огромное всем!
Сергей, ваш вариант на мой взгляд самый оптимальный для моей задачи. еще раз благодарю!
caustic
 
 
 
#9
17.07.2015 11:27:10
Сергей, минусы лишние в Вашей формуле. Знака умножить достаточно.

Формула массива (ФМ) вводится Ctrl+Shift+Enter
Memento mori
 
 
 
#10
17.07.2015 11:36:48
=МАКС(СЧЁТЕСЛИ(A1:E1;$J$1:$J$17))
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#11
17.07.2015 12:13:50
Непойму почему без минусов в этой формуле =СУММ(--(A1:D1=$J$1:$J$4))  в ответе ноль, в строке же есть одно совпадающее число. Блин это просто бред. Это ж сколько кислоты разработчики выжрали, чтоб такой синтаксис придумать. 8-0
Изменено: Alexey200 - 17.07.2015 12:15:37
 
 
 
#12
17.07.2015 14:47:57
=ИЛИ(НЕ(A1:E1-$J$1:$J$4))
=ИЛИ(СОВПАД(A1:E1;$J$1:$J$4))
В диапазон J не включать пустые ячейки. Вводятся как формула массива.
Без массивного ввода:
=СУММПРОИЗВ(--НЕ(A1:E1-$J$1:$J$4))
=СУММПРОИЗВ(--СОВПАД(A1:E1;$J$1:$J$4))

Цитата
почему без минусов в этой формуле =СУММ(--(A1:D1=$J$1:$J$4)) в ответе ноль
Потому что СУММ игнорирует логические значения. Бинарное отрицание преобразует логику в число.
 
 
 
#13
17.07.2015 15:15:16
Цитата
почему без минусов в этой формуле =СУММ(--(A1:D1=$J$1:$J$4))  в ответе ноль
Ув.vikttur уже написал, немного добавлю:
Если никаких математических манипуляций внутри формируемого массива не делаем, то нужно бинарное отрицание.
А если добавить, то не нужно (преобразование происходит неявно)
Код
=СУММ((A1:D1=$J$1:$J$4)*1)  
Кому решение нужно - тот пример и рисует.
 
 
 
#14
17.07.2015 15:19:32
Бинарное отрицание воспринимается как оператор и работает быстрее математических операций.
 
 
 
Страницы: 1
Читают тему
Наверх