Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Построение списка уникальных значений с условием
 
#1
25.01.2017 15:12:15
Добрый день.

Есть таблица из двух столбцов (в 1000 строк, например) в первом столбце находятся 10 различных текстовых значений, а во втором различные признаки этих  10 значений.
Нужно построить таблицу из уникальных значений первого столбца, которые проходят по условию.
Пример вложил.
Построение списка без условия я знаю:
=ЕСЛИОШИБКА(ИНДЕКС(A2:A9;ПОИСКПОЗ(СУММ(СЧЁТЕСЛИ(B$1:B1; A2:A9));СЧЁТЕСЛИ(A2:A9;"<"& A2:A9);0));" ")  а вот с условием никак.

UPD. В примере во втором столбце только "Нет" и "Да", но там могут быть и другие текстовые значения. На одном и том же имени во всём массиве всегда будет одно и тоже значение во втором столбце.
Спасибо.
Изменено: Dispershin - 25.01.2017 15:22:28
 
 
 
#2
25.01.2017 15:26:48
это легко сделать в сводных таблицах выбрав нужное значение в фильтрах или срезах (срезы доступны с 2010 офиса)
 
 
 
#3
25.01.2017 15:27:40
Да, но мне нужно именно через формулу.
 
 
 
#4
25.01.2017 15:31:46
=ЕСЛИОШИБКА(ИНДЕКС($A$2:$A$9;НАИМЕНЬШИЙ(ЕСЛИ(ЧАСТОТА(ЕСЛИ($B$2:$B$9="Да";ПОИСКПОЗ($A$2:$A$9;$A$2:$A$9;0));ПОИСКПОЗ($A$2:$A$9;$A$2:$A$9;0));СТРОКА($A$2:$A$9)-1);СТРОКА(A2)));"")
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#5
25.01.2017 15:41:18
Формула выдаёт нули
 
 
 
#6
25.01.2017 16:03:06
Предлагаю такую формулу.
Код
=IFERROR(INDEX($A:$A;AGGREGATE(15;6;ROW(A$1:A$2200)/($B$1:$B$2200="Да")/(COUNTIF(F$1:F1;$A$2:$A$2200)=0);ROWS($2:2)));"")
 
 
 
#7
25.01.2017 17:56:36
Кнопка цитирования не для ответа [МОДЕРАТОР]

Спасибо, проблема возникает теперь если в /($B$1:$B$2200="Да") я вставаляю ИЛИ с 3 условиями. Перестаёт корректно работать, можно узнать почему?
 
 
 
#8
25.01.2017 18:21:42
Покажите пример.
 
 
 
#9
25.01.2017 18:30:02
Вложил
 
 
 
#10
25.01.2017 21:06:45
Исправил-ограничил диапазон поиска индекс.
Код
=IFERROR(INDEX($A$2:$A$2200;AGGREGATE(15;6;ROW(A$1:A$2200)/($B$2:$B$2200="Профи")/(COUNTIF(D$1:D1;$A$2:$A$2200)=0);ROWS($2:2)));"")
 
 
 
#11
26.01.2017 12:08:07
Спасибо, на одно условие работает стабильно, но как я писал выше, на ИЛИ с 3мя условия не срабатывает вообще. То, что я прошу реализуемо через эту формулу?
 
 
 
#12
26.01.2017 12:15:04
Цитата
Dispershin написал:
Формула выдаёт нули
У меня нет нулей.
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#13
26.01.2017 12:18:53
=ЕСЛИОШИБКА(ИНДЕКС($A$2:$A$12;НАИМЕНЬШИЙ(ЕСЛИ(ЧАСТОТА(ЕСЛИ(МУМНОЖ(Ч($B$2:$B$12={"Профи";"Мастер";"Старый"});{1:1:1});ПОИСКПОЗ($A$2:$A$12;$A$2:$A$12;0));ПОИСКПОЗ($A$2:$A$12;$A$2:$A$12;0));СТРОКА($A$2:$A$12)-1);СТРОКА(A1)));"")
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#14
26.01.2017 13:58:21
Всё работает шикарно, спасибо)
 
 
 
Страницы: 1
Читают тему
Наверх