Sub Макрос_1()
  
  ' Задать имя книги источника
  Const SrcFileName = "книга1.xlsx"
  ' Задать перечень листов для копирования
  Const SheetNames = "Лист3,Лист4"
  
  Dim p As String
  Dim WbSrc As Workbook, WbDest As Workbook
  
  ' Путь этой книги с маросами
  p = ThisWorkbook.Path & "\"
    
  ' Отключить обновление экрана
  Application.ScreenUpdating = False
  ' Перехватывать ошибки
  On Error GoTo exit_
  
  ' Открыть файл назначения
  With Application.FileDialog(msoFileDialogFilePicker)
    .InitialFileName = p
    .AllowMultiSelect = False
    .Title = "Выберите файл, в который будут скопированы листы"
    .Filters.Clear
    .Filters.Add "Файл назначения", "*.xlsx"
    If .Show = False Then Exit Sub
    If StrComp(.SelectedItems(1), p & SrcFileName, vbTextCompare) = 0 Then
      MsgBox "Это книга-источник листов", vbExclamation, "Ошибка выбора"
      Exit Sub
    End If
    Set WbDest = Workbooks.Open(.SelectedItems(1))
  End With
  
  ' Открыть книгу-источник листов
  Set WbSrc = Workbooks.Open(p & SrcFileName, False)
  ' Скопировать листы
  WbSrc.Sheets(Split(SheetNames, ",")).Copy After:=WbDest.Sheets(WbDest.Sheets.Count)
  ' Закрыть книгу-источник
  WbSrc.Close False
  ' Сохранить книгу назначения
  WbDest.Save
  ' Закрыть книгу назначения
  'WbDest.Close
  
exit_:
  
  ' Включить обновление экрана
  Application.ScreenUpdating = True
  ' Сообщить об ошибке, если случилась 
  If Err Then MsgBox Err.Description, vbCritical, "Ошибка!"
  
End Sub