Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Количество дней в квартале, Необходимо подсчитать количество дней в квартале за минусом воскресений
 
#1
29.11.2017 10:58:13
Всем доброго дня.

Столкнулся с проблемой. У части работников показатель KPI труда напрямую зависит от количества рабочих дней (за минусом воскресений) в квартале перемноженных на объем ежедневно выполняемых работ.

Посчитать такое количество в месяце не проблема, но как это сделать в квартале? Да так, чтобы каждый новый квартал этот плановый показатель обновлялся.

Вывел себе базовые значения "года", "квартала", "месяца", его начала и конца. Но смекнуть, как из всего этого рассчитывать количество дней в текущем квартале не могу.

Может кто уже сталкивался или просто понимает, как это сделать. Буду признателен за помощь!    
 
 
 
#2
29.11.2017 11:18:09
Murlif, А8 - год, В8 - номер квартала (1..4)
Код
=СУММПРОИЗВ(--(ДЕНЬНЕД(СТРОКА(ИНДЕКС(A:A;ДАТА(A8;B8*3-2;1)):ИНДЕКС(A:A;ДАТА(A8;B8*3+1;)));2)<>7))
 
 
 
#3
29.11.2017 11:19:29
если в ячейках поставлена дата начала и конца (А1 начало, А2 конец)
Код
=ЧИСТРАБДНИ.МЕЖД(A1;A2;11)
 
 
 
#4
29.11.2017 11:33:31
Может я не так понял, но Ваша формула считает количество рабочих дней в 11 месяце. С этим проблем не было. Нужно было подсчитать такое количество в квартале, при условии, что кварталы будут сменяться и количество дней в них соответственно.

Казанский, спасибо! Работает. А можете объяснить механизм работы формулы?  
 
 
 
#5
29.11.2017 11:53:01
Murlif,
ДАТА(A8;B8*3-2;1) - первый день квартала
ДАТА(A8;B8*3+1;) - последний день квартала, можно написать также ДАТА(A8;B8*3+1;0) и ДАТА(A8;B8*3+1;1)-1
ИНДЕКС(A:A;ДАТА(A8;B8*3-2;1)) - ячейка с соотв. номером в столбце А, например сегодня это A43068
ИНДЕКС(A:A;ДАТА(A8;B8*3-2;1)):ИНДЕКС(A:A;ДАТА(A8;B8*3+1;) - диапазон, у которого номера строк соответствуют дням квартала
СТРОКА(ИНДЕКС(A:A;ДАТА(A8;B8*3-2;1)):ИНДЕКС(A:A;ДАТА(A8;B8*3+1;)) - массив дат дней квартала
ДЕНЬНЕД(СТРОКА(ИНДЕКС(A:A;ДАТА(A8;B8*3-2;1)):ИНДЕКС(A:A;ДАТА(A8;B8*3+1;)));2)<>7 - массив ЛОЖЬ/ИСТИНА (воскресенье=ЛОЖЬ)
--() - превращение ЛОЖЬ/ИСТИНА в 0/1
И суммирование.
 
 
 
#6
29.11.2017 12:57:35
Цитата
Murlif написал:
в 11 месяце
11 в формуле означает считать выходным только воскресенье
 
 
 
#7
29.11.2017 12:59:23
Цитата
Казанский написал:
--() - превращение ЛОЖЬ/ИСТИНА в 0/1
Спасибо большое. Почти всю формулу смекнул и тут же приладил ее к расчетам, где воскресенье отсеивать не нужно. Загадкой оставалось только суммирование "ложь/истина". Спасибо за разъяснения.

Вообще-то без таких форумов и людей, как вы, нам - гуманитариям до мозга костей, самоучкам по экселю, было бы не выжить.  
Изменено: Murlif - 29.11.2017 12:59:52
 
 
 
Страницы: 1
Читают тему
Наверх