Private Sub DicttVsCollTest()
    Const CntElem& = 200000
    Const CntIter& = 1
    Const minSzStr& = 5   'минимальный размер случайных строк
    Const maxSzStr& = 10  'максимальный размер случ. строк
    Dim sRndAr$()
    sRndAr = GetRndStrArray(CntElem, minSzStr, maxSzStr)
    Dim i&, j&, t!, t1!, t2!
    Dim Coll As New VBA.Collection
    
    t = Timer
    For j = 0 To CntElem - 1
        Coll.Add Empty, sRndAr(j)
    Next
    t1 = t1 + Timer - t
    
    Dim Dict As New Dictionary
    
    t = Timer
    For j = 0 To CntElem - 1
        Dict.Add sRndAr(j), Empty
    Next
    t2 = t2 + Timer - t
    
    Debug.Print "Скорость заполнения " & CntElem & " элементов: "
    Debug.Print "Коллекция: ", t1
    Debug.Print "Словарь: ", t2
    
    Dim vElem
    t1 = Timer
    For i = 1 To CntIter
        For j = 0 To CntElem - 1
            vElem = Coll(sRndAr(j))
        Next
    Next
    t1 = Timer - t1
    
    t2 = Timer
    For i = 1 To CntIter
        For j = 0 To CntElem - 1
            vElem = Dict(sRndAr(j))
        Next
    Next
    t2 = Timer - t2
    
    Debug.Print "Получение элементов: "
    Debug.Print "Коллекция: ", t1
    Debug.Print "Словарь: ", t2
    
End Sub

Function GetRndStrArray(ByVal Cnt As Long, ByVal minStrSz&, ByVal maxStrSz&) As String()
    Cnt = Cnt - 1
    Dim i&, sArOut$(): ReDim sArOut(Cnt)
    For i = 0 To Cnt
        sArOut(i) = GetRandomString(minStrSz, maxStrSz)
    Next
    GetRndStrArray = sArOut
End Function
Function GetRandomString(ByVal Lw&, ByVal Up&) As String
    Static init As Boolean, ChrTbl$, ChrTblLen&
    If init Then
    Else
      ChrTbl = "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqastuvwxyzАБВГДЕЁЖЗИЙКЛМНУФХЦЧШЩЬЫЪЭЮЯабвгдеёжзийклмнопрстуфхцчшщьыъэюя "
      ChrTblLen = Len(ChrTbl)
      Randomize
      init = True
    End If
    Dim i&, j&, strLen&: strLen = (Up - Lw + 1) * Rnd + Lw
    GetRandomString = String(strLen, vbNullChar)
    For i = 1 To strLen
        j = Int(ChrTblLen * Rnd + 1)
        Mid$(GetRandomString, i) = Mid$(ChrTbl, j, 1)
    Next
End Function