' функция удаления строк по критерию
'===================================================================================
' Sub         : DelRows(TableHeader,ColNum,DelValue)
' TableHeader : Range; table header range
' ColNum      : Long; column number with DelValue
' DelValue    : Variant; value of rows to be deleted
' DateFrom    : с какой даты начиная нужно удалять !!! ДОБАВИЛ Я.
'-------------+---------------------------------------------------------------------
' VBA call    : DelRows ActiveSheet.Range("A1:H1"), 5, 0
'-------------+---------------------------------------------------------------------
' Created     : ZVI:2009:12:26 http://www.sql.ru/forum/actualthread.aspx?tid=722758
'-----------------------------------------------------------------------------------
Sub DelRows(TableHeader As Range, ColNum As Long, DelValue, DateFrom As Date) '!!! добавил DateFrom
  Dim Arr(), r&, rs&, cs&, i&, v, ac
  With TableHeader.CurrentRegion
    rs = .Rows.Count - TableHeader.Row + .Row
    cs = .Columns.Count - TableHeader.Column + .Column
  End With
  
  With TableHeader.Resize(rs, 1)
    Arr() = .Offset(, cs).Value
    ' Arr_Date() = .Offset(, 2).Value    !!! Пытался решить задачу созданием массива-дублера (именно для колонки дат),
                                         ' но думаю что лучше как то обойтись одним массивом
    ' Check DelValue
    For Each v In .Offset(, ColNum - 1).Value
      r = r + 1
      If Not ((v = DelValue) Or (DelValue = "_CSKU" And IsNumeric(v) And v >= 1000000)) Then
                ' !!! быть хорошей строкой ты можешь только если
                ' !!! ты не содержишь: а) слова "Все" (передается в DelValue при вызове процедуры)
                ' !!! либо б) числа больше миллиона и при этом DelValue = "_CSKU"
                ' !!! Именно в этот IF надо как-то вставить проверку даты из колонки В
                ' !!! OR ((Дата из В) < DateFrom) - тогда ты всегда хорошая строка,
                ' !!! и чего бы в тебе не было, тебя мы удалять не будем
        i = i + 1  ' !!! уже при размещении файла на форуме, обратил внимание, что не понимаю откуда i взялась то...
        Arr(r, 1) = 1
      End If
    Next
    If i < rs Then
      ' Freeze on
      With Application
        .ScreenUpdating = False
        .EnableEvents = False
        ac = .Calculation: .Calculation = xlCalculationManual
      End With
      ' Delete rows with DelValue in ColNum
      .Offset(, cs) = Arr
      .Resize(, cs + 1).Sort .Cells(1).Offset(, cs), 1, Header:=xlNo
      .Resize(, 1).Offset(, cs).ClearContents
      .Resize(rs - i, cs).Offset(i).Clear   ' или .Resize(rs - i).Offset(i).EntireRow.Delete
      ' Freeze off
      With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = ac
      End With
    End If
  End With
End Sub


Sub Test_del_rows()
  DelRows ActiveSheet.Range("A1:G1"), 2, "_CSKU", #7/1/2013#
End Sub