Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1 2 След.
RSS
Убрать все символы из ячейки до определенного знака (формула)
 
#1
03.05.2013 21:41:28
Кто знает нужна формула что бы убрать из ячейки весь текст который расположен слева от заданного знака.
например текст в ячейке "opic_new&FID=1" как убрать все включая знак "&" и оставить только "FID=1"
 
 
 
#2
03.05.2013 21:52:22
Код
=ПСТР(A1;ПОИСК("&";A1)+1;99)
 
 
 
#3
09.05.2013 18:33:45
=ЗАМЕНИТЬ(A1;1;ПОИСК("&";A1);)
 
 
 
#4
28.11.2016 16:26:46
Проблема похожая, нужно удалить весь текст до значения <p  после значения много текста, Excel 2013.
Изменено: bizzon - 28.11.2016 16:27:24
 
 
 
#5
28.11.2016 16:29:19
Формула похожая. Вы пробовали применять?
Цитата
убрать из ячейки весь текст который расположен слева...  все включая знак "&"...
удалить весь текст до значения <p
Большая разница?
ПОИСК("<p";A1)-1
 
 
 
#6
28.11.2016 17:11:17
Похоже, Вы применили часть формулы, в которой я показал, что нужно исправить. Целая формула - в сообщениях №2 и №3
 
 
 
#7
28.11.2016 17:31:30
=ЗАМЕНИТЬ(A1;1;ПОИСК("<p";A1)-1) использовал эту, все равно пишет мало аргументов
https://yadi.sk/i/TnvpAshxzgFDN вот файл
Изменено: bizzon - 28.11.2016 17:31:51
 
 
 
#8
28.11.2016 17:52:25
=ЗАМЕНИТЬ(A2;1;ПОИСК("<p";A2)-1;)
 
 
 
#9
28.11.2016 18:12:13
огромное спасибо
 
 
 
#10
07.06.2023 14:22:02
Добрый день.
Прошу помощи, нужно всё то же самое, только чтобы Excel удалял текст перед 3 русскими буквами.
То есть, что бы Excel находил подряд 3 русские буквы и удалял всё перед первой русской буквой.
Пример во вложенииПример.xlsx (9.12 КБ)
 
 
 
#11
07.06.2023 15:30:41
Пробуйте
Код
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;" ";"</s><s>")&"</s></t>";"//s[translate(.,'абвгдеёжзийклмнопрстуфхцчшщъыьэюя','')!=.][translate(.,'1234567890abcdefghijklmnopqrstuvwxyz','')=.][string-length()>3]");A2);999);"")
Изменено: Msi2102 - 07.06.2023 15:47:12
 
 
 
#12
07.06.2023 15:44:15
Еще вариант для пробы )
=ЕСЛИОШИБКА(ПСТР(A2;МИН(ЕСЛИОШИБКА(ПОИСК(" ??"&СИМВОЛ(СТРОКА($224:$255));A2)+1;""));999);"")
 
 
 
#13
07.06.2023 15:52:06
Цитата
написал:
Пробуйте
Да, но некоторые строки почему-то не читает, я добавил в пример пару строк, где формула не работает.
 
 
 
#14
07.06.2023 15:54:42
Павел с Востока, А если так:
Патрубок A2а1R22110919220 Патрубок воздушного фильтра Газель дв.
 
 
 
#15
07.06.2023 15:54:52
Павел, утёс СИМВОЛ(ЕСЛИОШИБКА(СТРОКА($224:$255)*ЧАСТОТА(СТРОКА($224:$255);СТРОКА($224:$255));184))
Gefest добавьте АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ
Изменено: Тимофеев - 07.06.2023 15:59:10
 
 
 
#16
07.06.2023 16:01:09
Цитата
Тимофеев написал:
добавьте АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ
Вот так
Код
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;" ";"</s><s>")&"</s></t>";"//s[translate(.,'абвгдеёжзийклмнопрстуфхцчшщъыьэюяАБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЪЫЬЭЮЯ','')!=.][translate(.,'1234567890abcdefghijklmnopqrstuvwxyz','')=.][string-length()>3]");A2);999);"")
 
 
 
#17
07.06.2023 16:13:09
Код
=ЕСЛИОШИБКА(ЗАМЕНИТЬ(A2;1;
ПОИСК("111";СЦЕП((КОДСИМВ(ПСТР(СТРОЧН(A2);СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A2)));1))>=224)+
(КОДСИМВ(ПСТР(СТРОЧН(A2);
СТРОКА(ДВССЫЛ("1:"&ДЛСТР(A2)));1))=184)))-1;"");"")
 
 
 
#18
07.06.2023 16:20:49
Цитата
Msi2102,  Патрубок A2а1R22110919220 Патрубок воздушного фильтра Газель дв.
Я ж сказал для пробы )
Причем все варианты в примере считает и во втором тоже, кроме предпоследней строки где аглицкие маскируются русскими
Цитата
Тимофеев,  Павел, утёс
Кого утёс? ))
 
 
 
#19
07.06.2023 16:22:33
Всех благодарю за помощь, оба варианта оказались рабочими для меня.
 
 
 
#20
07.06.2023 17:35:47
Не понял, а зачем искать три русские буквы подряд? В вашем примере достаточно найти первую русскую букву...
 
 
 
#21
08.06.2023 09:29:54
Цитата
написал:
Не понял, а зачем искать три русские буквы подряд? В вашем примере достаточно найти первую русскую букву...
Что бы находить целые слова исключая предлоги и просто случайные одиночные буквы после английского текста, в примере буквально несколько позиций из ~500.000 строк.
 
 
 
#22
08.06.2023 09:47:44
Еще вариант без новых функций и если следовать строгой букве закона условий
=ЕСЛИОШИБКА(ПСТР(A2;ПОИСК(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(" "&A2;" ";ПОВТОР(" ";99));ПОИСКПОЗ(3;МУМНОЖ(--(ABS(КОДСИМВ(ПСТР(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(" "&ПОДСТАВИТЬ(СТРОЧН(A2);"ё";"е");" ";ПОВТОР(" ";99));СТРОКА($1:$99)*99;99))&"zzz";{1;2;3};1))-239,5)<16);{1:1:1});0)*99;99));A2);999);"")
 
 
 
#23
24.05.2024 07:58:13
Добрый день, прошу помощи. Нужно в столбце D дописать формулу, если есть текст в скобках удалять его, а если нет просто вставлять исходное значение. Столбец F, если нет даты увольнения то просто пусто и в дате убрать конечную скобку. Помогите пожалуйста
Изменено: Евгения мосеенкова - 24.05.2024 07:58:43
 
 
 
#24
24.05.2024 09:13:02
Евгения мосеенкова,  для D3
Код
=IF(ISNUMBER(SEARCH("(";C3));(MID(C3;1;SEARCH(" (";C3)));C3)

для f3
Код
=SUBSTITUTE(TRIM(MID(SUBSTITUTE(C3;" ";REPT(" ";100));400;100));")";"")
 
 
 
#25
24.05.2024 09:13:47
Код
=ЕСЛИОШИБКА(ПСТР(C3;1;ПОИСК(" (";C3))&ПСТР(C3;ПОИСК(")";C3)+ДЛСТР(")");ДЛСТР(C3));C3)
Изменено: МатросНаЗебре - 24.05.2024 09:14:30
 
 
 
#26
24.05.2024 09:48:54
Евгения мосеенкова, здравствуйте.  
Столбец C
Код
=ЕСЛИОШИБКА(ПСТР(C3;1;ПОИСК(" (";C3));C3)

Столбец F (если дата всегда в таком же формате ДД.ММ.ГГГГ)
Код
=ЕСЛИОШИБКА(ПСТР(C3;ПОИСК(")";C3)-10;10);"")
 
 
 
#27
23.04.2025 01:18:55

Здравствуйте!

Нужно решить такую задачу:

Есть три столбца, первые два это обозначение и тип позиции, третий содержит запись диапазона измерений соответствующей позиции в одной точке: минимальное значение и максимальное.

Позиций много. Мне нужно вычленить уникальные наименования позиций и указать их минимальные значения.

Значения измерений может быть разные это и трех и четырех и пятизначные цифры и т.д.

Файл прикладываю.

Изменено: MORO2025 - 23.04.2025 01:24:57
 
 
 
#28
23.04.2025 08:34:50
Bond2025, к теме как бы мало ваш вопрос относится, если только выделить мин из столбца измерений =--LEFT(C2;FIND("-";C2)-1), получить уникальные, если офис новый, то через уник, старый - или формулы искать или сводной
 
 
 
#29
23.04.2025 09:29:13
Bond2025, есть решение вашего вопроса (думаю не только у меня), но ваш вопрос к этой теме не имеет отношения
создайте свою тему
...подобных вопросов можно массу найти и в поиске  
 
 
 
#30
23.04.2025 19:02:45
Создал отдельную тему, пожалуйста, прошу помочь.
"Поиск минимальных значений из диапазона + вычленение уникальных позиций, вычленение уникальных позиций и поиск минимальных значений из одной ячейки, где указан диапазон."
 
 
 
Страницы: 1 2 След.
Читают тему
Наверх