Преобразование текста "день недели" в число

Пользователь

Сообщений: 145 Регистрация: 23.12.2012

14.05.2013 00:37:52

Здравствуйте. Есть таблица со столбцом дней недели: "понедельник", "вторник" и т.д. (столбец D)

Для преобразования в число использовал такую многовложенную "ЕСЛИ":

Код

=ЕСЛИ(D2="понедельник";1;
   ЕСЛИ(D2="вторник";2;
      ЕСЛИ(D2="среда";3;
         ЕСЛИ(D2="четверг";4;
            ЕСЛИ(D2="пятница";5;
               ЕСЛИ(D2="суббота";6;7))))))

Хочется это преобразование как-то усовершенствовать. Есть идеи?
Спасибо.

Юрий М Модератор Сообщений: 60983 Регистрация: 14.09.2012 Контакты см. в профиле	#2 14.05.2013 00:43:01 ВЫБОР() не подойдёт?

vikttur Пользователь Сообщений: 47172 Регистрация: 15.09.2012	#3 14.05.2013 00:52:33 ВЫБОР() можно, но есть выбор короче: =ПОИСКПОЗ(ЛЕВСИМВ(A1;2);{"по";"вт";"ср";"че";"пя";"су";"во"};) =ПОИСК(ЛЕВСИМВ(A1;2);" повтсрчепясуво")/2

okshef Пользователь Сообщений: 145 Регистрация: 23.12.2012	#4 14.05.2013 01:32:11 vikttur, впечатляет... Юрий М, не совсем понял, как в этом случае использовать ВЫБОР(). Где взять номер индекса?

Юрий М Модератор Сообщений: 60983 Регистрация: 14.09.2012 Контакты см. в профиле	#5 14.05.2013 02:12:44 =ВЫБОР(D2;"Понедельник";"Вторник";"Среда";"Четверг";"Пятница";"Суббота";"Воскресенье")

Юрий М Модератор Сообщений: 60983 Регистрация: 14.09.2012 Контакты см. в профиле	#6 14.05.2013 02:15:07 Нет - у Вас же обратная задача))) Невнимательно прочитал.

Владимир Пользователь Сообщений: 8196 Регистрация: 21.12.2012	#7 14.05.2013 06:41:03 =ПОИСКПОЗ(D2;ТЕКСТ(СТРОКА(2:8);"DDDD");) "..Сладку ягоду рвали вместе, горьку ягоду я одна."

okshef Пользователь Сообщений: 145 Регистрация: 23.12.2012	#8 14.05.2013 08:19:21 Владимир, что-то у меня не работает, ни простой формулой, ни формулой массива. Дело в том, что "понедельник" - это не дата в формате "ДДДД", а простой текст. Или я что-то не то делаю.

Пользователь

Сообщений: 6111 Регистрация: 21.12.2012

Win 10, MSO 2013 SP1

14.05.2013 08:31:31

Цитата
okshef пишет: ... не то делаю

Хоккей - массив - "=ПОИСКПОЗ(D2;ТЕКСТ(СТРОКА(2:8);"ДДДД");)"

Изменено: Z - 14.05.2013 09:14:31

"Ctrl+S" - достойное завершение ваших гениальных мыслей!.. ;)

jakim Пользователь Сообщений: 2110 Регистрация: 01.03.2013	#10 14.05.2013 10:25:53 Можно и так. =VLOOKUP(A1;н_дня;2;0) Прикрепленные файлы Book1.xlsx (9.28 КБ)

Владимир

Пользователь

Сообщений: 8196 Регистрация: 21.12.2012

#11

14.05.2013 14:16:04

Цитата
okshef пишет: "понедельник" - это не дата в формате "ДДДД", а простой текст.

Да, это просто текст. Формула массива.

Прикрепленные файлы

День нед.xlsx (8.71 КБ)

"..Сладку ягоду рвали вместе, горьку ягоду я одна."

okshef

Пользователь

Сообщений: 145 Регистрация: 23.12.2012

#12

14.05.2013 21:01:23

jakim, спасибо, оригинально.
Владимир, я же писал, что ФМ тоже не сработала, видимо, из-за разницы языковых версий. При замене "DDDD" на "ДДДД" - работает

Очень интересное решение!
Изменил в формуле

Код
СТРОКА(2: 8) на СТРОКА($2:$8)

- так более корректно работает при перетаскивании

Огромное спасибо всем!
Как говорит основатель сайта и форума: "Когда знаешь - все просто!"

Изменено: okshef - 14.05.2013 21:04:50

Владимир Пользователь Сообщений: 8196 Регистрация: 21.12.2012	#13 14.05.2013 21:51:54 Это у меня Эксель такой, он не воспринимает кириллицу - "ДДД", только латиницу. В настройках ковырялся, но не нашёл, как это изменить. "..Сладку ягоду рвали вместе, горьку ягоду я одна."

okshef Пользователь Сообщений: 145 Регистрация: 23.12.2012	#14 14.05.2013 22:59:51 А Windows не английская?

Владимир Пользователь Сообщений: 8196 Регистрация: 21.12.2012	#15 15.05.2013 06:27:58 И винда и офис - русские, только задание формата ячейки "латинистическое". "..Сладку ягоду рвали вместе, горьку ягоду я одна."

Читают тему