'функция разбивки строки координат многоугольника на массив строк,
'каждый чётный элемент содержит долготу, каждый нечётный широту
'пара i, i + 1 задаёт координату вершины многоугольника, при i mod 2 = 0
Public Function strArray(ByVal this As String) As String()
    Dim pReg As Object
    Set pReg = CreateObject("VBScript.RegExp"): pReg.Global = True
    pReg.Pattern = "[\[\]]"
    strArray = VBA.Split(pReg.Replace(this, ""), ",")
End Function

'ФУНКЦИЯ: определение вложености точки в многоугольник, заданный своими координатами
'положение точки на линии многоугольника считается отсутствием вложености.
'xy() - массив координат вершин многоугольника, где координаты 1-ой = последней.
'первый индекс массива: 1 - координата X, 2 - координата Y
'второй индекс массива: номер точки в массиве
'Xo, Yo - координаты исследуемой точки
Function InPoligon(xy() As Double, Xo As Double, Yo As Double) As Boolean
  Dim dXnext As Double, dYnext As Double, Yb As Double
  Dim dXprev As Double, dYprev As Double, Resault As Integer
  Dim nextZone As Integer, prevZone As Integer, dZone As Integer, k As Integer
  Resault = 0
  For k = LBound(xy, 2) To UBound(xy, 2)
    dXnext = xy(1, k) - Xo: dYnext = xy(2, k) - Yo
    'проверка четверти плоскости
    nextZone = 0
    If (dXnext >= 0) And (dYnext > 0) Then nextZone = 1
    If (dXnext < 0) And (dYnext >= 0) Then nextZone = 2
    If (dXnext <= 0) And (dYnext < 0) Then nextZone = 3
    If (dXnext > 0) And (dYnext <= 0) Then nextZone = 4
    'If nextZone = 0 Then InPoligon = -100: Exit Function - на линии
    If nextZone = 0 Then InPoligon = False: Exit Function
    '
    If k > LBound(xy, 2) Then 'проверка перехода
      If nextZone <> prevZone Then 'переход в другую четверть
        dZone = nextZone - prevZone
        If dZone = 3 Then dZone = -1
        If dZone = -3 Then dZone = 1
        If (dZone = 2) Or (dZone = -2) Then 'переход через 2 четверти
          'If dXnext = dXprev Then InPoligon = -100: Exit Function - на линии
          Yb = (dYnext * dXprev - dYprev * dXnext) / (dXprev - dXnext)
          'If Yb = 0 Then InPoligon = -100: Exit Function - на линии
          If Yb = 0 Then InPoligon = False: Exit Function
          dZone = dZone * Sgn(Yb)
          If (prevZone = 2) Or (prevZone = 4) Then dZone = -dZone
        End If '(dZone = 2) Or (dZone = -2)
        Resault = Resault + dZone
      End If 'nextZone <> prevZone
    End If 'k > 1
    dXprev = dXnext: dYprev = dYnext: prevZone = nextZone
  Next k
  If Abs(Resault) = 4 Then
    InPoligon = True
  Else
    InPoligon = False
  End If
End Function 'InPoligon