Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Расчёт рабочих дней
 
#1
21.07.2013 09:24:59
доброго времени суток. Я сейчас изучаю excel интересным способом: у меня есть товарищ, гуру эксель. =) он даёт задачи, а я их решаю. В решениии помогают Google и всякие книжки. но есть вещи которых я просто не могу там найти. А каждый раз обращаться по "тупому" вопросу с товарищу тоже неудобно.
Сейчас я "встал" на такой вот задаче.
Есть 3 ячейки. 1 ячейка начальная дата (любая), 2 ячейка конечная дата (тоже любая). В 3 ячейке надо дать сумму рабочих дней между этими 2 датами. Однако выходные дни СРЕДА и СУББОТА или только СРЕДА.
Я так понимаю, что это надо сделать через формулу массивов и функции счётесли. Однако просто не понимаю, как можно из двух дат создать массив (двссыл тут не работает).

очень прошу помочь.

Чуть не забыл, для расчётов надо использовать только 1 ячейку.
Заранее спасибо.
 
 
 
#2
21.07.2013 10:10:55
Цитата
SanShiney пишет:
Однако выходные дни СРЕДА и СУББОТА или только СРЕДА
Как это понять?
С уважением,
Федор/Все_просто
 
 
 
#3
21.07.2013 10:14:38
вариант для "только СРЕДА"
Код
=СУММ(ЕСЛИ(ДЕНЬНЕД(СТРОКА(ДВССЫЛ(A2&":"&B2));2)<>3;1;0))

для "СРЕДА и СУББОТА"
Код
=СУММ(ЕСЛИ(ОСТАТ(ДЕНЬНЕД(СТРОКА(ДВССЫЛ(A2&":"&B2));2);3)>0;1;0))

формулы массива, конечно же.
Изменено: ikki - 21.07.2013 10:18:27
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#4
21.07.2013 10:28:56
варианты, не требующие ввода как формулы массива
Код
=СУММПРОИЗВ(--(ДЕНЬНЕД(СТРОКА(ДВССЫЛ(A2&":"&B2));2)<>3))
=СУММПРОИЗВ(--(ОСТАТ(ДЕНЬНЕД(СТРОКА(ДВССЫЛ(A2&":"&B2));2);3)>0))
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#5
21.07.2013 11:03:44
Только для суббота. Думал не выкладывать, потому что слишком сложно, к тому же возможно присутствие багов. Вот моя формула:
Код
=ЕСЛИ(ДЕНЬНЕД(B2;2)-ДЕНЬНЕД(A2;2)>0;ЕСЛИ(И(6-ДЕНЬНЕД(B2;2)<=0;6-ДЕНЬНЕД(A2;2)>=0);ЦЕЛОЕ((B2-A2)/7)*6-1+ДЕНЬНЕД(B2;2)-ДЕНЬНЕД(A2;2);ЦЕЛОЕ((B2-A2)/7)*6+ДЕНЬНЕД(B2;2)-ДЕНЬНЕД(A2;2));
             ЕСЛИ(ДЕНЬНЕД(B2;2)=ДЕНЬНЕД(A2;2);ЦЕЛОЕ((B2-A2)/7)*6; ЕСЛИ(И(6>=ДЕНЬНЕД(A2;2);6<=ДЕНЬНЕД(B2;2)+7);ЦЕЛОЕ((B2-A2)/7)*6+ДЕНЬНЕД(B2;2)-ДЕНЬНЕД(A2;2)+6;ДЕНЬНЕД(B2;2)+7-ДЕНЬНЕД(A2;2))))
С уважением,
Федор/Все_просто
 
 
 
#6
21.07.2013 11:43:03
Цитата
SanShiney пишет:
у меня есть товарищ, гуру эксель.
Так почему бы не спросить у этого товарища?
 
 
 
#7
21.07.2013 13:27:40
среда:
Код
=B2-A2-((B2+(ДЕНЬНЕД(B2;2)>3)*7-3-ДЕНЬНЕД(B2;2))-(A2+7-ДЕНЬНЕД(A2;2)+4-(ДЕНЬНЕД(A2;2)<4)*7))/7-(B2-A2=1)
Цитата
Юрий М пишет:
почему
потому:
Цитата
SanShiney пишет:
А каждый раз обращаться по "тупому" вопросу с товарищу
"тупые" вопросы для нас :)
 
 
 
#8
21.07.2013 13:38:19
Ну да - к товарищу неудобно, а к нам удобно))
 
 
 
#9
21.07.2013 14:24:08
Для 2007 и выше (Ср и Сб):
Код
=ЧИСТРАБДНИ.МЕЖД(A2;B2;"0010010")

только среда:
Код
=ЧИСТРАБДНИ.МЕЖД(A2;B2;14)
 
 
 
#10
21.07.2013 16:16:20
ВСЕМ БОЛЬШОЕ СПАСИБО!
Буду смотреть и разбираться.
Мне было сложно понять, как 2 даты сделать массивом. Ща посмотрим.
Ещё раз всем спасибо!
С меня пиво.
 
 
 
#11
21.07.2013 16:19:31
У ДВ оптимальный вариант. Другие лучше вообще не брать в расчет.
С уважением,
Федор/Все_просто
 
 
 
#12
21.07.2013 16:19:37
Цитата
ikki пишет: вариант ...
БЛИН!!! ТОЧНО!!!
У меня ДВССЫЛ никак не хотел работать.
А вся суть в том, что я тупо забыл прописать СТРОКА...
Ну блин...

Спасибо! =)
 
 
 
#13
21.07.2013 16:49:35
Цитата
Все_просто пишет:
оптимальный вариант
а каков критерий "оптимальности"?
что не во всех версиях работает?  :D
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#14
21.07.2013 17:40:01
Критерий оптимальности для меня состоит в простоте и быстроте формулы. Чем меньше функций в формуле, тем более быстрой она является. К тому же, при любом удобном случае лучше - да и легче - пользоваться встроенными функциями (не беру в расчет массивы - здесь все немного сложнее).
Изменено: Все_просто - 21.07.2013 17:40:25
С уважением,
Федор/Все_просто
 
 
 
#15
21.07.2013 17:41:47
Код
=СЧЁТ(ЕСЛИ(СТРОКА(40000:50000)>=A2;ЕСЛИ(СТРОКА(40000:50000)<=B2;ЕСЛИ(ОСТАТ(ДЕНЬНЕД(СТРОКА(40000:50000);2);3)<>0;СТРОКА(40000:50000)))))
среда+суббота - массивная без ДВССЫЛ
 
 
 
#16
21.07.2013 18:00:15
Цитата
Все_просто пишет:
Чем меньше функций в формуле, тем более быстрой она является.
Не всегда это верно.
 
 
 
#17
21.07.2013 19:56:26
Полностью согласен. Именно поэтому вместе "СУММЕСЛИ" лучше использовать старое доброе "СУМС"=>"ЕСЛИ". =)
 
 
 
#18
21.07.2013 20:58:57
"вместе с" или "вместо"?
СУММ(ЕСЛИ(...) - будет формула массива, гарантированно медленнее СУММЕСЛИ(), которая работает с диапазоном.
 
 
 
#19
21.07.2013 21:24:34
СУММ(ЕСЛИ(...)
И да, я согласен, что формулы массива медленнее. Однако в некоторых случаях я просто не вижу другого выхода.
 
 
 
#20
22.07.2013 00:26:18
Oфф.
Цитата
SanShiney пишет: у меня есть товарищ, гуру эксель.
Цитата
Юрий М пишет: Так почему бы не спросить у этого товарища?
Напомнило невыдуманную историю:
Малыш: У меня есть друг, он негр, …
Родители: ?!
Малыш: Ну, … он просто очень загорелый

Теперь понятно, как правильно называть всех гуру Excel – афроамериканцы!  :)
Изменено: ZVI - 22.07.2013 03:22:34
 
 
 
#21
22.07.2013 01:01:46
:)
 
 
 
#22
24.07.2013 01:13:21
ОФФ
Тогда и ЧИСТРАБДНИ для афроамериканцев подходит, ну если сквозь призму цитаты нижеследующей:

ZsaZsaZu: экселевская функция ЧИСТРАБДНИ мейкс ми край. звучит как глагол.
ZsaZsaZu: пойду чистрабдну
ZsaZsaZu: а еще есть функция РАЗНДАТ.
ZsaZsaZu: "он был красив и разндат"
ZsaZsaZu: КУБЧИСЛОЭЛМНОЖ СУКА!!!!!
ZsaZsaZu: есть еще древнегреческий ученый ДСТАНДОТКЛ
ZsaZsaZu: ДАТАКУПОНДО - это боевое искусство такое.
ZsaZsaZu: ПОИСКПОЗ - функция для тех, кому нехватает разнообразия
ZsaZsaZu: вот еще греческого философа нашла: СРОТКЛ
ZsaZsaZu: я прнс ЛГРФПРИБЛ

bash.im (с)

Кстати, здравствуйте (-:
Удивление есть начало познания © Surprise me!
И да пребудет с нами сила ВПР.
 
 
 
Страницы: 1
Читают тему
Наверх