Страницы: 1
RSS
Формула СУММЕСЛИ ИЛИ, суммирование по нескольким условиям
 
Добрый вечер, помогите пожалуйсто написать формулу для подсчёта ночных часов в ячейке(al20)  по трём условиям, подробности в примере
 
Можно подробности подробнее? В формуле только два условия.
 
Эх, люблю ответить ничего не поняв:
Код
=СУММЕСЛИ($E20:$AI20;"<>11")
Зы СМЕЩ там уж точно ни к чему.
 
griva_olga, Ваша формула, но немного не Ваша :)
=СУММЕСЛИ(G19:AI19;"НС";G20:AI20)+СУММЕСЛИ(G19:AI19;"РП";G20:AI20)
=СУММ(СУММЕСЛИ(G19:AI19;{"НС";"РП"};G20:AI20))


Может, я угадаю:
=СУММ(G20:AI20)-СУММЕСЛИ(G19:AI19;"Я";G20:AI20)
 
смещ нужно, по значению "рп" (работа в праздник)в верхней строке должны суммироваться только 4 или 8 (аналогично записать <>11)
 
СМЕЩ() не нужно, уж поверьте. Функция летуча (пересчет - при любом изменении на листе).

Путаете Вы нас. Если Вам нужно только "РП", зачем в формуле "НС"?
Опишите точнее условие.
 
Спасибо, не так всё же  :) СУММЕСЛИ(СМЕЩ($E20:$AI20;-1;0);"НС";$E20:$AI20)+СУММЕСЛИ(И(СМЕЩ($E20:$AI20;-1;0);"РП");$E20:$AI20<>"11";$E20:$AI20) она не работает,а как переписать формулу, чтобы суммировались только часы <> в нижней строке, если в верхней "РП"?
 
Не равно чему?
Сообщение #3, там еще и формула есть. Видели?
Не нужно рассказывать о формуле, просто напишите, ЧТО НУЖНО ПОЛУЧИТЬ.
 
Еще одна попытка:
Код
=СУММПРОИЗВ((E19:AI19="РП")*(E20:AI20<>11);E20:AI20)
 
Для Excel-2010:
=СУММЕСЛИМН(E20:AI20;E19:AI19;"РП";E20:AI20;"<>11")
 
Рассказываю: в  ячейке(al20) надо получить сумму чисел, у которых значение над ними (верхнее) :
-"НС"
- "РП", где сами числа 4 или 8 (можно записать и <>11)
 
Код
=СУММПРОИЗВ((E19:AI19="РП")*(E20:AI20<>11);E20:AI20)+СУММЕСЛИ(E19:AI19;"НС";E20:AI20)
:?:
 
Добавьте еще одно условие в одну из двух последних формул.
Не спешите и все получится.

Nic70y, зачем две функции?
 
Код
=СУММПРОИЗВ((E19:AI19="НС")+(E19:AI19="РП")*(E20:AI20<>11);E20:AI20)
Спешил ответить в одну секунду с Вами :)
 
Работает, спасибо, что разобрались в моих сумбурных описаниях, тема закрыта
 
=СУММПРОИЗВ((E19:AI19<>"Я")*ЕЧИСЛО(E20:AI20);E20:AI20)
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
Страницы: 1
Читают тему
Наверх