Создание базы Access без установленного Access

Пользователь

Сообщений: 2737 Регистрация: 21.12.2012

06.08.2015 21:45:48

Сегодня как-то между делом Александр (ikki) спросил про код, который позволяет создавать базу данных (и структуру) без наличия установленного Access'а. Я ответил ему, но продублирую ответ здесь - на всякий случай.

Для этого потребуется библиотека "Microsoft ADO Ext. 6.0 for DDL and Security".

Код

Sub CreateAccessDatabaseWithoutAccess()
      
    Dim cat As ADOX.Catalog '// Каталог (база данных)
    Dim t As ADOX.Table     '// Таблица
    Dim c As ADOX.Column    '// Столбец
      
    '// Создаём файл базы данных "C:\Temp\1.mdb".
    Set cat = New ADOX.Catalog
    '// Excel 2007+
    cat.Create "Provider=Microsoft.ACE.OLEDB.12.0;Data Source=C:\Temp\1.mdb"
    '// Excel 97-2003
    '// cat.Create "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=C:\Temp\1.mdb"
      
    '// Создаём таблицу
    Set t = New ADOX.Table
    t.Name = "User"
      
    '// Создаём два столбца: Id и UserName
    Set c = New ADOX.Column
    c.Name = "Id"      '// Название столбца
    c.Type = adInteger '// Тип данных
    t.Columns.Append c '// Добавляем столбец в таблицу
  
    Set c = New ADOX.Column
    c.Name = "UserName"
    c.Type = adWChar
    c.DefinedSize = 255
    t.Columns.Append c
  
    '// Добавляем таблицу в базу
    cat.Tables.Append t
      
    Set cat = Nothing
      
End Sub

There is no knowledge that is not power

JayBhagavan Пользователь Сообщений: 11833 Регистрация: 17.01.2014 ПОЛ: МУЖСКОЙ \| Win10x64, MSO2019x64	#2 07.08.2015 09:09:58 Johny, спасибо. (аки Плюшкин утащил в свою кладовку) Формула массива (ФМ) вводится Ctrl+Shift+Enter Memento mori

Johny Пользователь Сообщений: 2737 Регистрация: 21.12.2012	#3 07.08.2015 13:21:10 There is no knowledge that is not power

Читают тему