Привет! Я тоже издалека :-) Для решения Вашего вопроса нужно знать следующее:  
1. Исходные таблицы находятся на одном листе, или на разных?  
2. В каких столбцах расположены эти исходные таблицы?  
3. Создавать отчёт (третью таблицу) нужно на отдельном листе?  
4. Каким образом будет задаваться эти Лучинский/Кобелев/другие...?  
Лучше показать небольшой фрагмент реального файла с исходными таблицами.

Подготовлю таблички исходные как они есть на самом деле и выложу... спасибо за участие

Уточняю условие...Даны три таблицы, вообще это 3 разные книги (базы) я для примера сделала как отдельные листы…мне нужно сделать табл 3, основываясь на первые 2… по критерию «Торговый представитель»… то есть по каждому торговому сформировать базу по точкам: все берется со второй таблицы, отсортированное по каждому конкретному торговому, а паспортные данные (т.к. их нет во второй таблице) с табл.1. Таблица 1 – основная.. там может содержаться информация к примеру по 20 000 точкам (база всех существующих точек), во второй таблице представляется информация по торговым точкам , которые выполнили план…т. е. примерно 5000 точек…, которые относятся к 50 торговым представителям… и для каждого из 50 торговых нужно сделать табличку с его точками, которые выполнили план… как показано в табл.3. столбцы в табличках соответсвуют своим адресам, как есть в реальности

Понятно.  
Ну я ведь не предлагаю Вам портить саму табл.2 :) Сделайте её копию, из копии удалите ненужные № п/п Страна, вообще сделайте подобие табл.3, только без того, чего пока нет - без паспортных данных, для них отставьте место. Столбец "торговый представитель" сразу перенесите на своё место, затем удалите уже ненужные "ФИО ответственных лиц". Это займёт минуту-две. Затем запускаете мой код - в эту заготовку подтягиваются по номеру регистрации паспортные данные.  
Да, на 20000х5000 будет думать может минут 10, но в статусбаре процесс работы отображается.  
Теперь ставите автофильтр на "ФИО торгового представителя"  и печатаете по-одному. Вот для именно печати можно спецмакрос написать, это просто, чтоб вручную 50 раз не фильтровать и не распечатывать.  
Можно конечно всю эту процедуру делать специально написанным макросом, и работать он будет быстрее (если мастер напишет), но работа это непростая, а при малейшем изменении в структуре таблиц макрос придётся исправлять. А в моём Вы сами замените в настройках столбцы.  
Да и наверное такого вида задачи ещё есть - сделайте несколько копиий файла с макросом с разными настройками и используйте.

все варианты рассматриваю))) конечно актуален

Юрий, надо было на массивах делать, там ведь 20000х5000. А так скорость будет как у меня.

У меня такое работает, если удалить слияние ячеек в заголовках и разместить их в одной строке:  
 
Option Explicit  
'---------------------------------------------------------------------------------------  
' Procedure : Build_List  
' Author    : KL  
' Date      : 21/08/2010  
' Purpose   :  
' Comments  : Reference to Microsoft ActiveX Data Objects Library  
'             is required to execute this code.  
'---------------------------------------------------------------------------------------  
Sub Build_List()  
   Dim Con As ADODB.Connection  
   Dim RS As ADODB.Recordset  
   Dim Sql As String  
     
   Application.ScreenUpdating = False  
     
   Set Con = New ADODB.Connection  
   With Con  
     .Provider = "Microsoft.Jet.OLEDB.4.0"  
     .ConnectionString = "Data Source=" & "C:\Temp\Tab1.xls" & ";Extended Properties=Excel 8.0;"  
     .Open  
   End With  
     
   Set RS = New ADODB.Recordset  
         
   Sql = _  
       "SELECT Tab1.[Город], Tab1.[Номер регистрации], Tab1.[Название фирмы], " & _
       "Tab1.[Фамилия], Tab1.[Имя], Tab1.[Отчество], Tab1.[серия], Tab1.[номер], " & _
       "Tab1.[дата], Tab1.[кем выдан], Tab2.[торговый представитель] " & _
       "FROM [табл 1$] AS Tab1 INNER JOIN `C:\Temp\Tab2.xls`.[табл 2$] AS Tab2 " & _
       "ON Tab1.[Номер регистрации] = Tab2.[Номер регистрации] " & _
       "ORDER BY 11;"  
         
   RS.Open Sql, Con  
   With ThisWorkbook.Sheets(1)  
       .Range("a1").CopyFromRecordset RS  
   End With  
   Con.Close: Set RS = Nothing: Set Con = Nothing  
End Sub

Кирилл, а через MSQuery можно это дело провернуть? Чтоб весь запрос в одном *.dqy файле разместить?

Вот подчищенный код:  
 
Option Explicit  
'---------------------------------------------------------------------------------------  
' Procedure : Build_List  
' Author    : KL  
' Date      : 21/08/2010  
' Purpose   :  
' Comments  : Reference to Microsoft ActiveX Data Objects Library  
'             is required to execute this code.  
'---------------------------------------------------------------------------------------  
Sub Build_List()  
   Dim Con As ADODB.Connection  
   Dim RS As ADODB.Recordset  
   Dim Sql As String, strPath As String, strRep As String  
   Dim strFile1 As String, strFile2 As String, strTab1 As String, strTab2 As String  
     
   strPath = ThisWorkbook.Path  
   strFile1 = strPath & "\Tab1.xls"  
   strFile2 = strPath & "\Tab2.xls"  
   strTab1 = "табл 1"  
   strTab2 = "табл 2"  
   strRep = "Кобелев"  
     
   Application.ScreenUpdating = False  
     
   Set Con = New ADODB.Connection  
   With Con  
     .Provider = "Microsoft.Jet.OLEDB.4.0"  
     .ConnectionString = "Data Source=" & strFile1 & ";Extended Properties=Excel 8.0;"  
     .Open  
   End With  
     
   Set RS = New ADODB.Recordset  
         
   Sql = _  
       "SELECT Tab1.[Город], Tab1.[Номер регистрации], Tab1.[Название фирмы], " & _
       "Tab1.[Фамилия], Tab1.[Имя], Tab1.[Отчество], Tab1.[серия], Tab1.[номер], " & _
       "Tab1.[дата], Tab1.[кем выдан], Tab2.[торговый представитель] " & _
       "FROM [" & strTab1 & "$] AS Tab1 INNER JOIN `" & strFile2 & "`.[" & strTab2 & "$] AS Tab2 " & _
       "ON Tab1.[Номер регистрации] = Tab2.[Номер регистрации] " & _
       "WHERE Tab2.[торговый представитель] = '" & strRep & "' "
       '"ORDER BY 11;"  
         
   RS.Open Sql, Con  
   With ThisWorkbook.Sheets(1)  
       .Range("A1").CopyFromRecordset RS  
   End With  
   Con.Close: Set RS = Nothing: Set Con = Nothing  
End Sub