Не пробовали макрорекордером записать эти действия?  
Если оптимизировать то, что он запишет, получится  
 
Range("A9:E19,F12:J28").Delete Shift:=xlUp  
 
Нумерация и границы - это отдельный вопрос.

43 кб  
текст макроса :(уважаемые гуру! Бросьте взгляд на счет примененного алгоритма и ткните носом меня - где неправ, где по другому оптимальнее и т.д. - мне для самообразования надо, пожалуйста!) :О)  
 
Sub DelBlocks()  
Dim lngI As Long 'счетчик для строк с данными  
Dim bytJ As Byte 'вспомогательный счетчик для смещения по таблице  
'отключаем "тормоза"  
Application.Calculation = xlCalculationManual  
Application.ScreenUpdating = False  
 
For bytJ = 1 To 6 Step 5 'запускаем цикл по "смещению" поиска удаляемых блоков (сначала работаем с столбцами 1 - 5, затем  
'6 - 10, соответственно шаг цикла = 5  
 
'запускаем цикл по поиску пустых значений в ячейках столбца 1, выделением блока в найденной строке с 1 по 5 столбец  
'и удалением блока со смещением ячеек вверх. Цикл запускаем "задом-наперед" с шагом - 1  
   For lngI = Cells(Rows.Count, bytJ).End(xlUp).Row To 6 Step -1  
       If Cells(lngI, bytJ) = "" Then  
           Range(Cells(lngI, bytJ), Cells(lngI, bytJ + 4)).Delete shift:=xlUp  
       End If  
   Next lngI  
Next bytJ  
'Повторно запускаем цикл в цикле для перенумерации в столбцах 1 и 6  
For bytJ = 1 To 6 Step 5  
   For lngI = 6 To Cells(Rows.Count, bytJ).End(xlUp).Row  
       Cells(lngI, bytJ).Value = lngI - 5  
   Next lngI  
Next bytJ  
'включаем "тормоза" обратно  
Application.ScreenUpdating = True  
Application.Calculation = xlCalculationAutomatic  
 
End Sub

Вот так всегда, изобретаю паровоз для копания, когда есть лопата... :О(  
Спасибо! :О)  
 
Sub DelBlocks()  
Dim lngI As Long 'счетчик для строк с данными  
Dim bytJ As Byte 'вспомогательный счетчик для смещения по таблице  
'удаляем  
Range(Range("A5"), Cells.SpecialCells(xlCellTypeLastCell)).SpecialCells(xlCellTypeBlanks).Delete xlUp    
'перенумеровываем  
For bytJ = 1 To 6 Step 5  
   For lngI = 6 To Cells(Rows.Count, bytJ).End(xlUp).Row  
       Cells(lngI, bytJ).Value = lngI - 5  
   Next lngI  
Next bytJ  
End Sub

Спасибо за очередной переделанный паровоз! :О)  
 
Sub DelBlocks()  
Dim lngI As Long  
Dim bytJ As Byte  
Range(Range("A5"), Cells.SpecialCells(xlCellTypeLastCell)).SpecialCells(xlCellTypeBlanks).Delete xlUp  
For bytJ = 1 To 6 Step 5  
   Cells(6, bytJ).Value = 1  
   Range(Cells(6, bytJ), Cells(Cells(Rows.Count, bytJ).End(xlUp).Row, bytJ)).DataSeries Rowcol:=xlColumns, _  
   Type:=xlDataSeriesLinear, Step:=1, Stop:=Cells(Rows.Count, bytJ).End(xlUp).Row  
Next bytJ  
 
End Sub

Ага, понятно! Спасибо!  
А вот про это:  
 
"И не используйте тип Byte, для адресации ячеек он все равно преобразуется в Long."  
 
Можно поподробнее? В справке про это э.... молчок (или я запросы строить не умею). Это по причине превышения для объекта Cells возможного значения номера столбца/ячейки относительно заданного типа Byte (0-255)? Всегда идет автоматическое преобразование, или может вызвать ошибку?