Может и мой корявенький макрос кому-нибудь пригодится. Обрабатывает таблицу HTML, в которой в полях одной записи встречаются и объединенные и отдельные ячейки. В результате получается запись в одной строке, а лишние удаляются. Для наглядности кусочек исходной таблицы в файле.  
Sub UnMergeAndPack()    ' Если в поле А есть объединенные строки (ячейки) разъединяет их  
   Dim iCell As Range      ' а из необъединенных ячеек собирает текст в верхнюю ячейку.После этого  
   Dim nRow As Long        ' удаляет строки с пустыми ячейками в столбце А  
   Dim howRow As Integer  
   Dim endRow As Long  
   Dim nCol As Integer  
   Dim addRow As Long  
   Dim iLastRow As Long  
   Application.DisplayStatusBar = True  
   'Установка текста строки состояния.  
   Application.StatusBar = "Преобразование таблицы"  
   Application.ScreenUpdating = False                 'Отключить обновление экрана  
   iLastRow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count  
   For Each iCell In Range("A3:A" & iLastRow)  
       With iCell  
           If .MergeCells And .Address = .MergeArea.Cells(1).Address Then  ' Если ячейка Merge и она первая в Merge  
               nRow = iCell.Row                    ' номер первой строки в объкдиненной ячейке  
               howRow = .MergeArea.Rows.Count      ' кол-во строк в объединенной ячейке  
               endRow = nRow + howRow - 1          ' номер последней строки в объединенной ячейке  
                   For nCol = 1 To 7               ' обработка записи в полях  
                       If Cells(nRow, nCol).MergeCells = True Then ' Если ячейка объединенная,  
                           Cells(nRow, nCol).UnMerge   ' то разъединяем  
                           Else  
                              For addRow = nRow + 1 To endRow  ' если ячейки отдельные, то собираем из них текст в верхнюю ячейку  
                               Cells(nRow, nCol) = Cells(nRow, nCol) & Chr(10) & Cells(addRow, nCol)  
                              Next addRow  
                       End If  
                   Next nCol  
           End If  
       End With  
   Next  
     
   iLastRow = ActiveSheet.UsedRange.Row - 1 + ActiveSheet.UsedRange.Rows.Count  
   Range("A2", "G" & iLastRow).AutoFilter Field:=1, Criteria1:="=", Operator:=xlFilterValues ' Фильтрация по "Пусто" в поле А  
   Range("A3:A" & iLastRow).SpecialCells(xlCellTypeVisible).EntireRow.Delete ' Удаление отфильтрованных строк  
   Range("A2", "G" & iLastRow).AutoFilter ' Отключение автофильтра  
     
   ActiveSheet.UsedRange.Replace Empty, "insert", xlWhole ' Устанавливаем рабочую область  
   ActiveSheet.UsedRange.Replace "insert", Empty          ' по размерам таблицы  
     
   Columns("B:G").EntireColumn.AutoFit ' Автоподбор ширины ячеек  
   Cells.EntireRow.AutoFit             ' Автоподбор высоты ячеек  
Range("H2").Select  
   Application.ScreenUpdating = True  
   Application.StatusBar = False  
 
End Sub