Есть вариант удалить строку на листе, а потом записать в массив.  
Но можно как-то программно?

А, например, вот так:  
Sub Del_Arr_RC(Arr(), Optional iRow& = 0, Optional iCol& = 0) 'удалить из массива любую строку и/или столбец  
  Dim L1&, U1&: L1 = LBound(Arr, 1): U1 = UBound(Arr, 1)  
  Dim L2&, U2&: L2 = LBound(Arr, 2): U2 = UBound(Arr, 2)  
  Dim TempSh As Worksheet, Rng As Range  
  Application.ScreenUpdating = False: Application.DisplayAlerts = False  
  Set TempSh = ThisWorkbook.Worksheets.Add  
  Set Rng = Cells(1, 1).Resize(U1 - L1 + 1, U2 - L2 + 1)  
  Rng.Value = Arr  
  If iRow > 0 And iRow <= U1 - L1 + 1 Then Rows(iRow).Delete  
  If iCol > 0 And iCol <= U2 - L2 + 1 Then Columns(iCol).Delete  
  Arr = Rng.Resize(U1 - L1 + 1 + (iRow > 0), U2 - L2 + 1 + (iCol > 0)).Value  
  TempSh.Delete  
  Application.ScreenUpdating = True: Application.DisplayAlerts = True  
End Sub  
 
Надо будет ещё попробовать найти время и доработать:  
- не на временном листе делать, а во временной книге  
- чтобы можно было число строк/столбцов задавать.

Ну, и чтобы закрыть тему:  
Function DelArrRC(Arr(), Optional xRow& = 0, Optional xCol& = 0)   'удалить из массива любую строку и/или столбец  
  ' работает во временном новом листе текущей книги. При защите структуры или общем доступе к книге могут быть сбои.  
  Dim L1&, U1&: L1 = LBound(Arr, 1): U1 = UBound(Arr, 1)  
  Dim L2&, U2&: L2 = LBound(Arr, 2): U2 = UBound(Arr, 2)  
  Dim tmpSh As Worksheet, tmpRng As Range  
  Application.ScreenUpdating = False: Application.DisplayAlerts = False  
  Set tmpSh = ThisWorkbook.Worksheets.Add  
  Set tmpRng = Cells(1, 1).Resize(U1 - L1 + 1, U2 - L2 + 1)  
  tmpRng.Value = Arr  
  If xRow > 0 And xRow <= U1 - L1 + 1 Then Rows(xRow).Delete  
  If xCol > 0 And xCol <= U2 - L2 + 1 Then Columns(xCol).Delete  
  DelArrRC = tmpRng.Resize(U1 - L1 + 1 + (xRow > 0), U2 - L2 + 1 + (xCol > 0)).Value  
  tmpSh.Delete: Set tmpSh = Nothing: Set tmpRng = Nothing  
  Application.ScreenUpdating = True: Application.DisplayAlerts = True  
End Function  
 
Function DelArrRC_0(Arr(), Optional xRow& = 0, Optional xCol& = 0)   'удалить из массива любую строку и/или столбец  
  ' работает во временной новой книге - чуть медленнее, но не волнует защита структуры книги или общий доступ  
  Dim L1&, U1&: L1 = LBound(Arr, 1): U1 = UBound(Arr, 1)  
  Dim L2&, U2&: L2 = LBound(Arr, 2): U2 = UBound(Arr, 2)  
  Dim tmpWBk As Workbook, tmpRng As Range  
  Application.ScreenUpdating = False: Application.DisplayAlerts = False  
  Set tmpWBk = Application.Workbooks.Add  
  Set tmpRng = tmpWBk.Sheets(1).Cells(1, 1).Resize(U1 - L1 + 1, U2 - L2 + 1)  
  tmpRng.Value = Arr  
  If xRow > 0 And xRow <= U1 - L1 + 1 Then tmpRng.Rows(xRow).Delete  
  If xCol > 0 And xCol <= U2 - L2 + 1 Then tmpRng.Columns(xCol).Delete  
  DelArrRC_0 = tmpRng.Resize(U1 - L1 + 1 + (xRow > 0), U2 - L2 + 1 + (xCol > 0)).Value  
  tmpWBk.Close: Set tmpWBk = Nothing: Set tmpRng = Nothing  
  Application.ScreenUpdating = True: Application.DisplayAlerts = True  
End Function

Дмитрий, ты, конечно, прав...  
Просто по инерции мышления: как начали тут делать с диапазоном, так я и продолжил...  
Конечно, с массивом намного универсальнее и быстрее в несколько раз получается.  
Я свою предыдущую универсальную (любые размерности массивов и сразу строку и столбец можно задавать) формулу подпилил.  
На массиве 100х100 выигрыш в скорости получился в 5 раз.  
 
Function DelArrRC(Arr(), Optional xRow& = 0, Optional xCol& = 0)   'удалить из массива любую строку и/или столбец  
  Dim L1&, U1&: L1 = LBound(Arr, 1): U1 = UBound(Arr, 1)  
  Dim L2&, U2&: L2 = LBound(Arr, 2): U2 = UBound(Arr, 2)  
  Dim tArr(): ReDim tArr(L1 To U1 + (xRow > 0), L2 To U2 + (xCol > 0))  
  Dim RR&, CC&, tRR&, tCC&  
  tRR = L1  
  For RR = L1 To U1  
     tCC = L2  
     If RR <> xRow Then  
        For CC = L2 To U2  
           If CC <> xCol Then: tArr(tRR, tCC) = Arr(RR, CC): tCC = tCC + 1  
        Next  
        tRR = tRR + 1  
     End If  
  Next  
  DelArrRC = tArr  
End Function

{quote}{login=PavelKs}{date=15.11.2010 06:48}{thema=}{post}Alex_ST, R Dmitry, Спасибо.  
R Dmitry, подошел Ваш вариант.{/post}{/quote}  
Ну и ладненько, пользуйтесь на здоровье.

Alex_ST, Ваш в копилке. Спасибо.  
R Dmitry'я, в работе. :)

Alex_ST, спасибо, это я заметил - именно по этому и в копилке.  
Загляните в http://www.planetaexcel.ru/forum.php?thread_id=21342. Спасибо.

R Dmitry, и Вас просу заглянуть  
http://www.planetaexcel.ru/forum.php?thread_id=21342

но можно еще быстрее - цикл copymemory по столбцам

слэн,  
на сколько я понял, delStr - это не число удаляемых строк, а номер удаляемой строки (иначе нужно было бы ещё и задавать, с какой начиная нужно удалять)  
Поэтому я и писАл:    
Dim tArr(): ReDim tArr(L1 To U1 + (xRow > 0), L2 To U2 + (xCol > 0))

слэн, спасибо, буду разбираться.