у Уокенбаха написано, что некоторые надстройки, в частности, Поиск решения, также создают много скрытых имён.

Упс... Не знал. Спасибо, Дмитрий.  
Сейчас проверил один рабочий файл - 136 имён накопилось. Чтож MS за собой не подчищает?

Zurnal!Print_Area - вот это появилось при задании области печати и само удалилось после удаления.  
А Zurnal!_FilterDatabase так и сидит.

Да, забыл сказать, макросов по удалению скрытых имен, как грязи. И я в свое время выкладывал:  
Sub DeleteHiddenNames()  
   Dim n As Name  
   Dim Count As Integer  
   For Each n In ActiveWorkbook.Names  
       If Not n.Visible Then  
           n.Delete  
           Count = Count + 1  
       End If  
   Next n  
   MsgBox "Скрытые имена в количестве " & Count & " удалены"  
   'MsgBox "У вас " & Count & " скрытых имен"  
 
End Sub  
И вот еще тема, где Николай(nilem) свои варианты предложил:  
http://forum.msexcel.ru/microsoft_excel/uvelichenie_fayla_excel-t5365.0.html

Ребята, я только что тоже потестировал.  
Выяснил, что скрытые имена, оканчивающиеся на !_FilterDatabase , удалять нельзя - перестают работать установленные автофильтры.  
А не скрытое имя области печати - Print_Area - тоже удалять не стоит, наверное.  
Поэтому я слепил такой макрос:  
 
Sub EraseNames()   ' очистка списка имен диапазонов  
  Dim nM As Name  
  For Each nM In ActiveWorkbook.Names  
     If Not nM.Visible Then  
        If Not nM.Name Like "*!_FilterDatabase" Then nM.Delete ' удалить все скрытые имена диапазонов кроме фильтров  
     Else  
        If Not nM.Name Like "*!Print_Area" Then  
           Select Case MsgBox("Удалить имя диапазона:" & vbCrLf & vbCrLf _  
                              & nM.Name & nM.RefersTo, vbYesNoCancel + vbQuestion)  
              Case vbYes: nM.Delete  
              Case vbCancel: Exit Sub  
           End Select  
        End If  
     End If  
  Next nM  
End Sub