Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel (архив)
Страницы: 1
RSS
сохранение листа книги в отдельный файл без макросов и кнопок
 
#1
12.08.2011 10:23:15
Здравствуйте.Уважаемые Специалисты!:)  
Помогите пожалуйста...  
Нужно сохранить данные в новый файл без макросов и кнопок на листе.  
Как вариант решения - можно также сохранить область печати.  
Огромное вам СПАСИБО!:)  
 
Sub save_me()  
Dim Rng As Range  
If Cells(1, 4) = "" Or Cells(6, 2) = "" Then  
MsgBox "Ячейки пусты!", 48, " Ошибка!"  
Exit Sub  
End If  
Sheets("Лист1").Copy  
Set Rng = Sheets("Лист1").UsedRange  
With Rng  
.Cells.Value = .Cells.Value  
End With  
ActiveWorkbook.SaveAs Filename:="C:\" & Cells(1, 4) & "_" & Cells(6, 2) & ".xls"  
ActiveWindow.Close  
End Sub
 
 
 
#2
12.08.2011 10:33:25
В чем вопрос - как сделать это вручную?  
Правый клик на ячрычке листа - Переместить/копировать - новая книга, создать копию. Сохраняете новую книгу.
 
 
 
#3
12.08.2011 10:41:28
Я думаю, в новом листе не должно быть макросов и кнопок.  
1. Если в исходном листе нет макросов, то и в новом не будет :)  
Т.е. может быть макросы из модуля листа можно перенести в общий модуль?  
Если нельзя - то ищите "ActiveWorkbook.VBProject.VBComponents"  
 
Вот, например, нашёл цитату:  
 
============================================================­==  
помогите пожалуйста убрать макро из отчета  
 
Yasha123,  
вот этот код всё удалил из активной книги:  
 
Sub DeleteModulesAndCode2()  
   Set iVBComponents = ActiveWorkbook.VBProject.VBComponents  
   For Each iVBComponent In iVBComponents  
       Select Case iVBComponent.Type  
           Case 1 To 3: iVBComponents.Remove iVBComponent  
           Case 100  
           With iVBComponent.CodeModule  
                .DeleteLines 1, .CountOfLines  
           End With  
       End Select  
   Next  
End Sub  
 
============================================================­==  
 
2. Кнопки можно удалить перебором, или если их одна/две, можно конкретно по имени и удалить.
 
 
 
#4
12.08.2011 10:45:26
Спасибо за ответы:) Не ожидал такой оперативности:)  
Но хотелось бы встроить это в код указанный выше.  
Чтобы был один макрос:)
 
 
 
#5
12.08.2011 11:01:11
Можно не встраивать - просто добавьте одну строку перед сохранением, а код положите рядом в модуль:  
 
DeleteModulesAndCode2  
ActiveWorkbook.SaveAs Filename:="C:\" & Cells(1, 4) & "_" & Cells(6, 2) & ".xls"  
ActiveWindow.Close  
End Sub  
 
Ну и ещё с кнопками разберитесь.  
Файлик (небольшой, без данных можно) показали бы, а то так вслепую может и не то советую...
 
 
 
#6
12.08.2011 11:13:40
Спасибо,Hugo!  
Сделал так как Вы сказали,но выскакивает ошибка в этой строке  
Set iVBComponents = ActiveWorkbook.VBProject.VBComponents
 
 
 
#7
12.08.2011 11:43:25
Нужно разрешить доступ к объектной модели или как-то так, нет под рукой XL2007/10.
 
 
 
#8
12.08.2011 12:28:16
Спасибо Вам,Hugo,огромное!:)С макросами разобрались:)  
Про то как доверить написано здесь:  
http://www.excel-vba.ru/chto-umeet-excel/kak-udalit-makrosy-v-knige/  
*правда пользовательские кнопки тот макрос не удаляет+ у Вас код короче:)  
 
Возможно ли отдельным макросом удалить все объекты на листе?  
Всёж их около 10:).Можно по одной конечно..  
 
ActiveSheet.Shapes(«Имя кнопки»).Delete  
 
но быть может есть способ красивее?;)  
 
Самое оптимальное,конечно если бы новый лист был бы сохранён как область печати:)Тем более у меня она присутствует:)
 
 
 
#9
12.08.2011 12:41:25
Пример:  
'Удаляем ВСЕ объекты на листе  
dim oSh as object  
for each oSh in ActiveSheet.Shapes  
   oSh.Delete  
next  
Application.ScreenUpdating = True  
End Sub  
 
Но лучше бы файл показали - вдруг там кнопки "не той системы" :)
 
 
 
#10
12.08.2011 12:54:12
Всё супер,Hugo!:)  
Низкий поклон Вам:)всё работает:)  
Спасибо огромное:)
 
 
 
#11
12.08.2011 13:34:48
{quote}{login=Hugo}{date=12.08.2011 12:41}{thema=}{post}Пример:  
'Удаляем ВСЕ объекты на листе  
dim oSh as object  
for each oSh in ActiveSheet.Shapes  
   oSh.Delete  
next  
Application.ScreenUpdating = True  
End Sub  
 
Но лучше бы файл показали - вдруг там кнопки "не той системы" :){/post}{/quote}  
 
мне на днях Уважаемый KukLP вот что поведал: Лист.DrawingObjects.Delete
Чебурашка стал символом олимпийских игр. А чего достиг ты?
Тишина - самый громкий звук

https://github.com/nervgh
 
 
 
#12
12.08.2011 15:10:24
Спасибо Сергею и Вам!:)  
Единственное но..  
Удаляет формы в текущем файле,но не сохранённом:)
 
 
 
#13
12.08.2011 15:33:59
Попробуйте  
ActiveSheet.DrawingObjects.Delete
 
 
 
#14
12.08.2011 16:40:40
Спасибо вам,Друзья!:)  
Подвожу итоги:  
 
Сохранение листа книги в отдельный файл без макросов и кнопок  
(новому файлу присваивается название взятому из ячеек,c проверкой на их заполнение)  
 
Добавьте два макроса:  
------------------  
Sub save_me()  
Application.ScreenUpdating = False  
Dim Rng As Range  
If Cells(1, 4) = "" Or Cells(6, 2) = "" Then  
MsgBox "Ячейки пусты!", 48, " Ошибка!"  
Exit Sub  
End If  
Sheets("Лист1").Copy  
Set Rng = Sheets("Лист1").UsedRange  
With Rng  
.Cells.Value = .Cells.Value  
End With  
DeleteModulesAndCode2  
ActiveSheet.DrawingObjects.Delete  
ActiveWorkbook.SaveAs Filename:="C:\" & Cells(1, 4) & "_" & Cells(6, 2) & ".xls"  
ActiveWindow.Close  
Application.ScreenUpdating = True  
End Sub  
------------------  
Sub DeleteModulesAndCode2()  
Set iVBComponents = ActiveWorkbook.VBProject.VBComponents  
For Each iVBComponent In iVBComponents  
Select Case iVBComponent.Type  
Case 1 To 3: iVBComponents.Remove iVBComponent  
Case 100  
With iVBComponent.CodeModule  
.DeleteLines 1, .CountOfLines  
End With  
End Select  
Next  
End Sub  
------------------  
Ещё раз...Огромное-преогромное спасибо всем Специалистам!:)
 
 
 
Страницы: 1
Читают тему
Наверх