Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel (архив)
Страницы: 1
RSS
Перенос столбцов из текстового файла в фаил xls
 
#1
18.10.2011 15:53:58
Здравствуйте! Подскажите пожалуйста как вытащить из файла TXT столбцы со значениями (нужен столбец 8; 10; 13) в фаил xls.
 
 
 
#2
18.10.2011 15:56:42
Копируем это все в эксель, жмем Данные-Текст_по_столбцам, выбираем разделитель пробел. Затем ненужные столбцы удалите, нужные оставите.
 
 
 
#3
18.10.2011 16:04:48
А проблема в чем? Вот я макрорекордером записал открытие:  
Sub Макрос1()  
   Workbooks.OpenText Filename:="I:\Dokument\post_268737.txt", Origin:=866, _  
       StartRow:=1, DataType:=xlFixedWidth, FieldInfo:=Array(Array(0, 9), Array(6, _  
       9), Array(12, 9), Array(15, 9), Array(21, 9), Array(29, 9), Array(39, 9), Array(48, 1), _  
       Array(65, 9), Array(83, 1), Array(90, 9), Array(97, 9), Array(104, 1), Array(113, 9), Array _  
       (126, 9), Array(140, 9)), TrailingMinusNumbers:=True  
End Sub
Я сам - дурнее всякого примера! ...
 
 
 
#4
18.10.2011 16:07:00
{quote}{login=}{date=18.10.2011 03:56}{thema=}{post}Копируем это все в эксель, жмем Данные-Текст_по_столбцам, выбираем разделитель пробел. Затем ненужные столбцы удалите, нужные оставите.{/post}{/quote}Аногним, зачем усложнять? Просто открываем тхт файл и указываем нужные столбцы и кодировку.
Я сам - дурнее всякого примера! ...
 
 
 
#5
18.10.2011 16:12:25
угу, прямо в Excel нажимаем - Файл - Открыть... - указываем на наш текстовый файл и нажимаем кнопку Открыть. А дальше в появившемся окне выбираем нужные параметры
 
 
 
#6
18.10.2011 16:13:03
Спасибо помогло. Но получилась большая таблица в которой есть пробелы в виде окончания табличных данных, затем какой то текст и начало следующей таблицы. Как мне после определенного значения (3 ‹Ёбв) первой строке при окончании очередной таблицы  удалять 8 строк до начала новой таблицы? Попробовал вручную долго. Может подскажите формулу?
 
 
 
#7
18.10.2011 16:16:57
Может пример выложите? И еще - формулы не умеют удалять строки, толко макросы.
Я сам - дурнее всякого примера! ...
 
 
 
#8
18.10.2011 16:22:48
Можно так (возможно ещё с типами данных похимичить нужно):  
 
Sub ImportTXT()  
 
Dim f, strText, arr, a()  
Dim i As Long, lCount As Long  
 
Set f = CreateObject("Scripting.FileSystemObject").OpenTextFile("C:\tmp\post_268737.txt", 1)  
strText = f.ReadAll  
f.Close  
Set f = Nothing  
 
arr = Split(strText, Chr(10))  
strText = Empty  
 
lCount = UBound(arr)  
ReDim a(1 To lCount + 1, 1 To 3)  
 
'(нужен столбец 8; 10; 13)  
For i = 0 To lCount  
a(i + 1, 1) = Mid(arr(i), 50, 16)  
a(i + 1, 2) = Trim(Mid(arr(i), 85, 6))  
a(i + 1, 3) = Trim(Mid(arr(i), 106, 6))  
Next  
Erase arr  
 
 
[a1].Resize(UBound(a, 1), UBound(a, 2)).Value = a 'выгружаем результат
 
End Sub
 
 
 
#9
18.10.2011 16:23:15
Вот что получилось...  
Надо просто убрать пробелы между таблицей. Я начал убирать правда с пробелами, но в ручную это не реально, так как там разрыв в 500 страниц. Нужно просто одну целостную табличную часть без разрывов. Помогите если это можно сделать макросом.  
<EM><STRONG>Файл удален</STRONG> - велик размер - [<STRONG>МОДЕРАТОРЫ</STRONG>]</EM>
 
 
 
#10
18.10.2011 16:28:12
Прочитайте правила и выложите файл НОРМАЛЬНОГО размера.
Я сам - дурнее всякого примера! ...
 
 
 
#11
18.10.2011 16:34:29
Уменьшил фаил.
 
 
 
#12
18.10.2011 16:35:29
Sub www()  
   With ActiveSheet.UsedRange.Columns(2)  
       Union(.SpecialCells(2, 2), .SpecialCells(4)).EntireRow.Delete  
   End With  
End Sub
Я сам - дурнее всякого примера! ...
 
 
 
#13
18.10.2011 16:41:31
В мой вариант можно проверку встроить:  
For i = 0 To lCount  
If IsNumeric(Mid(arr(i), 50, 5)) Then  
a(i + 1, 1) = Mid(arr(i), 50, 16)  
a(i + 1, 2) = Trim(Mid(arr(i), 85, 6))  
a(i + 1, 3) = Trim(Mid(arr(i), 106, 6))  
End If  
Next
 
 
 
#14
18.10.2011 16:42:47
Спасибо что помогли!!!!! Единственное чего не хватает это убрать "-" тире в первом столбце между числами. И все я счастлив)))) Это последняя просьба.
 
 
 
#15
18.10.2011 16:49:41
ctrl+H
Я сам - дурнее всякого примера! ...
 
 
 
#16
18.10.2011 16:56:52
В моём варианте есть пара способов - или в массив брать данные из трёх мест строки, или потом в массиве через replace заменить что нужно.  
Но можно и заменять уже на листе в выгруженном.
 
 
 
#17
18.10.2011 17:05:48
Мне бы просто прописать в макросе это.
 
 
 
#18
18.10.2011 17:12:02
Я пытаюсь соединить 2 макроса которые вы мне написали и даже это у меня не очень получается. Уважаемые профессионалы если вас не затруднит можно выразить это одним текстом?
 
 
 
#19
18.10.2011 17:13:12
Одним макросом
 
 
 
#20
18.10.2011 17:18:54
Sub www()  
   Dim s$  
   Workbooks.OpenText Filename:="I:\Dokument\post_268737.txt", Origin:=866, _  
   StartRow:=1, DataType:=xlFixedWidth, FieldInfo:=Array(Array(0, 9), Array(6, _  
   9), Array(12, 9), Array(15, 9), Array(21, 9), Array(29, 9), Array(39, 9), Array(48, 1), _  
   Array(65, 9), Array(83, 1), Array(90, 9), Array(97, 9), Array(104, 1), Array(113, 9), Array _  
   (126, 9), Array(140, 9)), TrailingMinusNumbers:=True  
   With ActiveSheet.UsedRange.Columns(2)  
       Union(.SpecialCells(2, 2), .SpecialCells(4)).EntireRow.Delete  
   End With  
   s = ActiveSheet.UsedRange.Columns(1).Address  
   Range(s).Value = Evaluate("""'""&" & s)  
   [A:A].Replace What:="-", Replacement:="", LookAt:=xlPart
End Sub
Я сам - дурнее всякого примера! ...
 
 
 
#21
18.10.2011 20:31:34
Почему то он нстанавливается на этой строке  
Union(.SpecialCells(2, 2), .SpecialCells(4)).EntireRow.Delete
 
 
 
#22
19.10.2011 09:02:56
#ЗНАЧ! 75 75  
Вот что получается при обработке макроса.
 
 
 
#23
19.10.2011 09:33:00
Попробуйте мой вариант.  
 
Option Explicit  
 
Sub ImportTXT()  
 
Dim f, strText, arr, a()  
Dim i As Long, ii As Long, lCount As Long  
 
Set f = CreateObject("Scripting.FileSystemObject").OpenTextFile("C:\tmp\post_268737.txt", 1)  
strText = f.ReadAll  
f.Close  
Set f = Nothing  
 
arr = Split(strText, Chr(10))  
strText = Empty  
 
lCount = UBound(arr)  
ReDim a(1 To lCount + 1, 1 To 3)  
 
'(нужен столбец 8; 10; 13)  
For i = 0 To lCount  
If IsNumeric(Mid(arr(i), 50, 5)) Then  
ii = ii + 1  
a(ii, 1) = Mid(arr(i), 50, 16)  
a(ii, 1) = Replace(a(ii, 1), "-", "")  
a(ii, 2) = Trim(Mid(arr(i), 85, 6))  
a(ii, 3) = Trim(Mid(arr(i), 106, 6))  
End If  
Next  
 
Erase arr  
 
Columns(1).NumberFormat = "0"  
[a1].Resize(ii, UBound(a, 2)).Value = a 'выгружаем результат
Columns(1).AutoFit  
End Sub
 
 
 
#24
19.10.2011 09:49:05
Hugo БОЛЬШОЕ СПАСИБО!!!!! все работает!!!!
 
 
 
Страницы: 1
Читают тему
Наверх