????  
Вопрос исчерпывающий. Попробуйте нажать мастер функций, выбрать полный алфавитный перечень и подобрать себе нужную. Ведь при расчете зарплаты/сотруднику/ округляют до 2 знаков, пересчет валюты - 5, и не маловажно знать по какому правилу, или для чего Вам необходимо округление.  
Английский и русский вариант.  
=ROUND(A1;2) =ОКРУГЛ(A1;2)  
Округляет число до указанного количества десятичных разрядов (по правилам математики).

Есть такой знак - fx /вставка функции-, при нажатии активизируется мастер функций.

---  
Округление в Excel вполне предсказуемое, т.к. оно выполняеться по математическим правилам.  
 
Но, не всем известно, что функция Round() в VBA округляет не по математическим правилам, а по банковским.  
В частности:    
Round(1.5)=2, ничего необычного;  
Но Round(2.5)=2, а не 3, как обычно ожидается.  
 
Упрощенно, для одного десятичного знака правило банковского округления такое: половинки (0.5), прибавленные к нечетным числам округляются до целых с избытком, а к четным - с недостатком.  
Смысл - в уменьшении систематической ошибки округления при суммировании большого количества чисел. Это удобно банкам, но знают ли об этом их клиенты?  
 
' Проверка VBA- округления  
Sub Нюансы_округления()  
MsgBox "Round(1.5)=" & Round(1.5) & vbCr _  
& "Round(2.5)=" & Round(2.5), _  
vbExclamation, "Crazy VBA round"  
End Sub  
 
Интересно, что многие публикации ошибаются относительно математического метода округления в VBA, и даже коммерческие программы порой используют в VBA функцию Round(число,2), принося тем самым кому-то убытки, а кому-то неожиданную прибыль.  
 
Более точно определение банковского округления можно прочесть здесь:  
http://ru.wikipedia.org/wiki/Округление  
 
Реализация (на мой взгляд, не очень оптимальная) разных видов округления, на английском здесь:  
http://support.microsoft.com/default.aspx?scid=kb;en-us;196652  
 
---  
ZVI

{quote}{login=Sh_Alex}{date=04.06.2008 03:15}{thema=VBA Round()}{post}В дополнение к изложенному ZVI.  
Приведенный способ банковского округления, применяется в геодезии с незапамятных времен, по-видимому, с тех, когда и банков (в современном понимании) не было.  
Да, таким образом уменьшалась систематическая ошибка округления при математической обработке геодезических измерений. А вычисления, еще на моей памяти, проводились с помощью «таблиц семизначных логарифмов» Вега и конторских счетов, альтернативой были «шестизначные таблицы тригонометрических функций» Петерса и железный «Феликс».  
С уважением, Александр.{/post}{/quote}  
 
Эх, а как здорово было считать на счётах нормы естественной убыли товаров! А "Феликс"...  
Всё ушло, всё умчалося в невозвратную даль...  
(Сейчас дедушка Мазай будет ругаться.)

---  
Прошу исправить, должно быть:  
 
Function ZVI_Round(x, Optional N = 0) As Double  
Dim b#  
b = Fix(N)  
If N < 0 Then  
b = 10 ^ -b  
ZVI_Round = Round(x / b + x * 1E-16, 0) * b  
Else  
ZVI_Round = Round(x + x * 1E-16, b)  
End If  
If Abs(ZVI_Round) = 0 Then ZVI_Round = 0  
End Function  
 
Откорректированый вариант таблицы прилагается  
 
---  
ZVI

Все верно, вроде исправлял. По крайней мере, у меня в архиве корректный вариант :-) Вот правильный вариант арифметического округления, заодно привожу еще одну функцию для округления с заданной точностью:  
 
' ZVI:2009-06-02 VBA arithmetic rounding function  
' Arguments are the same as for WorksheetFunction.Round(V,DecPlaces)  
' Функция, аналогичная =ОКРУГЛ(число;число_разрядов)  
Function ZVI_Round(V As Double, Optional DecPlaces As Integer = 0) As Double  
 If DecPlaces < 0 Then  
   ZVI_Round = Round(V / 10 ^ -DecPlaces + V * 2E-16, 0) * 10 ^ -DecPlaces  
 Else  
   ZVI_Round = Round(V + V * 2E-16, DecPlaces)  
 End If  
 If Abs(ZVI_Round) = 0 Then ZVI_Round = 0  ' Exclude -0 return value  
End Function  
 
' ZVI:2009-06-07 VBA rounding to the desired multiple  
' Like Excel function =MROUND(Value, Multiple) from Analysis ToolPack Add-In  
' Функция, аналогичная =ОКРУГЛТ(число;точность)  
Function ZVI_MRound(V As Double, Optional Multiple As Double = 1) As Double  
 If Multiple = 0 Then Exit Function  
 ZVI_MRound = Round((V + V * 2E-16) / Abs(Multiple), 0) * Abs(Multiple)  
 If Abs(ZVI_MRound) = 0 Then ZVI_MRound = 0  
End Function

фото средств измерения упомянутых, и не упомянутых, выше.  
Слева направо: [Железый] Феликс (серийный номер - Г89573), логарифмическая линейка, счёты (mini).
Всё поддерживается в исправном состоянии на случай энергетического каллапса.

Да, скорее My_Round - это только алгоритм :(  
Вопрос из треьего ряда аудитории:  
Почему MS не привела правила округления к общему знаменателю,  
на рабочем листе ЦЕЛОЕ() и ОКРУГЛ() - работают по ПРАВИЛЬНО,  
а VBA.Int и VBA.Round - извращенцы ?  
Ответ optional.

{quote}{login=}{date=18.02.2011 12:32}{thema=Округление}{post}...  
Почему MS не привела правила округления к общему знаменателю,  
на рабочем листе ЦЕЛОЕ() и ОКРУГЛ() - работают по ПРАВИЛЬНО,  
а VBA.Int и VBA.Round - извращенцы ?{/post}{/quote}  
Сначала был Visual Basic (VB), а затем уже VBA.  
В VB изначально функция Round() выполняла банковское округление, VBA просто наследовал эту функцию, что с точки зрения VB логично. Но возникло противоречие между округлением в VBA и Excel, видимо, посчитали, что так как это разные объектные модели с разными библиотеками, то так логичнее.    
Что касается Int(), то к ней нет претензий. Проблемы возникают из-за способа представления Double чисел: http://support.microsoft.com/kb/78113/ru

У меня проблема. Нужно округлить число в середине формулы. Например:  
((2,8-2,1)/0,8)*25  
мне нужно значение ((2,8-2,1)/0,8) округлить до целого числа. Можно сделать это в одной формуле?

А если округлить нужно до 0,5

{quote}{login=ZVI}{date=17.02.2011 10:43}{thema=}{post}Все верно, вроде исправлял. По крайней мере, у меня в архиве корректный вариант :-) Вот правильный вариант арифметического округления, заодно привожу еще одну функцию для округления с заданной точностью:  
 
' ZVI:2009-06-02 VBA arithmetic rounding function  
' Arguments are the same as for WorksheetFunction.Round(V,DecPlaces)  
' Функция, аналогичная =ОКРУГЛ(число;число_разрядов)  
Function ZVI_Round(V As Double, Optional DecPlaces As Integer = 0) As Double  
 If DecPlaces < 0 Then  
   ZVI_Round = Round(V / 10 ^ -DecPlaces + V * 2E-16, 0) * 10 ^ -DecPlaces  
 Else  
   ZVI_Round = Round(V + V * 2E-16, DecPlaces)  
 End If  
 If Abs(ZVI_Round) = 0 Then ZVI_Round = 0  ' Exclude -0 return value  
End Function  
 
' ZVI:2009-06-07 VBA rounding to the desired multiple  
' Like Excel function =MROUND(Value, Multiple) from Analysis ToolPack Add-In  
' Функция, аналогичная =ОКРУГЛТ(число;точность)  
Function ZVI_MRound(V As Double, Optional Multiple As Double = 1) As Double  
 If Multiple = 0 Then Exit Function  
 ZVI_MRound = Round((V + V * 2E-16) / Abs(Multiple), 0) * Abs(Multiple)  
 If Abs(ZVI_MRound) = 0 Then ZVI_MRound = 0  
End Function{/post}{/quote}  
Уважаемый ZVI, подскажите пожалуйста, а как реализовать функцию аналогичную ОКРУГЛВВЕРХ с помощью VBA

'ZVI:2012-02-09 VBA ROUNDUP function  
Function ZVI_RoundUp(V As Double, Optional DecPlaces As Integer = 0) As Double  
 Dim x#  
 x = Fix(V * 10 ^ DecPlaces)  
 If x <> V * 10 ^ DecPlaces Then x = x + 1  
 ZVI_RoundUp = Round(x / 10 ^ DecPlaces, DecPlaces + 1)  
End Function

{quote}{login=ZVI}{date=09.02.2012 12:54}{thema=}{post}'ZVI:2012-02-09 VBA ROUNDUP function  
Function ZVI_RoundUp(V As Double, Optional DecPlaces As Integer = 0) As Double  
 Dim x#  
 x = Fix(V * 10 ^ DecPlaces)  
 If x <> V * 10 ^ DecPlaces Then x = x + 1  
 ZVI_RoundUp = Round(x / 10 ^ DecPlaces, DecPlaces + 1)  
End Function{/post}{/quote}  
 
=ZVI_RoundUp(2,2;2) = 2,21  
=ZVI_RoundUp(46,02;4) = 46,0201  
=ZVI_RoundUp(17,1;5) = 17,10001  
=ZVI_RoundUp(128,717;3) = 128,718  
и т.п.