Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel (архив)
Страницы: 1
RSS
как можно подсчитать стаж?
 
#1
24.02.2012 02:26:24
Если кто- нибудь сталкивался, подскажите пожалуйста.  
В одной ячейке  стаж в формате 1г.5мес.5дн.(не текст, а результат работы функции), в другой - 2г.6мес.20 дн., как можно просуммировать две ячейки? Или в какой формат их нужно перевести, что бы они поддавались арифметическим действиям?
 
 
 
#2
24.02.2012 03:12:02
Вариант:  
=РАЗНДАТ(СУММ(B4:B9);СУММ(C4:C9);"y")&"г."&РАЗНДАТ(СУММ(B4:B9);СУММ(C4:C9);"ym")&"мес."&РАЗНДАТ(СУММ(B4:B9);СУММ(C4:C9);"md")&"дн."
 
 
 
#3
24.02.2012 03:17:50
еще вариант:  
=ЦЕЛОЕ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9))/360)&"г."&ОСТАТ(ЦЕЛОЕ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9))/30);12)&"мес."&ОСТАТ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9));30)&"дн."
 
 
 
#4
24.02.2012 03:22:00
для определения стажа по 2-м датам можно использовать формулу:  
=ЦЕЛОЕ(ДНЕЙ360(B4;C4)/360)&"г."&ОСТАТ(ЦЕЛОЕ(ДНЕЙ360(B4;C4)/30);12)&"мес."&ОСТАТ(ДНЕЙ360(B4;C4);30)&"дн."
 
 
 
#5
24.02.2012 03:40:13
можно, конечно,  разбить стаж на 3 колонки (год, месяц,день) и суммировать каждую, но может получиться результат: например 3г, 18 мес. 48 дн., т.е. не пересчитывает в полные месяцы и годы. Может нужно разложить результат на дни,и сложить их, но ведь в разных месяцах разное количество дней.Как тут быть?
 
 
 
#6
24.02.2012 03:52:49
MCH, не получается, так как в разных месяцах разное количество дней. ((
 
 
 
#7
24.02.2012 04:18:34
Забыла еще про одну особенность:  
между концом одного периода и началом другого могут быть промежутки времени.
 
 
 
#8
24.02.2012 04:46:19
А какой результат должен получится?  
Формула:  
=РАЗНДАТ(B4;C9;"y")&"г."&РАЗНДАТ(B4;C9;"ym")&"мес."&РАЗНДАТ(B4;C9;"md")&"дн."  
дает результат 5г.10мес.3дн.  
 
формула из первого моего поста - 5г.10мес.2дн.  
из второго - 5г.10мес.3дн.  
 
Кроме того, если рассмотреть даты:  
01.01.2012 16.01.2012 0г.0мес.15дн.  
17.01.2012 01.02.2012 0г.0мес.15дн.  
---  
 
01.02.2012 16.02.2012 0г.0мес.15дн.  
17.02.2012 03.03.2012 0г.0мес.15дн.  
---  
 
01.04.2012 16.04.2012 0г.0мес.15дн.  
17.04.2012 02.05.2012 0г.0мес.15дн.  
 
Какой суммарный стаж в каждом из этих 3х случаев?
 
 
 
#9
24.02.2012 04:55:18
MCH, я наверное перемудрила сама себя. Просто представила ситуацию, когда работник не постоянно работает на предприятии, или ему не весь стаж засчитывается, а только выборочно. Вам спасибо.
 
 
 
#10
24.02.2012 08:39:30
РАЗНДАТ не всегда дает корректный результат, см. файл
 
 
 
#11
24.02.2012 08:53:03
Еще один пример.  
Я все таки больше доверяю функции ДНЕЙ360
 
 
 
#12
24.02.2012 11:42:43
это красиво, но не совсем то.  
Это я сама виновата, не правильно задала вопрос.  
 
Попробую задать его иначе.  
Периоды на разных должностях чередуются, как быстро посчитать стаж на каждой должности отдельно?  
Прилагаю файл с вопросом.
 
 
 
#13
24.02.2012 11:55:09
=ЦЕЛОЕ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9)*(E4:E9="уборщица"))/360)&"г."&ОСТАТ(ЦЕЛОЕ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9)*(E4:E9="уборщица"))/30);12)&"мес."&ОСТАТ(СУММПРОИЗВ(ДНЕЙ360(B4:B9;C4:C9)*(E4:E9="уборщица"));30)&"дн."  
 
погрешность может быть на один-два дня
 
 
 
#14
24.02.2012 11:57:57
пожалуй это то, что искала, MCH, спасибо!!
 
 
 
Страницы: 1
Читают тему
Наверх