Ну, приблизительно так  
 
'Работа с комментариями  
'1) меняем штрифт у комментария в заданной ячейке  
Range("D10").Comment.Shape.TextFrame.Characters.Font.Size  
 
'2) изменяем размер окошка всех примечаний на листе ровно под текст (AutoSize)  
Sub All_Comments_Size_Change()  
Dim iComment As Comment  
   For Each iComment In ActiveSheet.Comments  
       iComment.Shape.TextFrame.AutoSize = True  
   Next iComment  
End Sub  
 
'3) добавляем комментарий в ячейку и меняем его шрифт  
Sub ChangeFontInComment()  
   With Range("B2")  
       .ClearComments  
       .AddComment  
       .Comment.Text "бла-бла-бла"  
       With .Comment.Shape.TextFrame.Characters.Font  
           .Name = "Times New Roman"  
           .Size = 14  
           .Bold = True  
       End With  
   End With  
End Sub  
 
'4) меняем шрифт у всех комментариев  
Sub All_Comments_Font_Change()  
Dim iComment As Comment  
   For Each iComment In ActiveSheet.Comments  
      With iComment.Shape.TextFrame.Characters.Font  
           .Name = "Times New Roman"  
           .Size = 14  
           .Bold = True  
       End With  
   Next iComment  
End Sub  
 
'5) устанавливаем высоту и ширину окна примечания  
Sub Change_Size_Comment_Window()  
   With Range("A1")  
       .AddComment "Bla-bla-bla"  
       With .Comment.Shape  
           .Width = 100  
           .Height = 200  
           .Visible = True  
       End With  
   End With  
End Sub  
 
'6) устанавливаем высоту и ширину для всех примечаний  
Sub Размер_Комментарий()  
Dim iComment As Comment  
   For Each iComment In ActiveSheet.Comments  
       iComment.Shape.TextFrame.AutoSize = True  
       iComment.Shape.Height = iComment.Shape.Height + 10  
       iComment.Shape.Width = iComment.Shape.Width + 15  
   Next iComment  
   MsgBox "Размеры комментарий исправлены!", vbInformation, "Комментарии"  
End Sub  
 
'7 устанавливаем размер окна комментария AutoSize и меняем свойство окно на "Перемещать, но не именять размеры"  
Sub AutoSizeMoveDontChangeSizeComments()  
'Свойство XlPlacement объекта Shape может быть одним из этих констант (Формат примечания/Свойства/)  
'- xlFreeFloating - не перемещать и не изменять размеры  
'- xlMove - перемещать, но не именять размеры  
'- xlMoveAndSize - перемещать и изменять объект вместе с ячейками  
Dim iComment As Comment  
   For Each iComment In ActiveSheet.Comments  
       With iComment.Shape  
           .TextFrame.AutoSize = True  
           .Placement = xlMove 'перемещать, но не именять размеры  
       End With  
   Next iComment  
   MsgBox "Все комментарии обработаны!", 64, "Конец"  
End Sub  
 
'8 Добавление даты в комментарий  
Private Sub Worksheet_Change(ByVal Target As Range)  
   'если изменения в диапазоне A1:A10  
   If Not Intersect(Target, Range("A1:A10")) Is Nothing Then  
       'если выделили больше одной ячейке, то выход  
       If Selection.Cells.Count > 1 Then Exit Sub  
       Target.NoteText Text:=Application.UserName & Chr(10) & "Дата: " & Now  
   End If  
End Sub