Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel (архив)
Страницы: 1
RSS
Как извлечь из текста "Название ООО", отельно название и отдельно ООО и ИП
 
#1
05.11.2012 22:49:19
Добрый вечер.  
Пытаюсь решить следующую задачу, есть список вида:  
Рога ООО  
Рога и копыта ООО  
Рогов ИП  
Рогов И.Н ИП.  
Рога  
Вот из него надо извлечь текст в отдельные ячейки (Отдельно "Рога", Отдельно "ООО")  
Текст по столбцам не подходит, т.к. используем в качестве разделителя пробел, то "Рога и копыта ООО" разносятся на четыре отдельные ячейки.    
Использовал формулу =ЕСЛИОШИБКА(ЛЕВСИМВ(B10;НАЙТИ(" ";B10)-1);"") и =ЕСЛИОШИБКА(ПРАВСИМВ(B10;НАЙТИ(" ";B10)-2);"")  
Т.Е. отталкиваюсь от первого найденного пробела. Этим способ работает пока текст однороден Рога ООО. Однако в том случае когда название имеет вид Рога и Копыта ООО или Рогов И.Н ИП, формула не работает. Понимаю, что неправильно отталкиваться от поиска первого пробела (с правой, или с левой стороны), но как по другому не знаю. Помогите пожалуйста с этим разобраться.
 
 
 
#2
05.11.2012 22:51:50
В XLS
 
 
 
#3
05.11.2012 23:20:18
поиском по форуму совсем не пользовались?  
аналогичные задачи решались если и не миллион раз, то чуть меньше :)  
 
вас интересует только решение формулами?  
формат строк только такой - в конце строки "ООО", "ИП" или нет строки, относящейся к организационной форме?  
 
как-то... интересно получается...  
задача ваша, а вопросов куча - у меня?  
и ведь вы не первый день на форуме.  
:)
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#4
05.11.2012 23:37:24
По форуму искал. Находил с использованием ДЛСТР (на работе осталась), но она тоже не работала. Запрос формулировал по разному.Да в конце всегда ООО и ИП. А если в конце строки не будет ни ИП, ни ООО, это усложняет или упрощяет решение?  
Формулой или макросом, наверное, чем проще.    
Да на форуме не первый  день, все чему научился в EXCEL, реально благодаря этому форуму и приемам. но 32<3178 ))) (это про количество собщений)
 
 
 
#5
05.11.2012 23:44:11
"Если в конце строки нет ни ИП, ни ООО", это не упрощяет, и не усложняет решение, это снимает необходимость решения.    
Ikki, я сейчас не уверен точно, но возможно что в Списке с ИП и ООО, могут быть названия где нет принадлежности к организационно правовой форме. Т.Е. часть названий с ООО и ИП, а часть без ООО и ИП.    
Утром еще раз проверю рабочий файл.
 
 
 
#6
05.11.2012 23:47:57
3178 - эт, конечно, да...  
в смысле - ни о чем не говорит (разве что о том, что я известный флудер:)  
 
решений может быть много, самых разных.  
как вариант, для столбца F:  
=ЕСЛИ(ПРАВСИМВ(D7;4)=" ООО";ЛЕВСИМВ(D7;ДЛСТР(D7)-4);ЕСЛИ(ПРАВСИМВ(D7;3)=" ИП";ЛЕВСИМВ(D7;ДЛСТР(D7)-3);D7))  
 
для столбца I - условия в ЕСЛИ() те же, но формулы при выполнении условий - другие. надеюсь, с этим вы справитесь :)
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#7
06.11.2012 02:27:02
Ikki, спасибо разобрался. Днем приложу решение и по второму столбцу. Тоже изначально хотел отталкиваться не от пробела а от ИП и ООО, но не догадался что можно сделать ПРАВСИМВ=ООО, и это будет логическим условием.
 
 
 
#8
06.11.2012 02:31:37
Еще варианты:
excel 2010
 
 
 
#9
06.11.2012 02:46:24
Nic70y, спасибо за участие. Само решение посмотрю только днем (тел, не открывает excel).
 
 
 
#10
06.11.2012 17:49:39
Для IKKI, справился, по столбцу I сделал так =ЕСЛИ(ПРАВСИМВ(D7;4)=" ООО";ПРАВСИМВ(D7;3);ЕСЛИ(ПРАВСИМВ(D7;3)=" ИП";ПРАВСИМВ(D7;2);"Форма собственности неизвестна")) спасибо Вам.  
 
Для  Nic70y, разнообразие вариантов восхищает особенно вот это =ВЫБОР(ЕСЛИОШИБКА((НАЙТИ("ООО";D7)>0)*2;0,5)+ЕСЛИОШИБКА((НАЙТИ("ИП";D7)>0)*3;0,5);"";"ООО";"ИП")  Пока так и не понял как работает, но через пару вечеров разберусь, и Вам спасибо.
 
 
 
#11
06.11.2012 17:56:37
умгу.  
можно чуть короче - незачем два раза вычислять одно и то же :)  
=ЕСЛИ(ПРАВСИМВ(D7;4)=" ООО";"ООО";ЕСЛИ(ПРАВСИМВ(D7;3)=" ИП";"ИП";"Форма собственности неизвестна"))
фрилансер Excel, VBA - контакты в профиле
"Совершенствоваться не обязательно. Выживание — дело добровольное." Э.Деминг
 
 
 
#12
06.11.2012 17:59:35
А вообще специально под эту задачу писалась Прайстом надстройка...до сих пор пользуюсь..причем она универсальная так как можно менять ..списое слов исключений на свое усмотрение..
 
 
 
#13
16.11.2012 20:23:11
Здравствуйте, вот решение для извлечения не только для ИП и ООО, а для ИП, ООО, ОАО, ЗАО.  
Извлечь название:  
=ЕСЛИ(ИЛИ(ПРАВСИМВ(D7;4)=" ООО";ПРАВСИМВ(D7;4)=" ОАО";ПРАВСИМВ(D7;4)=" ЗАО");ЛЕВСИМВ(D7;ДЛСТР(D7)-4);ЕСЛИ(ПРАВСИМВ(D7;3)=" ИП";ЛЕВСИМВ(D7;ДЛСТР(D7)-3);D7))  
 
Извлечь форму собственности:  
=ЕСЛИ(ИЛИ(ПРАВСИМВ(D7;4)=" ООО";ПРАВСИМВ(D7;4)=" ОАО";ПРАВСИМВ(D7;4)=" ЗАО");ПРАВСИМВ(D7;3);ЕСЛИ(ПРАВСИМВ(D7;3)=" ИП";"ИП";"Форма собственности неизвестна"))  
 
Спасибо, всем с чьей помощью научился это делать.
 
 
 
#14
16.11.2012 21:49:57
Похоже, 10 ноября ответ потерялся в этой теме.  
 
=СЖПРОБЕЛЫ(ЕСЛИ(ИЛИ(ПРАВСИМВ(D7;3)={"ООО";"ОАО";"ЗАО";" ИП"});ЛЕВСИМВ(D7;ДЛСТР(D7)-3);D7))
 
 
 
#15
16.11.2012 22:00:25
Да Виктор, именно здесь.  
Вот эта часть ={"ООО";"ОАО";"ЗАО";" ИП"} очень была нужна. Заменяет эти ПРАВСИМВ=ООО, ПРАВСИМВ=ОАО, и т.д.  
Но как в немассивной формуле часть массивной??? Это где-то документировано (кроме планеты)?
 
 
 
#16
16.11.2012 22:03:41
Её, ведь даже обычным способом вводить можно, а не трехпальцевым !!!!
 
 
 
#17
16.11.2012 22:07:11
В формуле уже определен массив, поэтому "трехпальцевый" ввод не требуется.  
Но это массив констант. Со ссылками так не получится.
 
 
 
#18
16.11.2012 22:12:31
Массив констант, где-то в литературе было, куда смотреть понял.  
Спасибо, просто великолепно !!!
 
 
 
#19
18.11.2012 16:35:36
{quote}{login=Микки}{date=06.11.2012 05:59}{thema=}{post}А вообще специально под эту задачу писалась Прайстом надстройка...до сих пор пользуюсь..причем она универсальная так как можно менять ..списое слов исключений на свое усмотрение..{/post}{/quote}  
Добрый день.  
Микки я её подключила через AddIns и что-то не пойму как она работает? Что, где должно проявиться?    
 
С уважением,  
Ольга
 
 
 
#20
18.11.2012 17:26:21
Разобралась. Спасибо Дмитрий. :)
 
 
 
Страницы: 1
Читают тему
Наверх