Надо разделить цифры

Василий Пользователь Сообщений: 6 Регистрация: 26.02.2009	#1 26.02.2009 09:07:06 Здравствуйте! В графе "сумма цифрами" надо, чтобы разделить рубли и копейки (доллары иценты, евро и евроценты), не знаком ",", а "-" чтобыполучилось не 1234567,89 а 1234567-89

КАДР Пользователь Сообщений: 148 Регистрация: 26.11.2008	#2 26.02.2009 09:16:33 если дробное число забито в ячейке А1 =ЗАМЕНИТЬ(A1;НАЙТИ(",";A1);1;"-")

КАДР

Пользователь

Сообщений: 148 Регистрация: 26.11.2008

26.02.2009 09:37:24

если дробное число забито в ячейке А1
если дробное число - результат вычислений с любым количеством знаков после запятой
если после "-" надо оставить 2 знака

=ЦЕЛОЕ(A1)&"-"&ЛЕВСИМВ(ПРАВСИМВ(A1;ДЛСТР(A1)-НАЙТИ(",";A1));2)

Pankratd

Пользователь

Сообщений: 114 Регистрация: 05.01.2013

26.02.2009 09:41:21

Уважаемый КАДР, " =ЗАМЕНИТЬ(A1;НАЙТИ(",";A1);1;"-") " не будет работать с числовыми форматами и числами, полученными с помощью формул. Позволю себе немножко доработать вашу формулу:
=ЗАМЕНИТЬ(ТЕКСТ(E26;"0,00");НАЙТИ(",";ТЕКСТ(E26;"0,00"));1;"-")
Проверял, работает при числовых форматах.

Василий Пользователь Сообщений: 6 Регистрация: 26.02.2009	#5 26.02.2009 12:22:50 а можно сделать чтобы они еще и разделялись? чтобы 1234567,89 стало 1 234 567-89

Guest

Гость

26.02.2009 12:29:25

{quote}{login=Pankratd}{date=26.02.2009 09:41}{thema=Re: }{post}Уважаемый КАДР, " =ЗАМЕНИТЬ(A1;НАЙТИ(",";A1);1;"-") " не будет работать с числовыми форматами и числами, полученными с помощью формул. Позволю себе немножко доработать вашу формулу:
=ЗАМЕНИТЬ(ТЕКСТ(E26;"0,00");НАЙТИ(",";ТЕКСТ(E26;"0,00"));1;"-")
Проверял, работает при числовых форматах.{/post}{/quote}

Спасибо.
Но у меня оба варианта работают - и с числовыми форматами и с числами, полученными с помощью формул. Первый вариант - корявый, согласен. Второй, как и Ваш, работает.

Pankratd Пользователь Сообщений: 114 Регистрация: 05.01.2013	#7 26.02.2009 12:32:30 Можно так, но будут нулики впереди при цифрах > 1000 =ЗАМЕНИТЬ(ТЕКСТ(A1;"0 000,00");НАЙТИ(",";ТЕКСТ(A1;"0 000,00"));1;"-")

Pankratd Пользователь Сообщений: 114 Регистрация: 05.01.2013	#8 26.02.2009 12:37:01 А вы протестируйте все варианты при ,00 (ноль,ноль копеек), у меня такие случаи не дают ,00 = -00.

Василий Пользователь Сообщений: 6 Регистрация: 26.02.2009	#9 26.02.2009 12:45:55 при 0,00 надо 0-00

Гость

#10

26.02.2009 12:55:35

Если эти "заморочки" нужны для серьезной и длительной работы, то, как вариант:
- в настройках XL снимаем галку "Использовать системные разделители",
- ставим разделителем дробной части "-" (дефис) или "-" (минус правая),
- формат ячеек - денежный/финансовый ("рваные", "ой-ой-ой-ро" - по желанию),
- смотрим "Все форматы", если надо - поправляем...

Pankratd Пользователь Сообщений: 114 Регистрация: 05.01.2013	#11 26.02.2009 12:57:44 Василий, последняя формула так и дает, а следующее мое сообщение - это для КАДРа. А вы тестируйте, выбирайте, пишите что и как.

Василий Пользователь Сообщений: 6 Регистрация: 26.02.2009	#12 26.02.2009 13:03:15 Этот файл передается по внутренней почте, поэтому надо чтобы он работал и на другом компе Спасибо за формулы!!! если есть возможность подскажите как все-таки сделать 0-00

Pankratd Пользователь Сообщений: 114 Регистрация: 05.01.2013	#13 26.02.2009 13:25:17 =ЕСЛИ(A1=0;"0-00";ЗАМЕНИТЬ(ТЕКСТ(A1;"0 0,00");НАЙТИ(",";ТЕКСТ(A1;"0 0,00"));1;"-"))

ytk5kyky Пользователь Сообщений: 2410 Регистрация: 01.01.1970	#14 26.02.2009 13:58:34 Что-то намудрили сильно. без всяких если: =ПОДСТАВИТЬ(ТЕКСТ(A1;"# ##0,00");",";"-") Bite my shiny metal ass!

Pankratd Пользователь Сообщений: 114 Регистрация: 05.01.2013	#15 26.02.2009 14:10:47 Век живи, век учись... и все равно дураком помрешь.(Это я осебе). Стереотипность мышления, однако, сработала. Молодец, Лузертм.

Василий Пользователь Сообщений: 6 Регистрация: 26.02.2009	#16 26.02.2009 15:16:57 Спасибо всем! Все работает! Преобразование: из 1234567,89 в 1 234 567-89 а 0,00 в 0-00) Вариант 1: =ЕСЛИ(A1=0;"0-00";ЗАМЕНИТЬ(ТЕКСТ(A1;"0 0,00");НАЙТИ(",";ТЕКСТ(A1;"0 0,00"));1;"-")) Вариант 2: =ПОДСТАВИТЬ(ТЕКСТ(A1;"# ##0,00");",";"-")

Читают тему