А зачем VBA-функция нужна?  
С этим легко и формулы справятся:  
=СУММ(Лист2:Лист6!I8)  
 
Только листы добавляйте МЕЖДУ существующих листов (Лист2 и Лист6)  
Ну или создайте 2 пустых листа (первый и последний), и в формуле укажите их названия.  
 
Пример в файле: http://excelvba.ru/XL_Files/Sample__15-07-2011__17-46-42.zip

{quote}{login=EducatedFool}{date=15.07.2011 03:49}{thema=}{post}Теперь эти листы (с именами НАЧАЛО и КОНЕЦ) можно скрыть - и добавлять новые листы даже после последнего видимого листа.  
Формулы будут считать корректно (и быстрее, чем ваша UDF)  
 
Пример в файле: http://excelvba.ru/XL_Files/Sample__15-07-2011__17-47-50.zip{/post}{/quote}  
 
Всё гениальное - просто :)  
Спасибо. Не знал что так можно сделать.  
Попробовал, работает. :)

С.М.,  
а в чем смысл использования пользовательского типа, состоящего из одной переменной?  
Если определить переменные как Variant:  
Dim Cubes(), Cube,  
и убрать везде ".Т", работает так же.

Убрал ".T", жму компилировать - ругань.  
Погорячился с названием пользов.типа - Cube - запутался в измерениях, надо было назвать Table - вроде как срез куба.  
Вот чуть покороче и ЮзерТип заменил на Коллекцию:  
'  
Function СуммЯчеекТаблиц2(ByVal ИмяТаблицы As String, Optional АвтоПересчет As Boolean = True)  
Rem Функция суммирует значения ячеек одинаково-именованных диапазонов на листах активной книги.  
   Dim WBk As Workbook, Ts As New Collection, T, Sh As Worksheet, TRng As Range, S() As Double  
   Dim N As Integer, M As Integer, TCnt As Integer, I As Integer, J As Integer, K As Integer  
   '  
   Application.Volatile АвтоПересчет  
   Set WBk = Application.Caller.Parent.Parent  
   On Error Resume Next  
   For Each Sh In WBk.Worksheets  
       Set TRng = Sh.Names(ИмяТаблицы).RefersToRange  
       If Not TRng Is Nothing Then  
           Ts.Add TRng.Value  
           Set TRng = Nothing  
       End If  
   Next  
   On Error GoTo ErrExit  
   N = UBound(Ts(1), 1)  
   M = UBound(Ts(1), 2)  
   ReDim S(1 To N, 1 To M)  
   For Each T In Ts  
       For J = 1 To M  
           For I = 1 To N  
               S(I, J) = S(I, J) + T(I, J)  
           Next  
       Next  
   Next  
   СуммЯчеекТаблиц2 = S  
   On Error GoTo 0  
   Exit Function  
ErrExit:  
   Err.Clear  
   СуммЯчеекТаблиц2 = CVErr(xlErrValue)  
End Function

> Dim Cubes(), Cube ...  
Ух-ты!  
Получается, что ReDim Preserve Массив(Первое_измерение) ?  
 
А как же строгое "изменять можно только верхнюю границу ПОСЛЕДНЕГО измерения массива" в руководствах по VB/VBA ?

{quote}{login=Казанский}{date=15.07.2011 09:12}{thema=}{post}Это же одномерный массив. У него первое измерение - оно же и последнее :){/post}{/quote}  
Алексей, спасибо - уже понял.  
{quote}{login=Казанский}{date=15.07.2011 09:12}{thema=}{post}Другое дело, что массив массивов вообще не нужен. Считали массив с листа - сложили - дальше пошли.{/post}{/quote}  
Здесь не понял: до начала цикла по листам не известна геометрия выходного массива S(), можно конечно цикл прервать на первом попавшем, с нужном диапазоном, а смысл ?    
{quote}{login=Казанский}{date=15.07.2011 09:12}{thema=}{post}Неплохо бы добавить проверку на IsNumeric и размер считанного массива, вдруг они разные.{/post}{/quote}  
Проверку на  IsNumeric делает On Error GoTo ErrExit [S() As Double], а проверку на размеры, да, надо добавить.

Как-то так:  
'  
Function СуммЯчеекТаблиц(ByVal ИмяТаблицы As String, Optional АвтоПересчет As Boolean = True)  
Rem Суммирует значения ячеек одинаково-именованных и с одинаковой структурой диапазонов-таблиц на листах книги.  
   Dim Ts(), T(), Sh As Worksheet, TRng As Range, S() As Double  
   Dim N As Integer, M As Integer, TCnt As Integer, I As Integer, J As Integer, K As Integer  
   '  
   Application.Volatile АвтоПересчет  
   On Error Resume Next  
   For Each Sh In Application.Caller.Parent.Parent.Worksheets  
       Set TRng = Sh.Names(ИмяТаблицы).RefersToRange  
       If Not TRng Is Nothing Then  
           TCnt = TCnt + 1  
           ReDim Preserve Ts(1 To TCnt)  
           Ts(TCnt) = TRng.Value  
           Set TRng = Nothing  
       End If  
   Next  
   On Error GoTo ErrExit  
   N = UBound(Ts(1), 1)  
   M = UBound(Ts(1), 2)  
   ReDim S(1 To N, 1 To M)  
   For K = 1 To TCnt  
       T = Ts(K)  
       If UBound(T, 1) <> N Or UBound(T, 2) <> M Then GoTo ErrExit  
       For J = 1 To M  
           For I = 1 To N  
               S(I, J) = S(I, J) + T(I, J)  
           Next  
       Next  
   Next  
   СуммЯчеекТаблиц = S  
   On Error GoTo 0  
   Exit Function  
ErrExit:  
   Err.Clear  
   СуммЯчеекТаблиц = CVErr(xlErrValue)  
End Function

файл

соглашусь, с EducatedFool - зачем изобретать велосипед)  
 
Если исходить из макроса автора темы, то я бы сделал так (при условии, что суммируются только целые числа (результат в пределах от -32768 до +32767), и с первого листа нет нужды брать данные):  
 
Public Function SumOfSheets%(ByRef objCell As Object)  
Dim objSheet As Object  
For Each objSheet In Worksheets  
   If Not objSheet Is ActiveSheet Then  
       SumOfSheets = SumOfSheets + objSheet.Range(objCell.Address)  
   End If  
Next  
End Function

Попробую прояснить: в целом против) Но если все-таки автор (темы) хочет макрос, то (как вариант) выше.