А вы формируйте XML нормально, первой строкой добавив в него инструкцию с кодировкой  
И проблем не будет.  
 
Пример:  
(для работы кода, надо в tools-references поставить галочку для библиотеки Microsoft XML v6.0)  
 
 
Sub test()  
   xmlpath$ = ThisWorkbook.Path & "\gallery2.xml"  
     
   Dim xml As DOMDocument, rootnode As IXMLDOMElement  
   Dim filenode As IXMLDOMElement, sheetnode As IXMLDOMElement  
   Set xml = CreateObject("Microsoft.XMLDOM")  
 
   With xml  
       .appendChild .createProcessingInstruction("xml", "version='1.0' encoding='windows-1251'")  
 
       ' ============== rootnode ===============  
       Set rootnode = .appendChild(.createElement("PriceConfiguration"))  
       rootnode.Attributes.setNamedItem(.createAttribute("Name")).Text = "123"  
       rootnode.Attributes.setNamedItem(.createAttribute("Version")).Text = PRICE_CONF_VERSION&  
 
       rootnode.appendChild(.createElement("Description")).Text = Description  
       rootnode.appendChild(.createElement("AuthorID")).Text = AuthorID  
 
 
       ' ============== filenode ===============  
       Set filenode = rootnode.appendChild(.createElement("File"))  
       filenode.Attributes.setNamedItem(.createAttribute("Type")).Text = PriceType  
 
       filenode.appendChild(.createElement("FilesMask")).Text = FilesMask  
 
       With filenode.appendChild(xml.createElement("XLSoptions"))  
           .appendChild(xml.createElement("Password")).Text = Password  
           .appendChild(xml.createElement("MergeXLSsheets")).Text = Abs(CInt(MergeXLSsheets))  
       End With  
 
       If Len(xmlpath$) > 0 Then .Save xmlpath$  
   End With  
End Sub

Я правильно понимаю - это инструкция с кодировкой?

Василий, ну неужели нельзя было по аналогии сделать?  
 
вот вариант кода под ваши данные:  
 
Sub test2()  
   On Error Resume Next  
   xmlpath$ = ThisWorkbook.Path & "\gallery3.xml"  
 
   Set xml = CreateObject("Microsoft.XMLDOM")  
 
   Dim ra As Range, cell As Range  
   Set ra = Range([A2], Range("A" & Rows.Count).End(xlUp)) ' заполненные строки
 
   ' задаем кодировку для XML  
   xml.appendChild xml.createProcessingInstruction("xml", "version='1.0' encoding='utf-8'")  
 
   ' глявный узел  
   Set rootnode = xml.appendChild(xml.createElement("MyTable"))  
   rootnode.Attributes.setNamedItem(xml.createAttribute("Name")).Text = ThisWorkbook.Name  
 
   ' добавляем дочерние узлы для каждой строки  
   For Each cell In ra.Cells    ' перебираем все строки  
 
       With rootnode.appendChild(xml.createElement("Employee"))    ' создаём узел в XML  
           ' и добавляем в него значения  
           .Attributes.setNamedItem(xml.createAttribute("ID")).Text = cell.Value  
 
           For i = 2 To 12    ' для каждого столбца  
               ColumnName$ = Cells(1, i)  
               .appendChild(xml.createElement(ColumnName$)).Text = cell.EntireRow.Cells(i)  
           Next  
       End With  
   Next cell  
 
   xml.Save xmlpath$ ' сохраняем XML  
End Sub  
 
 
 
 
 
Чтобы воспользоваться кодом, добавьте его в стандартный модуль, и назначьте ему кнопку.  
Ваш макрос НЕ НУЖЕН. Ничего «активировать» не надо.  
Мой макрос - замена вашему. Какой использовать - выбор за вами.  
 
 
На выходе получается XML файл в нужной кодировке, такого вида:  
http://ExcelVBA.ru/pictures/20121016-pl8-80kb.jpg  
 
Вам ведь так нужно было?  
 
 
> Но я ооочень хотел бы сделать структуру читабельную  
 
Можно узнать, нафига?