Public Function getMatches(ByVal txtPattern As String, _
 ByVal txtString As String, _
 Optional ByVal bSensitive As Boolean = True) As Variant

 ' getMatches - return list of matches from matching pattern txtPattern
 ' against test string txtString, optionally case-insensitive
 
 Dim objRegex As VBScript_RegExp_55.RegExp
 Dim colMatch As VBScript_RegExp_55.MatchCollection
 Dim vbsMatch As VBScript_RegExp_55.Match
 Dim aMatches() As String
 Dim i As Integer
 
 On Error GoTo EvalError
 
 Set objRegex = New VBScript_RegExp_55.RegExp
 With objRegex
 .Pattern = txtPattern
 .IgnoreCase = Not bSensitive
 .Global = True
 End With
 
 Set colMatch = objRegex.Execute(txtString)
 If colMatch.Count = 0 Then
 ReDim Preserve aMatches(1)
 aMatches(1) = ""
 Else
 ReDim aMatches(0 To colMatch.Count - 1, 0 To 2)
 For i = 0 To colMatch.Count - 1
 Set vbsMatch = colMatch(i)
 aMatches(i, 0) = vbsMatch.value
 aMatches(i, 1) = vbsMatch.FirstIndex
 aMatches(i, 2) = vbsMatch.length
 Next i
 End If
 
 getMatches = aMatches
 
 Exit Function
 
EvalError:
 Debug.Print "Error in getMatches: " & Err.Number & " " & Err.Description
 Err.Raise Err.Number, Err.Source, Err.Description
 
End Function