Option Explicit

#If VBA7 Then
Public Declare PtrSafe Sub CopyMemory Lib "kernel32" _
    Alias "RtlMoveMemory" (ByRef destination As Any, ByRef Source As Any, ByVal length As LongPtr)
#Else
Public Declare Sub CopyMemory Lib "kernel32" _
    Alias "RtlMoveMemory" (ByRef destination As Any, ByRef Source As Any, ByVal length As Long)
#End If

Public ribbon As IRibbonUI
Private is_ribbon_loaded As Boolean

Sub OnRibbonLoaded(ribbonUI As IRibbonUI)
    Set ribbon = ribbonUI
    Names("RibbonPointer").Value = ObjPtr(ribbon) ' <== Здесь сохраняем указатель на ленту в именованный диапазон.
    is_ribbon_loaded = True
    Call ActivateFLTab
End Sub

Sub ActivateFLTab()
    If Val(Application.Version) > 12 Then
        If is_ribbon_loaded Then
            Call CheckRibbon
            ribbon.ActivateTab "rxFL"
        End If
    End If
End Sub

Sub CheckRibbon()
    
    If ribbon Is Nothing Then
#If VBA7 Then
        Dim lPointer As LongPtr
        lPointer = CLngPtr([RibbonPointer])
#Else
        Dim lPointer As Long
        lPointer = CLng([RibbonPointer])
#End If
        CopyMemory ribbon, lPointer, LenB(lPointer)
    End If

End Sub