Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Как через если соединить три разных показателя которые повторяются, Надо чтобы у каждого города который повторяется и не повторяется писалось по какому транспорту он едет
 
#1
21.11.2023 12:43:39
В столбике 1 есть города которые повторяются, но транспорт у них разный и я не понимаю как через формулу если сделать так, чтобы в 3 столбце показывалось, если москва - авиа, авто то будет писаться, "авиа/авто" или просто у города воронеж есть только авто значит авто, заранее спасибо за объяснение
 
 
 
#2
21.11.2023 12:46:19
Должно вот так получиться,  наверное сюда надо добавить "и, или"
 
 
 
#3
21.11.2023 13:01:29
Цитата
Kirill Kirk написал:
наверное сюда надо добавить "и, или"
Скорее всего надо.
Формула массива:
Код
=TEXTJOIN(", ";1;IF(A$2:A$12=A2;B$2:B$12;""))
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#4
21.11.2023 13:04:13
Цитата
написал:
=TEXTJOIN(", ";1;IF(A$2:A$12=A2;B$2:B$12;""))
Спасибо большое, но у меня в экселе даже нет textjoin ( объединить)
 
 
 
#5
21.11.2023 13:12:10
Все узнал, у меня это СЦЕПИТЬ
 
 
 
#6
21.11.2023 13:14:53
Выходит почему-то ошибка, буду пытаться исправить
Изменено: Kirill Kirk - 21.11.2023 13:15:37
 
 
 
#7
21.11.2023 13:25:12
Цитата
Kirill Kirk написал:
Все узнал, у меня это СЦЕПИТЬ
Круто.
=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(СЦЕПИТЬ(ЕСЛИОШИБКА(ИНДЕКС(B$2:B$12;НАИМЕНЬШИЙ(ЕСЛИ(A$2:A$12=A2;СТРОКА(A$2:A$12)-1);1));"");" ";ЕСЛИОШИБКА(ИНДЕКС(B$2:B$12;НАИМЕНЬШИЙ(ЕСЛИ(A$2:A$12=A2;СТРОКА(A$2:A$12)-1);2));"");" ";ЕСЛИОШИБКА(ИНДЕКС(B$2:B$12;НАИМЕНЬШИЙ(ЕСЛИ(A$2:A$12=A2;СТРОКА(A$2:A$12)-1);3));"")));" ";", ")
Массивная. Работает до 3-х видов транспорта.
Если нужно больше, докручивайте.
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#8
21.11.2023 13:47:14
С дополнительными столбцами до 5 видов транспорта
Алексей М.
 
 
 
#9
21.11.2023 14:06:04
=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TRIM(SUBSTITUTE(TEXT(SUM(COUNTIFS($A$2:$A$12;A2;$B$2:$B$12;{"ж/д";"авто";"авиа"})*{1;2;3}*10^{2;1;0});"0\ 0\ 0");0;));1;"ж/д");2;"авто");3;"авиа");" ";"/ ")


=SUBSTITUTE(TRIM(
IF(COUNTIFS($A$2:$A$12;A2;$B$2:$B$12;"ж/д");"ж/д ";"")&
IF(COUNTIFS($A$2:$A$12;A2;$B$2:$B$12;"авто");"авто ";"")&
IF(COUNTIFS($A$2:$A$12;A2;$B$2:$B$12;"авиа");"авиа ";"")
);" ";"/ ")
Изменено: БМВ - 21.11.2023 14:17:30
По вопросам из тем форума, личку не читаю.
 
 
 
#10
22.11.2023 07:34:58
Вариант для любого количества "транспорта", но если порядок не важен:
 
 
 
Страницы: 1
Наверх