Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Как преобразовать формат времени в Excel, Преобразование формата времени с "ч" "м" "с" в цифры
 
#1
20.05.2024 10:16:19
В отчет выгружает форматы такие, пример "4ч. 5мин. 22сек." и как пример "44мин."
Как преобразовать, чтобы получилось "4,5" и "0,44" соответственно.
Смотрел похожие вопросы на форуме, не получилось подставить те формулы.  
 
 
 
#2
20.05.2024 10:24:46
VasNF, приложите файл, что бы было понятно, что у вас за формат и 4,5 это никак не 4 часа 5 минут.
 
 
 
#3
20.05.2024 10:31:01
спасибо - да, неверно указал. Файл прикрепил
 
 
 
#4
20.05.2024 10:37:10
Код
=СЖПРОБЕЛЫ(ПСТР(A1;1;ЕСЛИОШИБКА(НАЙТИ("ч.";A1)-1;0)))&","&ПРАВСИМВ("0"&СЖПРОБЕЛЫ(ПСТР(A1;ЕСЛИОШИБКА(НАЙТИ("ч.";A1)+2;1);ЕСЛИОШИБКА(НАЙТИ("мин.";A1)-ЕСЛИОШИБКА(НАЙТИ("ч.";A1)+2;1);0)));2)
 
 
 
#5
20.05.2024 10:38:36
"4ч. 5мин. 22сек."  <> "4.5" (часа). 4.5 часа это "4ч. 30мин." ровно.
"44мин." <> 0.44 (часа). "44мин." = 44/60 часа
А то у вас "4ч. 6мин" (4,6) > "4ч. 50мин." (4,5).
Думайте над алгоритмом дальше.

Цитата
VasNF: Смотрел похожие вопросы на форуме, не получилось подставить те формулы.  
неудивительно

P.S.: пример просто великолепный, конечно  :D
Изменено: Jack Famous - 20.05.2024 10:39:59
Во всех делах очень полезно периодически ставить знак вопроса к тому, что вы с давних пор считали не требующим доказательств (Бертран Рассел) ►Благодарности сюда◄
 
 
 
#6
20.05.2024 10:54:16
Цитата
написал:
Код=СЖПРОБЕЛЫ(ПСТР(A1;1;ЕСЛИОШИБКА(НАЙТИ("ч.";A1)-1;0)))&","&ПРАВСИМВ("0"&СЖПРОБЕЛЫ(ПСТР(A1;ЕСЛИОШИБКА(Н
Спасибо. В целом формула срабатывает, но не так как надо.
1) минуты без нуля (если без часов)
2) не суммирует итоги, хотя формат числовой
что нужно поправить?
 
 
 
#7
20.05.2024 10:55:32
Цитата
написал:
неудивительноP.S.: пример просто великолепный, конечно  
да ладно ,ну ошибся же. Позже приложил файл потом, где точно написан пример
 
 
 
#8
20.05.2024 11:01:36
Цитата
написал:
1) минуты без нуля (если без часов)
В вашей "неправильной" арифметике 4.5 неравны 4.50. Это не вопрос.
Вы пытаетесь использовать функцию СУММ(), работающую в рамках классической арифметики. Вам нужна альтернативная функция, суммирующая подобные значения.
 
 
 
#9
20.05.2024 11:06:58
Код
=ЕСЛИОШИБКА(ЗНАЧЕН(ЛЕВСИМВ(G2;НАЙТИ(",";G2)-1));0)+ЕСЛИОШИБКА(ЗНАЧЕН(ЛЕВСИМВ(G3;НАЙТИ(",";G3)-1));0)&","&ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G2;НАЙТИ(",";G2)+1;ДЛСТР(G2)));0)+ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G3;НАЙТИ(",";G3)+1;ДЛСТР(G3)));0)
Функция =СУММ(G2;G4) в вашем варианте примет такой вид.
 
 
 
#10
20.05.2024 11:08:18
Цитата
написал:
В вашей "неправильной" арифметике 4.5 неравны 4.50. Это не вопрос.
это ошибся, конечно же 4,05
всё равно не удается сложить альтернативными сложениями. Какую применить в случае данной формулы подскажите пожалуйста?
 
 
 
#11
20.05.2024 11:14:56
Код
=ЕСЛИОШИБКА(ЗНАЧЕН(ЛЕВСИМВ(G2;НАЙТИ(",";G2)-1));0)+ЕСЛИОШИБКА(ЗНАЧЕН(ЛЕВСИМВ(G3;НАЙТИ(",";G3)-1));0)+ЦЕЛОЕ((ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G2;НАЙТИ(",";G2)+1;ДЛСТР(G2)));0)+ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G3;НАЙТИ(",";G3)+1;ДЛСТР(G3)));0))/60)&","&ПРАВСИМВ("0"&ОСТАТ(ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G2;НАЙТИ(",";G2)+1;ДЛСТР(G2)));0)+ЕСЛИОШИБКА(ЗНАЧЕН(ПСТР(G3;НАЙТИ(",";G3)+1;ДЛСТР(G3)));0);60);2)
В этом варианте минуты переходят в часы при превышении 60.
 
 
 
#12
20.05.2024 11:21:45
собственно, получилось. Спасибо за помощь!
 
 
 
#13
20.05.2024 11:32:24
Может быть так нужно?
Код
=СУММ(ПСТР(0&F2&"00000";ПОИСК({"ч";"м";"с"};0&F2&"--чмс")-2;2)/{24;1440;86400})
Алексей М.
 
 
 
#14
20.05.2024 11:38:21
Цитата
АlехМ написал:
Может быть так нужно?
красиво.
 
 
 
#15
20.05.2024 11:48:31
Цитата
написал:
красиво.
Научился ТУТ
Алексей М.
 
 
 
#16
20.05.2024 11:52:25
Если время нужно в виде чисел с запятой, то константы нужно уменьшить в 24 раза {1;60;3600} и формат ячеек "Общий" или "Числовой" с нужным количеством знаков после запятой.
Изменено: АlехМ - 20.05.2024 11:54:21
Алексей М.
 
 
 
#17
21.05.2024 08:58:12
Цитата
написал:
Может быть так нужно?
И так ещё нужнее. Спасибо Вам и всем за помощь!!!!
 
 
 
#18
21.05.2024 09:25:56
Цитата
АlехМ:  Может быть так нужно...
Научился ТУТ
Когда то тоже видел это решение от vikttur   ; )
можно еще поджать самую малость
=СУММ((ПСТР(0&F2;ПОИСК({"ч";"м";"с"};0&F2&"!!чмс")-2;2)&",0")/24/60^{0;1;2})
 
 
 
Страницы: 1
Наверх