Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Определить победителя и сделать ограничение по числу призеров
 
#1
03.12.2015 03:52:07
 Здравствуйте. Необходимо определить одного победителя (если у него 70 и более), 4 призеров (от 51 до 69), Остальные участники.
Все решено, но как сделать ограничение по числу призеров (их должно быть только 4). =ЕСЛИ(P7<=50;«Участник»; ЕСЛИ(И(P7<69;P7>50);«Призер»; ЕСЛИ(И((P7>=70);(P7=R7));«Победитель»;«Призер»
 
 
 
#2
03.12.2015 04:07:30
Формула ячейки Q7
Код
=ЕСЛИ(СЧЁТЕСЛИ($Q$4:Q6;"Призер")>=4;"Участник"; здесь_Ваша_формула )
Затем ячейку Q7 скопировать или протянуть в ячейки ниже
Если нужно, то вместо "Участник" впишите формулу для случая с ограничением призеров - полагаю, что правильнее ограничивать общее количество победителей и призеров.
Название темы могло бы быть таким: Как в формулу добавить ограничение на количество призеров и победителей?
Изменено: ZVI - 03.12.2015 05:54:14
 
 
 
#3
03.12.2015 04:50:08
Спасибо!
 
 
 
#4
03.12.2015 05:44:26
По-моему, все же нужно ограничивать общее количество призеров и победителей, например, не больше 4-х.
Тогда формула в Q7 может быть, например, такой:
Код
=ЕСЛИ((СЧЁТЕСЛИ($Q$6:Q6;"Призер")+СЧЁТЕСЛИ($Q$6:Q6;"Победитель"))>=4;
   "Участник";
   ВЫБОР(ПОИСКПОЗ(P7;{0;50,005;70;1000};{1;2;3;3});
        "Участник";
        "Призер";
        ЕСЛИ(P7>=МАКС(P:P);"Победитель";"Призер")
    )
)
Затем ячейку Q7 скопировать или протянуть в ячейки ниже.
Если у Вас в качестве разделителя целой и дробной части используется точка, а не запятая, то в формуле вместо 50,005 запишите 50.005
Изменено: ZVI - 03.12.2015 05:56:05
 
 
 
#5
03.12.2015 10:04:03
Огромнейшее спасибо!!!
Только там не >=4,
а >=5.
ОЧЕНЬ ПОМОГЛИ!!!
 
 
 
#6
03.12.2015 12:26:32
Рад, что помогло. По поводу >=5 вроде бы изначально в сообщении #1 так и было написано, но потом и сейчас "(их должно быть только 4)", но это не принципиально - используйте, как Вам нужно.
Изменено: ZVI - 03.12.2015 12:28:53
 
 
 
#7
03.12.2015 16:39:43
Цитата
ZVI написал: например, не больше 4-х.
грустно за последнего (выделила жёлтеньким в столбце Итог)...
Изменено: JeyCi - 03.12.2015 18:11:12
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
 
 
 
#8
03.12.2015 17:48:55
Цитата
NalsuE написал: Необходимо определить одного победителя (если у него 70 и более), 4 призеров (от 51 до 69), Остальные участники.
может, лучше 1-й Победитель, следующие 4 - Призёры, остальные - Участники??
тогда если взять за основу
формулу от vikttur  из Рейтинг без дублей #2,
то получается можно так в Q7 и растянуть
(для Отбора 1 победителя и 4х призёров):
=ЕСЛИОШИБКА(ВЫБОР(РАНГ(P7;$P$7:$P$14)+СЧЁТЕСЛИ($P$7:P7;P7)-1;"Победитель";"Призёр";"Призёр";"Призёр";"Призёр");"Участник")
P.S. последнего (почти призёра) тоже учли  :)

но если 2 призёра с одинак кол-вом балов (вдруг появятся), то, наверно, лучше работает СЧЁТ от Владимир из Перенос данных минуя пустые ячейки #2
тогда рейтинг такой =РАНГ(P7;$P$7:$P$14)+СЧЁТЕСЛИ(СМЕЩ($P$7;;;СТРОКА($P$7:$P$14)-6);"<>")-1
(возможно, лучше подойдёт)
=ЕСЛИОШИБКА(ВЫБОР(РАНГ(P7;$P$7:$P$14)+СЧЁТЕСЛИ(СМЕЩ($P$7;;;СТРОКА($P$7:$P$14)-6);"<>")-1;"Победитель";"Призёр";"Призёр";"Призёр";"Призёр");"Участник")
Изменено: JeyCi - 03.12.2015 18:32:25
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
 
 
 
#9
04.12.2015 03:36:15
Тоже хороший вариант) НО!
И в первом и во втором,и в третьем случаях при изменении данных в графах по видам спорта не будут адекватно меняться победитель и призер, например, при новом результате в 100 баллов он не учтется и не станет победителем. Вывод, данные можно заносить один раз. Иногда, все же формула показывает верные результаты.
Есть ли возможность редактировать данные с изменением в онлайне победителя и призера?
 
 
 
#10
04.12.2015 04:01:57
И вопрос немного не по теме, но по этой же таблице. УДАЛЕН
 
 
 
#11
04.12.2015 04:39:53
Эпиграф:
"Если гора не идёт к Магомеду...."
Почему нельзя навечно вписать статусы участников и сортировать их самих со всем приданным по событию Worksheet_Calculate?
 
 
 
#12
04.12.2015 04:48:44
Потому что не все знают от скольки и до скольки считать, как и куда писать. А затем все данные, а их порядка 10 протоколов будет, сводить в одну!
 
 
 
#13
04.12.2015 04:49:19
Порядка 100 протоколов
 
 
 
#14
04.12.2015 04:59:06
Цитата
NalsuE написал:
от скольки и до скольки считать
Что именно считать?
-------------------------
В макросе файла из сообщения #11 ошибка. Исправил.
Виновные наказаны.
 
 
 
#15
04.12.2015 05:05:23
Вот для примера. Столбцы с подписью НЕ РЕДАКТИРОВАТЬ-их как раз и нужно считать. А головная боль-это определение победителя, призера и победителя АВТОМАТИЧЕСКИ по мере редактирования данных. Как вариант, конечно, сначала определить точное число участников) Тогда соглашусь, проблем не возникнет.  
 
 
 
#16
04.12.2015 05:10:38
Цитата
NalsuE написал:  Столбцы с подписью НЕ РЕДАКТИРОВАТЬ
Таких нет в файле сообщения #15.
 
 
 
#17
04.12.2015 05:31:13
Попробуйте кликнуть ячейку G7 для примера
 
 
 
#18
04.12.2015 05:38:50
Там формула с участием ячейки "F7".
В ячейке "F7" примечания ""не редактировать" нет.
Спокойно меняете значение в ней и событие Worksheet_Calculate происходит.
---------------------
Видимо я не победитель, не призёр и уже не участник на ближайшие несколько часов. Уехал по работе.
 
 
 
#19
04.12.2015 09:20:50
Цитата
NalsuE написал: Тоже хороший вариант) НО!
голословное утверждение...
вы проверяли? - у меня в файле всё меняется (с соотв. формулами из следующего поста)...
Правила форума !!! (о примере файла)
Изменено: JeyCi - 04.12.2015 09:22:39
чтобы не гадать на кофейной гуще, кто вам отвечает и после этого не совершать кучу ошибок - обратитесь к собеседнику на ВЫ - ответ на ваш вопрос получите - а остальное вас не касается (п.п.п. на форумах)
 
 
 
#20
07.12.2015 04:24:16
Почему 24-й остался участником?
 
 
 
#21
07.12.2015 04:27:53
А вот второй вариант формул, тоже не показывает и победителя тоже
 
 
 
#22
07.12.2015 12:12:57
Попробуйте так:
Код
=ЕСЛИ((РАНГ(P7;$P$7:$P$1000)+СЧЁТЕСЛИ($P$7:P7;P7)-1)>5;
   "Участник";
   ВЫБОР(ПОИСКПОЗ(P7;{0;50,005;70;1000};{1;2;3;3});
        "Участник";
        "Призер";
        ЕСЛИ(P7>=МАКС(P:P);"Победитель";"Призер")
    )
)

Если у Вас в качестве разделителя целой и дробной части используется точка, а не запятая, то в формуле вместо 50,005 запишите 50.005
Но имейте ввиду, что если исходить из Вашей логики по ограничению в 5 человек в категории "призеры+победители", то из этой категории будут выкинуты те, кто попал в неё (одинаковые с ними результаты), но лимит в 5 человек уже исчерпан.
Например: 1 победитель + 4 призера, а еще у нескольких человек результат такой же, как у 4-го призера, но они уже не будут считаться призерами.
Изменено: ZVI - 07.12.2015 14:16:39
 
 
 
#23
08.12.2015 03:02:20
Мои овации))) Теперь можно редактировать и дописывать данные и формула все верно рассчитает) СПАСИБО
 
 
 
Страницы: 1
Читают тему
Наверх