Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
ПОИСКПОЗ части слова внутри ячеек диапазона
 
#1
02.02.2016 12:22:44
Добрый день!
Прошу помощи в решении задачи. На форуме похожего запроса не нашла.
Мне нужно подтянуть названия городов (диапазоном, не используя "название города" в формуле) к списку, где они (города) содержатся внутри текста.
Примерно так:

Хабаровск_______Эксплуатационный цех (Хабаровск)
Я что-то намудрила  8)
не работает конечно же))

{=ИНДЕКС($C$2:$C$26(ПОИСКПОЗ("*"&C2:C13&"*";$A$2:$A$26);-1);1)}
 
 
 
#2
02.02.2016 12:28:35
sens84,
Код
=ВПР("*"&C2&"*";A:A;1;)
Правда, 3 только находит:  
 
 
 
#3
02.02.2016 12:30:35
а я не понял что к чему надо подтянуть если к столбцу А то как вариант массивная
Код
=ИНДЕКС($C$1:$C$13;МАКС(ЕЧИСЛО(ПОИСК($C$1:$C$13;$A2))*СТРОКА($1:$13)))
Изменено: Сергей - 02.02.2016 12:31:00 (забыл формулу)
Лень двигатель прогресса, доказано!!!
 
 
 
#4
02.02.2016 12:34:12
Казанский,

Спасибо! но это только по 1 городу, а нужно чтобы он поиск был по диапазонам
 
 
 
#5
02.02.2016 12:36:03
Вы покажите в примере, что надо получить. Вы хотите получить все строки столбца А, в которых встречается указанный город? Если да - то только кодами(функции пользователя UDF), вроде этого:
Как сцепить несколько значений в одну ячейку по критерию? СцепитьЕсли
Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы...
 
 
 
#6
02.02.2016 12:42:04
Сергей,
нужно чтобы рядом со столбцом А были указаны города, которые указаны справа, если таковые содержатся в столбце А. Конкретно рядом с ячейкой, в которой содержится какой-либо город из предложенного списка
Изменено: sens84 - 02.02.2016 12:43:45
 
 
 
#7
02.02.2016 12:46:46
подразделениеРезультатГород
Эксплуатационно-технологический цех  № 3 (Хабаровск)ХабаровскВладивосток
Эксплуатационно-технологический цех № 10 (Комсомольск-на-Амуре)Хабаровск
Эксплуатационно-технологический цех № 20 (Тында) Алдан
Эксплуатационно-технологический цех № 6 (Уссурийск)Долинск
Электроизмерительная лабораторияКорсаков
Электроизмерительная лабораторияНевельск
Этц № 22 (Нерюнгри)Поронайск
Этц № 22 (Нерюнгри)Томари
ЭТЦ № 23 (Алдан)АлданТымовское
ЭТЦ № 23 (Алдан)АлданХолмск
ЭТЦ № 23 (Алдан)АлданЮжно-Сахалинск
ЭТЦ24 ( Нижний Бестях)Нижний БестияхНижний Бестях
Изменено: sens84 - 02.02.2016 12:52:49
 
 
 
#8
02.02.2016 12:47:15
=ЕСЛИОШИБКА(ВПР(ПСТР(A2;ПОИСК("(";A2)+1;ПОИСК(")";A2)-ПОИСК("(";A2)-1);$C$2:$C$16;1;0);"")
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
#9
02.02.2016 12:51:02
sens84, а, обратная задача
Код
=ПРОСМОТР(2;1/ПОИСК("*"&$C$2:$C$13&"*";A2);$C$2:$C$13)
 
 
 
#10
02.02.2016 12:57:19
Владимир,

низкий поклон Вам! :)
Работает! осталось ее "прочесть" для общего развития, пока что это все выглядит как "набор странных символов" :-)))
 
 
 
#11
02.02.2016 12:58:05
Цитата
sens84 написал: нужно чтобы рядом со столбцом А
дак она это и делает предложенные варианты в файле, обратите внимание что формула Владимир, не срабатывает в отдельных случаях из за того что у вас не одинаково написаны названия городов в скобках один я поправил (выделено желтым)
Лень двигатель прогресса, доказано!!!
 
 
 
#12
02.02.2016 13:13:38
=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$13;ПОИСКПОЗ(ПОДСТАВИТЬ(ПСТР(A2;ПОИСК("(";A2&"(")+1;20);")";);$C$2:$C$13;));"")
 
 
 
#13
02.02.2016 13:21:01
=ПРОСМОТР(2;1/ПОИСК($C$2:$C$13;A2);$C$2:$C$13)
подробнее, с пошаговым описанием алгоритма: Найти в ячейке любое слово из списка
Даже самый простой вопрос можно превратить в огромную проблему. Достаточно не уметь формулировать вопросы...
 
 
 
#14
02.02.2016 14:12:41
Сергей, Спасибо! Я подозревала что "*"& может пригодиться)) The_Prist, спасибо! vikttur, тоже работает! Спасибо!

Осталось в них разобраться
 
 
 
#15
03.02.2016 10:08:20
Поднимаю тему :-)
в общем предыдущие формулы находили Город ссылаясь на скобки, но не все города в скобках..(( поэтому он на половину обработал запрос.
Как изменить формулу, чтобы искать наименование города в самых разных вариантах? и со скобками и без скобок или даже, если скобка только с одной стороны))

=ЕСЛИОШИБКА(ИНДЕКС($C$2:$C$13;ПОИСКПОЗ(ПОДСТАВИТЬ(ПСТР(A12;ПОИСК("";A12&"(")+1;20);")";);$C$2:$C$13;));"")

=ЕСЛИОШИБКА(ВПР(ПСТР(A12;ПОИСК("(";A12)+1;ПОИСК(")";A12)-ПОИСК("(";A12)-1);$C$2:$C$16;1;0);"")
 
 
 
#16
03.02.2016 13:55:40
Цитата
sens84 написал: и со скобками и без скобок
Цитата
Казанский написал: #9 2 Фев 2016 12:51:02
Вам Алексей писал:
=ЕСЛИОШИБКА(ПРОСМОТР(2;1/ПОИСК("*"&$C$2:$C$13&"*";A2);$C$2:$C$13);"")
"..Сладку ягоду рвали вместе, горьку ягоду я одна."
 
 
 
Страницы: 1
Читают тему
Наверх