Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Получить последнее значение из строки с разделителями, Не получается разделить текст
 
#1
19.09.2025 10:29:44
Добрый день. Есть на форуме много похожих тем, но для себя ответа не нашел.
Суть в том, чтобы скопировать последние 2 или три символа из столбца В в столбец С. Проблема только в том, что разделителей  несколько и место их плавает, как и длина текста. Поэтому не получилось решить и с поиском MID + FIND.
Кто может помочь?
Изменено: Sanja - 19.09.2025 10:59:59
 
 
 
#2
19.09.2025 10:33:34
=ТЕКСТПОСЛЕ(B2;"-";-1)

pq
Изменено: sotnikov - 19.09.2025 10:45:42
 
 
 
#3
19.09.2025 10:36:14
Код
=ФИЛЬТР.XML("<l><i>"&ПОДСТАВИТЬ(B2;"-";"</i><i>")&"</i></l>";"//i[last()]")
Согласие есть продукт при полном непротивлении сторон
 
 
 
#4
19.09.2025 10:40:06
Благодарю!
попытаюсь понять синтаксис :)
 
 
 
#5
19.09.2025 10:47:17
В помощь
Деление слипшегося текста функцией ФИЛЬТР.XML
Согласие есть продукт при полном непротивлении сторон
 
 
 
#6
19.09.2025 11:00:18
Добрый день. Еще вариант =ПСТР(B2;ПРОСМОТР(;-1/(ПСТР(B2;СТРОКА($A$1:$A$100);1)="-");СТРОКА($A$1:$A$100))+1;9999)
 
 
 
#7
19.09.2025 11:03:19
Цитата
написал:
Добрый день. Еще вариант =ПСТР(B2;ПРОСМОТР(;-1/(ПСТР(B2;СТРОКА($A$1:$A$100);1)="-");СТРОКА($A$1:$A$100))+1;9999)
Тоже класс!
Спасибо!
 
 
 
#8
19.09.2025 11:06:41
UDF
Код
Function ПОСЛЕДНЕЕ(текст$, разделитель$)
Dim arr
  arr = Split(текст, разделитель)
  ПОСЛЕДНЕЕ = arr(UBound(arr))
End Function
Согласие есть продукт при полном непротивлении сторон
 
 
 
#9
19.09.2025 11:21:26
=МАКС(ЕСЛИОШИБКА(-ПРАВБ(B2;СТРОКА($1:$9));))
Формула массива
Изменено: _Boroda_ - 19.09.2025 11:21:34
Скажи мне, кудесник, любимец ба’гов...
 
 
 
#10
19.09.2025 11:42:54
в принципе Последнее слово
=--ПРАВБ(ПОДСТАВИТЬ(B2;"-";"         ");9)
Цитата
решить и с поиском MID + FIND
=--ПСТР(B2;ПОИСК("#";ПОДСТАВИТЬ(B2;"-";"#";ДЛСТР(B2)-ДЛСТР(ПОДСТАВИТЬ(B2;"-";))))+1;99)
 
 
 
#11
19.09.2025 12:22:26
мгновенное заполнение разбирает это на ура.
По вопросам из тем форума, личку не читаю.
 
 
 
#12
19.09.2025 13:15:59
Цитата
написал:
мгновенное заполнение разбирает это на ура.
Про это забыл :)
Изменено: draginoid - 19.09.2025 13:16:14
 
 
 
Страницы: 1
Читают тему
Наверх