Sub Отчет()

    Dim ПоследняяСтрокаОбщий As Long
    Dim ПоследняяСтрокаОтчет As Long
    Dim ПоследнийСтолбец As Long
    Dim СтрокаОбщий As Long
    Dim СтрокаОтчет As Long
    Dim Столбец As Long
    
    Dim ПутьКФайлу As String
    Dim НазваниеФайла As String
    
    Dim ОбщийФайл As Worksheet
    Dim Отчет As Worksheet
    
    Set ОбщийФайл = ThisWorkbook.Worksheets(1)
    ПутьКФайлу = ThisWorkbook.Path & "\"
    
    ПоследнийСтолбец = ОбщийФайл.Cells.SpecialCells(xlLastCell).Column
    ПоследняяСтрокаОбщий = ОбщийФайл.Cells.SpecialCells(xlLastCell).Row
    
    For Столбец = 3 To ПоследнийСтолбец
        'Название файла формируюется из месяца и года в заголовках начиная с третьего столбца. Все названия отчетных файло должны быть вид "ммгггг"
        'Все отчетные файлы находятся в той же папке, что и общий файл
        НазваниеФайла = Format(DatePart("m", Cells(1, Столбец)), "00") & DatePart("yyyy", Cells(1, Столбец))
        НазваниеФайла = ПутьКФайлу & НазваниеФайла
        If Dir(НазваниеФайла & "*") <> "" Then
            НазваниеФайла = Dir(НазваниеФайла & "*")
            Set Отчет = Workbooks.Open(ПутьКФайлу & НазваниеФайла).Worksheets(1)
            ПоследняяСтрокаОтчет = Отчет.Cells.SpecialCells(xlLastCell).Row
            СтрокаОбщий = 2
            Do While СтрокаОбщий <> ПоследняяСтрокаОбщий + 1
                СтрокаОтчет = 2
                Do While СтрокаОтчет <> ПоследняяСтрокаОтчет + 1
                    'Наименование в общем и отчетном файлах начинается со второй строки первого столбца
                    If Отчет.Cells(СтрокаОтчет, 1) = ОбщийФайл.Cells(СтрокаОбщий, 1) Then
                        'Суммы в отчетных файлах находятся в третьем столбце
                        ОбщийФайл.Cells(СтрокаОбщий, Столбец) = Отчет.Cells(СтрокаОтчет, 3)
                        СтрокаОтчет = СтрокаОтчет + 1
                        Exit Do
                    End If
                    СтрокаОтчет = СтрокаОтчет + 1
                Loop
                СтрокаОбщий = СтрокаОбщий + 1
            Loop
            ActiveWorkbook.Close (False)
        End If
    Next

End Sub