Страницы: 1
RSS
Формула счёт количества ячеек в строке до определенной их суммы
 
Нужна такая формула которая в числовом ряду посчитает число слагаемых до указанной суммы.
Например, есть строка со значениями 1 2 3 4 5 6 7 8 9 10:
для числа 15 формула должна выдать 5, так как 1+2+3+4+5=15
для числа 17 формула также должна выдать 5, так как 15+6>17
Значения в строке могут быть любыми!

Мне пока удалось получить максимально приближенную сумму такой формулой
=ПРОСМОТР(17;ПРОМЕЖУТОЧНЫЕ.ИТОГИ(9;СМЕЩ(A1;;;;СТОЛБЕЦ(A1:J10))))Но я не могу это число обратно раскидать, чтобы получить число слагаемых.

Смотрите файл пример.
Изменено: Выдр - 25.11.2022 18:38:32
 
Код
=ЦЕЛОЕ((КОРЕНЬ(1+8*B1)-1)/2)

где В1 - ваша сумма (при В1=15 результат =5)
Программисты - это люди, решающие проблемы, о существовании которых Вы не подозревали, методами, которых Вы не понимаете!
 
Цитата
написал:
=ЦЕЛОЕ((КОРЕНЬ(1+8*B1)-1)/2)
где В1 - ваша сумма (при В1=15 результат =5)
Это для примера подойдет, но у меня в числовых рядах будут разные числа, и не по порядку, так что такой вариант не поможет.
 
Выдр, именно по этому в правилах есть про пример.
Массивная
=MATCH(D1;MMULT(--(ROW(A2:A16)>=TRANSPOSE(ROW(A2:A16)));A2:A16))
Изменено: БМВ - 25.11.2022 18:19:53
По вопросам из тем форума, личку не читаю.
 
Цитата
написал:
Выдр, именно по этому в правилах есть про пример.
Массивная
=MATCH(D1;MMULT(--(ROW(A2:A16)>=TRANSPOSE(ROW(A2:A16)));A2:A16))
добавил пример
 
Парочка вариантов:
Код
=MATCH(A2;INDEX(SUBTOTAL(9;OFFSET(A4;;;;COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4)))));))

Или без волатильности (массивный ввод):
Код
=MATCH(A2;MMULT(--(COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4)))<=TRANSPOSE(COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4)))));--TRANSPOSE($A$4:INDEX($4:$4;COUNTA($4:$4)))))
Изменено: memo - 25.11.2022 19:21:56
 
Спасибо! Вопрос исчерпан! Теперь попробую разобраться, как работают формулы.
 
memo, при перестановке "слогаемых" один транспоз пропадает
=MATCH(A2;MMULT($A$4:INDEX($4:$4;COUNTA($4:$4));--(TRANSPOSE(COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4))))<=COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4))))))
По вопросам из тем форума, личку не читаю.
 
БМВ, Ну вот и замечательно.
UPD.
Ф топку TRANSPOSE и массивность туда же)
Код
=MATCH(A2;INDEX(MMULT(--($A$4:INDEX($4:$4;COUNTA($4:$4)));--(COLUMN($A$1:INDEX($1:$1;COUNTA($4:$4)))>=ROW($A$1:INDEX(A:A;COUNTA($4:$4)))));))
Изменено: memo - 25.11.2022 23:44:36
 
Добрый!

Что-то не пойму в какую ячейку вставить формулу

Не можете ли пример с формулой выложить?

Заранее благодарен
 
Цитата
Сергей написал:
в какую ячейку вставить формулу
Куда угодно, кроме ячеек четвертой строки. Держите файл.
 
спасибо
Страницы: 1
Наверх