Поиск  Пользователи  Правила  Войти
Форумы "Планета Excel" » Вопросы по Microsoft Excel
Страницы: 1
RSS
Как убрать год с текста, Как убрать год с текста.
 
#1
09.10.2023 23:43:42

Здравствуйте. Возможно ли формулай оставить текст до года. Как в файле.
Изменено: FrOleg80 - 09.10.2023 23:44:43
 
 
 
#2
10.10.2023 02:45:21
FrOleg80, Здравствуйте, вариант
Код
=СЖПРОБЕЛЫ(ЛЕВСИМВ(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";50));ДЛСТР(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";50)))-50))
 
 
 
#3
10.10.2023 06:01:18
Цитата
написал:
FrOleg80 , Здравствуйте, вариантКод ? 1=СЖПРОБЕЛЫ(ЛЕВСИМВ(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";50));ДЛСТР(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";50)))-50))
Спасибо. Работает.
 
 
 
#4
10.10.2023 10:03:09
такой вариант
Код
=ПСТР(A2;1;НАЙТИ("202";A2)-2)
 
 
 
#5
10.10.2023 10:15:46
Добавим экзотики
Код
=ПОДСТАВИТЬ(A2;ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A2;" ";"</s><s>")&"</s></t>";"//s[starts-with(., '202')]");"")
 
 
 
#6
10.10.2023 10:25:40
Ну и мой вариант до кучи:
=ЛЕВСИМВ(A2;ПОИСК("@";ПОДСТАВИТЬ(A2;" ";"@";ДЛСТР(A2)-ДЛСТР(ПОДСТАВИТЬ(A2;" ";""))))-1)
Если в мире всё бессмысленно, — сказала Алиса, — что мешает выдумать какой-нибудь смысл? ©Льюис Кэрролл
 
 
 
#7
10.10.2023 13:38:12
Увеличу кучу
=ЛЕВСИМВ(A2;ДЛСТР(A2)-ДЛСТР(СЖПРОБЕЛЫ(ПРАВСИМВ(ПОДСТАВИТЬ(A2;" ";ПОВТОР(" ";99));99)))-1)
 
 
 
#8
10.10.2023 17:16:26
=SUBSTITUTE(A2;" "&TRIM(RIGHT(SUBSTITUTE(A2;" ";REPT(" ";99));99));)
конечно есть шанс что можно срезать лишнее, но он очень мал.
Изменено: БМВ - 10.10.2023 17:17:15
По вопросам из тем форума, личку не читаю.
 
 
 
#9
10.10.2023 22:25:57
Всем большое спасибо, что откликнулись.
 
 
 
#10
10.10.2023 22:50:00
до последнего пробела в 365
Код
=TEXTJOIN(" ",TRUE, DROP(TEXTSPLIT(A2, " "), 0, -1))
Пришелец-прораб.
 
 
 
#11
10.02.2024 10:59:49
Цитата
написал:
такой вариантКод=ПСТР(A2;1;НАЙТИ("202";A2)-2)
Помогите дописать в формулу  =ЕСЛИОШИБКА . Чтобы возвращала ячейку как есть. Спасибо.
Изменено: FrOleg80 - 10.02.2024 11:01:06
 
 
 
#12
10.02.2024 11:07:58
Цитата
написал:
Помогите дописать в формулу  =ЕСЛИОШИБКА . Чтобы возвращала ячейку как есть. Спасибо.
Спасибо. Разобрался.
 
 
 
#13
10.02.2024 11:08:08
А самое простое - Ctrl+E
 
 
 
#14
10.02.2024 14:45:40
Power Query
Код
let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Split Column by Delimiter" = Table.SplitColumn(Source, "Column1", Splitter.SplitTextByEachDelimiter({" "}, QuoteStyle.Csv, true), {"Column1.1", "Column1.2"}),
    #"Removed Columns" = Table.RemoveColumns(#"Split Column by Delimiter",{"Column1.2"})
in
    #"Removed Columns"
 
 
 
Страницы: 1
Наверх